ay kaç gün çeker

[vitaminb1]

ben bir hücreye ay yazdığım zaman yanındaki hücreye kaç gün çektiğini onun yanındaki hücreyede o ayın başlangıç ve bitiş tarihlerini otamatik olarak yazdırabilirmiyim.
ÖRN:A1MART yazdığım zaman B131 C101.03.2009-31.03.2009 yazsın.

 

[uzmanamele]

merhaba
buraya bakınız

http://www.excel.web.tr/f60/tarih-zaman-saat-fonksiyonlar-uygulamalar-t18175.html

 

[Necdet]

Merhaba,

A1 e doğrudan tarih yazsanız, ya da ay kodu yazsanız işlemler daha yalın olurdu

Sadece A1 e Ayın adını yazmalısınız.


B1

=TARİH(YIL(BUGÜN());ARA(A1;{"Ağustos";"Aralık";"Ekim";"Eylül";"Haziran";"Kasım";"Mart";"Mayıs";"Nisan";"Ocak";"Şubat";"Temmuz"};{8\12\10\9\6\11\3\5\4\1\2\7}+1);0)
=DATE(YEAR(TODAY());LOOKUP(A1;{"Ağustos";"Aralık";"Ekim";"Eylül";"Haziran";"Kasım";"Mart";"Mayıs";"Nisan";"Ocak";"Şubat";"Temmuz"};{8\12\10\9\6\11\3\5\4\1\2\7}+1);0)

C1

=TARİH(YIL(BUGÜN());ARA(A1;{"Ağustos";"Aralık";"Ekim";"Eylül";"Haziran";"Kasım";"Mart";"Mayıs";"Nisan";"Ocak";"Şubat";"Temmuz"};{8\12\10\9\6\11\3\5\4\1\2\7});1)
=DATE(YEAR(TODAY());LOOKUP(A1;{"Ağustos";"Aralık";"Ekim";"Eylül";"Haziran";"Kasım";"Mart";"Mayıs";"Nisan";"Ocak";"Şubat";"Temmuz"};{8\12\10\9\6\11\3\5\4\1\2\7});1)

D1......AG1

=EĞER(AY($C$1+SÜTUN()-3)=AY($C$1);$C$1+SÜTUN()-3;"")
=IF(MONTH($C$1+COLUMN()-3)=MONTH($C$1);$C$1+COLUMN()-3;"")

 

[Necdet]

Herhalde yararlı olmadı yanıt tık çıkmadığına göre...

 

[vitaminb1]

üstad işim çoktu daha önceki caevabınıza baktım ama inceleyememiştim.az önce inceledim gün sayısı ve ayın ilk günü yazıyor. ayın son gününü yazdıramadım.mesala d1 31.03.2009 nasıl yazılır.yarın tekrar inceleyeceğim

 

[Merhum İdris SERDAR]

ben bir hücreye ay yazdığım zaman yanındaki hücreye kaç gün çektiğini onun yanındaki hücreyede o ayın başlangıç ve bitiş tarihlerini otamatik olarak yazdırabilirmiyim.
ÖRN:A1MART yazdığım zaman B131 C101.03.2009-31.03.2009 yazsın.

A1 hücresinde bir tarih varsa;

Kaç gün çektiği için:

=DAY(DATE(YEAR(A1);MONTH(A1)+1;0))
=GÜN(TARİH(YIL(A1);AY(A1)+1;0))


Ayın ilk günü için:

=DATE(YEAR(A1);MONTH(A1);1)
=TARİH(YIL(A1);AY(A1);1)

Ayın son günü için:

=DATE(YEAR(A1);MONTH(A1)+1;0)
=TARİH(YIL(A1);AY(A1)+1;0)

İlk gün ve son gün birleşik yazım için:

=TEXT(DATE(YEAR(A1);MONTH(A1);1);"gg.aa.yyyy")&" - "&TEXT( DATE(YEAR(A1);MONTH(A1)+1;0);"gg.aa.yyyy")

=METNEÇEVİR(TARİH(YIL(A1);AY(A1);1);"gg.aa.yyyy")&" - "&METNEÇEVİR( TARİH(YIL(A1);AY(A1)+1;0);"gg.aa.yyyy")


formüllerini kullanın.




.

 

[a.akyurek]

ben bir hücreye ay yazdığım zaman yanındaki hücreye kaç gün çektiğini onun yanındaki hücreyede o ayın başlangıç ve bitiş tarihlerini otamatik olarak yazdırabilirmiyim.
ÖRN:A1MART yazdığım zaman B131 C101.03.2009-31.03.2009 yazsın.

A1: MART

B1:

=("1-"&A1&"-"&YEAR(TODAY()))+0

=("1-"&A1&"-"&YIL(BUGÜN()))+0

C1:

=DATE(YEAR(B1),MONTH(B1)+1,1)-1

=TARİH(YIL(B1);AY(B1)+1;1)-1

yada

=TARİH(YIL(B1);AY(B1)+1;0)

D1:

=DAY(C1)

=GÜN(C1)

 

[haso_excel]

=DAY(EOMONTH(A1;0)) bu formul ilgili ayın kaçgün olduğunu gösterir size

 

[vitaminb1]

cevaplarınız için teşekkürler.

 

[aysebay]

Merhaba Arkadaşlar bir hücreye örneğin 01.08.2009 yazdığımda başka bir hücreye AĞUSTOS yazacak bir formül var mıdır?

 

[uzmanamele]

Merhaba Arkadaşlar bir hücreye örneğin 01.08.2009 yazdığımda başka bir hücreye AĞUSTOS yazacak bir formül var mıdır?

merhaba
tarih A1 de yazıyorsa, B1 hücreye
=A1 yazıp hücre biçimini aaaa yapınız.

 

[Necdet]

B1
=("1-"&A1&"-"&YEAR(TODAY()))+0

40 Yıl düşünsem aklıma gelmezdi, Teşekkürler Sayın Akyürek

 

[Orion1]

A1: MART

B1:

=("1-"&A1&"-"&YEAR(TODAY()))+0

=("1-"&A1&"-"&YIL(BUGÜN()))+0

Süper.
Teşekkürler sayın a.akyürek

 

[kayıphalka]

çeker ocak hakkında bilgi verebilir misiniz?