A-Z yerine karışık sıralama

[ahmet_mzb]

arkadaşlar bu sizin için heralde basit bir sorudur ama ben saatlerce ugrastım bi sonuç elde edemedim. sıradan bir soru sormak sevmedigim biseydir, konu açmadan forumlarda cevap aradım ama nasıl aratırsam aratayım binlerce konu çıkıyor karşıma


sormak istedigim soru excelde a'dan z'ye yada z'den a'ya sıralama var ama bana karışık olan bir sıralama yani rastgele olan bir sıralama lazım. ama excel burada ornek verdigim gibi yapıyor hep. yardım ederseniz müteşekkir olurum.


ali
ali
ali
ali
ali dogan
ayhan
bekir
bekir
bekir
beşir
bilal
bilal
bülent
cihangir
çapan
dagan kaya
dursun
dursun
ekrem
ekrem
emre
emrullah
ercan
erdal
erdal
erdal
ersin
esin
ethem
eyüp
faruk
fatih
fatih

 

[Necdet]

Merhaba,

Dosyayı B sütununa göre sıralayabilirsiniz.

Analiys ToolPack eklemelisiniz.

 

[Orion1]

Dosyanız ektedir.

Sub mikser()
Dim sat As Long, col As Collection, i As Long, indis
Randomize Timer
sat = Cells(65536, "A").End(xlUp).Row
Set col = New Collection
For i = 1 To sat
    col.Add Cells(i, "A").Value
Next
Range("A1:A" & sat).ClearContents
i = 0
Do While col.Count > 0
    i = i + 1
    indis = Int(Rnd() * col.Count) + 1
    Cells(i, "A").Value = col(indis)
    col.Remove (indis)
Loop
MsgBox "Rastgele atama yapıldı." & vbLf & _
"evrengizlen@hotmail.com", vbOKOnly + vbInformation, "E V R E N"
End Sub

 

[ahmet_mzb]

arkadaşlar çok sağolun. 1 haftadır belgemi tamamlayamıyordum bu yuzden. size ne kadar teşekkür etsem az. emegize saglık.

 

[Orion1]

arkadaşlar çok sağolun. 1 haftadır belgemi tamamlayamıyordum bu yuzden. size ne kadar teşekkür etsem az. emegize saglık.

Rica ederim.
İyi çalışmalar.

 

[tagayyur]

karışık sıralama

Saygıdeğer Orion Hocam,

Hazırladığınız dosyayı inceledim. Ama malesef makroları anlayamıyorum.
Elimde ingilizce kelimeleri yazdığım bir dosya var.
Karışık sıralama makrosunu bu dosyaya da uygularsanız çok minnettar kalırım.

hayatınızda başarılar dilerim.

 

[Necdet]

Merhaba,

Sayın orion1'in kodları baya bir profesyonel kodlar.

Aşağıdaki basit kodları öneririm.

İlk boş sütuna rastgele sayı ürettirip. bu sütuna göre sıralama yaptırdım.
Sonra formül yazdırdığım yani geçici olarak kullandığım sütunu sildim.

Kodlarda bunu yapar. Kod bilmezseniz bile bu yöntemi kullanabilirsiniz.
Her F9 hücresine bastığınızda bu rakamlar değişir, dolayısıyla değişik sıralama yaptırmak olasıdır.

Sub Karistir()
    
    Dim Kol As Integer
    Dim i   As Long
    
    'Ekrandaki değişiklikleri gösterme
    Application.ScreenUpdating = False
    '1. satırdaki son kolonu bul
    Kol = Cells(1, Columns.Count).End(1).Column + 1
    'Sütundaki son satırı bul
    i = Cells(Rows.Count, "A").End(3).Row
    '1. satırda ilk boş hücreye sayı üreten formül yazıldı
    Cells(1, Kol).Formula = "=RAND()"
    '1. satıra yazılan formül diğer satırlara kopyalandı
    Range(Cells(1, Kol), Cells(i, Kol)).FillDown
    'Formül yazılan sütun dahil tüm belge formül yazılan sütuna göre sıralandı
    Range(Cells(1, 1), Cells(i, Kol)).Sort Key1:=Cells(1, Kol)
    'Formül Yazılan, Geçici olarak kullanılan sütun silindi
    Range(Cells(1, Kol), Cells(i, Kol)).ClearContents
    'Artık ekrandaki değişikliği göstermeye izin ver
    Application.ScreenUpdating = True
    
End Sub