Aranan Verilerin Adreslerini Bulmak

[baydeniro]

Merhaba arkadaşlar. RAPOR sayfasında A1 ve A2 (sadece tek seçim de olabilir) yazılı verilerin DATA sayfasında bulunduğu adresleri RAPOR sayfasına yazılması mümkün mü ? Örnek dosya ekte.

 

[Necdet]

Merhaba,

Aranan sözcükleri RAPOR sayfasında 1. satıra sütunlara dağıtarak yazınız.

Sub AraBulAdresGoster()
    
    Dim i   As Long
    Dim j   As Integer, _
        Kol As Integer
    Dim c   As Range
    Dim Adr As String
    Dim sr  As Worksheet, _
        sd  As Worksheet
    
    Set sd = Sheets("DATA")
    Set sr = Sheets("RAPOR")
    
    Application.ScreenUpdating = False
    
    sr.Select
    
    Kol = sr.Cells.Find("*", , , , xlByColumns, xlPrevious).Column
    i = sr.Cells.Find("*", , , , xlByRows, xlPrevious).Row + 1
    
    sr.Range(sr.Cells(2, "A"), sr.Cells(i, Kol)).ClearContents
    
    For j = 1 To Kol
        i = 1
        With sd.Cells
            Set c = .Find(sr.Cells(1, j), LookIn:=xlValues)
            If Not c Is Nothing Then
                Adr = c.Address
                Do
                    i = i + 1
                    sr.Cells(i, j) = sd.Name & "!" & c.Address
                    Set c = .FindNext(c)
                Loop While Not c Is Nothing And c.Address <> Adr
            End If
        End With
    Next j
    
    Application.ScreenUpdating = True
    MsgBox "İşlem Tamamlanmıştır....", vbInformation
    
End Sub

 

[baydeniro]

Sayın Necdet Yeşertener, büyüksünüz vesselam. Çok çok teşekkür ederim. Allah sizleri yetiştirenlerden razı olsun. Sağlıcakla kalın.

 

[Necdet]

Sayın Necdet Yeşertener, büyüksünüz vesselam. Çok çok teşekkür ederim. Allah sizleri yetiştirenlerden razı olsun. Sağlıcakla kalın.

Güle güle kullanınız.