Aylar Bazında Harcırah Hesaplama

[murat.yildirim]

Merhaba,

Harcırah hesabı için formül yazmaya ihtiyacım var nasıl bir formül yazabilirim ?

Mesala, bir çalışan 1 ocak 18 şubat arası görevlendirmeye gidiyor1.250 euro harcırah alıyor. 48 günün 31 günü ocak ayına ait 17 günü şubat ayına ait günlük harcırah tutarı 26 euro olacak şekilde ocak ayına 807 euro şubat ayına 443 euro harcırah miktarı geliyor.

İkinci durumda ise çalışan 9 şubatta göreve gidiyor ve 26 Temmuz da dönüyor. 1.950 USD harcırah alacak. 1950 usd harcırah ın 9 şubat - 26 temmuz arasındaki aylara gün esas alınarak dağıtılması gerekiyor.

Bu iki durum için yardımcı olursanız çok memnun olurum. Aşağıda yardımcı olması açısından örnek olayların excel dökümünü paylaşıyorum


Teşekkürler

 

[çıtır]

F7 kopyalayınız.Yeterince sağa ve aşağı doğru çoğaltınız.

=EĞERHATA($D7/($C7-$B7)*MAK(0;MİN($C7-1;SERİAY(TARİHSAYISI(1&F$5&YIL($C7));0))-MAK($B7;TARİHSAYISI(1&F$5&YIL($C7)))+1);"")

=IFERROR($D7/($C7-$B7)*MAX(0,MIN($C7-1,EOMONTH(DATEVALUE(1&F$5&YEAR($C7)),0))-MAX($B7,DATEVALUE(1&F$5&YEAR($C7)))+1),"")

 

[murat.yildirim]

Hocam merhaba,
dosyayı şu şekilde güncellesem ayları üst kısımdaki ay isimlerinden değil de 1,2 ve 3 gibi ay isimlerinden alsa

 

[çıtır]

F7 kopyalayınız.Yeterince sağa ve aşağı doğru çoğaltınız.

=IFERROR($D7*VLOOKUP($E7,$B$1:$C$2,2,0)/($C7-$B7)*MAX(0,MIN($C7-1,EOMONTH(TEXT(YEAR($C7)&F$6&"1","0000-0-0")+0,0))-MAX($B7,TEXT(YEAR($C7)&F$6&"1","0000-0-0")+0)+1),"")

 

[Korhan Ayhan]

Alternatif,

Y7;

(İngilizce)

=$Q7/(DATE(YEAR($M7);MONTH($M7);DAY($M7))-DATE(YEAR($L7);MONTH($L7);DAY($L7)))*IF(OR(MONTH(DATEVALUE("1."&Y$6&"."&YEAR($L7)))<MONTH($L7);MONTH(DATEVALUE("1."&Y$6&"."&YEAR($L7)))>MONTH($M7));0;IF(EOMONTH(DATEVALUE("1."&Y$6&"."&YEAR($L7));0)<=DATE(YEAR($M7);MONTH($M7);DAY($M7));EOMONTH(DATEVALUE("1."&Y$6&"."&YEAR($L7));0);DATE(YEAR($M7);MONTH($M7);DAY($M7))-1)-IF(DATEVALUE("1."&Y$6&"."&YEAR($L7))>=DATE(YEAR($L7);MONTH($L7);DAY($L7));DATEVALUE("1."&Y$6&"."&YEAR($L7));DATE(YEAR($L7);MONTH($L7);DAY($L7)))+IF(EOMONTH(DATEVALUE("1."&Y$6&"."&YEAR($L7));0)=DATE(YEAR($M7);MONTH($M7);DAY($M7));0;1))/VLOOKUP($R7;$A$1:$B$2;2;0)

(Türkçe)

=$Q7/(TARİH(YIL($M7);AY($M7);GÜN($M7))-TARİH(YIL($L7);AY($L7);GÜN($L7)))*EĞER(YADA(AY(TARİHSAYISI("1."&Y$6&"."&YIL($L7)))<AY($L7);AY(TARİHSAYISI("1."&Y$6&"."&YIL($L7)))>AY($M7));0;EĞER(SERİAY(TARİHSAYISI("1."&Y$6&"."&YIL($L7));0)<=TARİH(YIL($M7);AY($M7);GÜN($M7));SERİAY(TARİHSAYISI("1."&Y$6&"."&YIL($L7));0);TARİH(YIL($M7);AY($M7);GÜN($M7))-1)-EĞER(TARİHSAYISI("1."&Y$6&"."&YIL($L7))>=TARİH(YIL($L7);AY($L7);GÜN($L7));TARİHSAYISI("1."&Y$6&"."&YIL($L7));TARİH(YIL($L7);AY($L7);GÜN($L7)))+EĞER(SERİAY(TARİHSAYISI("1."&Y$6&"."&YIL($L7));0)=TARİH(YIL($M7);AY($M7);GÜN($M7));0;1))/DÜŞEYARA($R7;$A$1:$B$2;2;0)

 

[murat.yildirim]

teşekkürler sayenizde halletim.

 

[murat.yildirim]

merhaba
Formül ihtiyacı tam karşılamadı ayın son günlerinde hata veriyor ve para birimi boş geldiğinde false veriyor.

 

[çıtır]

Sayın murat.yildirim
Formülde 10.Aydan itibaren hata olmuş.Düzelterek dosya ekledim.Hata varmı bakar mısınız?

 

[çıtır]

teşekkürler sayenizde halletim.

Dönüş yaptığınız için teşekkürler.

 

[murat.yildirim]

Hocam hata var en soldaki ctrl alanı kontrol noktası olarak hata veriyor ben kendimce düzellttim fakat yine olmadı

 

[Korhan Ayhan]

Merhaba Murat Bey,

Son eklediğiniz dosyaya göre #5 nolu mesajımdaki formülü revize ettim. Tekrar deneyip sonucu bildirir misiniz?

 

[murat.yildirim]

Teşekkürler Korhan Bey çalıştı formül

 

[çıtır]

Sayın murat.yildirim
hacırah USD de alındığında düşüyor.EUR alındığında sabit mi kalıyor du ben tam tersi düşünmüşdüm. Siz galiba benim gibi USD ye sevmiyenlerdensiniz bizde çarpıyı bölü yaparız olur.Ne dersiniz.

=EĞERHATA($Q7/DÜŞEYARA($R7;$A$1:$B$2;2;0)/($M7-$L7)*MAK(0;MİN($M7-1;SERİAY(METNEÇEVİR(YIL($M7)&SAĞDAN("0"&Y$6;2)&"01";"0000-00-00")+0;0))-MAK($L7;METNEÇEVİR(YIL($M7)&SAĞDAN("0"&Y$6;2)&"01";"0000-00-00")+0)+1);"")