A-B sütunu ile D-E sütunun karşılaştırılması

[metinavci23]

Arkadaşalar başlıkta bahsettiğim gibi ben A-B ile D-E sütünü karşılaştırmak istiyorum.tutmayanlar var ise diğer sayfaya aktarılmasını istiyorum.Şİmdiden herkese teşekkür ederim.YArdım edeceğinizden eminim.

 

[Erdal]

Merhabalar
Formül işinizi görmez mi?

 

[metinavci23]

cevap

Erdal Bey elbette formul olur yalnız fatura adetim çok fazla.binlerce satır.formul ile biraz ağır olur sanki.ama yine de siz formulleri yazın.bakalım nasıl olacak.

 

[Erdal]

Merhabalar
örneği inceleyin.
İyi çalışmalar

 

[metinavci23]

cevap

Erdal Bey çok teşekkür ederim ama makro ile benim işim çok daha iyi olur.elinize sağlık.umarım yardım eden arkadaş çıkar.bu yazılacak nakroyu başka tablolarda kullanıcağım.o yüzden makro tercih ediyorum

 

[Korhan Ayhan]

Selamlar,

Aşağıdaki kodu denermisiniz.

Option Explicit
 
Sub FATURA_NO_TUTMAYANLARI_AKTAR()
    Dim S1 As Worksheet, S2 As Worksheet
    Dim BUL As Range, ADRES As String
    Dim X As Long, SAY As Integer, SATIR As Long
    
    Set S1 = Sheets("kontrol")
    Set S2 = Sheets("tutmayanlar")
    
    S2.Range("A2:B65536").ClearContents
    SATIR = 2
    
    For X = 2 To S1.Range("A65536").End(3).Row
        Set BUL = S1.Range("D:D").Find(S1.Cells(X, 1), , , xlWhole)
        If Not BUL Is Nothing Then
            ADRES = BUL.Address
            Do
                If S1.Cells(X, 2) = BUL.Offset(0, 1) Then SAY = SAY + 1
        
        Set BUL = S1.Range("D:D").FindNext(BUL)
        Loop While Not BUL Is Nothing And BUL.Address <> ADRES
        End If
        
        If SAY = 0 Then
        S2.Cells(SATIR, 1) = S1.Cells(X, 1)
        S2.Cells(SATIR, 2) = S1.Cells(X, 2)
        SATIR = SATIR + 1
        End If
        SAY = 0
    Next
    
    S2.Select
    
    Set BUL = Nothing
    Set S1 = Nothing
    Set S2 = Nothing
    
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[metinavci23]

cevap

teşekkürler Korhan Bey.elinize sağlık