Soru 6 adet Excel dosyam var, C sütunundaki rakamları, 7. excel dosyasına toplayarak aktarsın

[serdarexe]

Merhaba, 6 adet excel dosyam var tablo şablon hepsinde aynı, C sütunundaki rakamları, 7. excel dosyama toplayarak aktarsın hepsi aynı klasörde lütfen bu konu hakkında bana yardımcı olur musunuz

 

[Muzaffer Ali]

Merhaba.
Toplamları Al butonuna tıklamanız yeterli.
Klasör seçmeniz istenecek seçtiğiniz klasördeki tüm dosyaların C sütunu toplanacaktır.

Ekteki dosya toplamı alınacak dosyalar ile aynı klasörde olmamalı.

 

[serdarexe]

Çok Teşekkür ederim ellerinize sağlık

 

[Muzaffer Ali]

Rica ederim. Kolay gelsin.

 

[Korhan Ayhan]

Alternatif olarak POWER QUERY kullanabilirsiniz.

Avantajı klasöre dosya eklenip-çıksada tablonuzu sadece güncelle diyerek dinamik bir tablo oluşturabilirsiniz.


Kullanmak isterseniz aşağıdaki adımları izleyebilirsiniz.

Klasörde sadece veri alınacak dosyalarınız olsun.
Sonrasında boş bir dosya açınız.
ALT+F12 ile POWER QUERY editörünü açınız.
HOME menüsünden NEW SOURCE-OTHER SOURCE-BLANK QUERY seçeneğini seçiniz.
Pencerenin sol kısmında BOŞ query oluşacaktır. Bu query üzerinde sağ tıklayıp RENAME diyerek adını RAPOR yapıp ENTER yapınız.
RAPOR sorgusunda tekrar sağ tıklayıp "ADWANCED EDITOR" seçeneğini seçiniz.
Karşınıza gelen penceredeki kodları seçerek siliniz. Yerine aşağıdaki kodu yapıştırınız.

Sadece kod içindeki ilk satırdaki dosya yolunu kendi sisteminize göre uyarlayınız. Bu aşamadan sonra DONE tuşuna basınız.

"C:\Belgelerim\deneme"

Zaten adımları doğru yaparsanız karşınıza veriler gelecektir.

Şimdi HOME menüsüne tıklayınız.
MEnünün en başında CLOSE & LOAD seçeneği var. Bu seçeneğin sağ altında bir ok işareti var. Ona tıkladığınızda karşınıza 2 seçenek gelecek. CLOSED & LOAD TO... yazan seçeneğe tıklayınız. Karşınıza gelen pencerede TABLE seçeneğini seçip OK diyerek işlemi tamamlayınız. Artık tüm veriler özet olarak karşınıza gelecektir.

Bu tablo üzerinde sağ tıklayıp REFRESH (YENİLE) diyebilirsiniz. Ya da tablodan herhangibir hücreye tıkladıktan sonra ALT+F5 yapabilirsiniz. Böylece tablonuz klasördeki en güncel verileri alacaktır.

Kullanım örnekleri için izleyebilirsiniz.

Youtube

let
    Source = Folder.Files("C:\Belgelerim\deneme"),
    Data = Table.Combine(
        Table.AddColumn(
            Table.SelectRows(Source, each [Attributes]?[Hidden]? <> true),
            "Data",
            each Table.SelectRows(Excel.Workbook([Content], null, true), each [Kind] = "Sheet"){0}[Data]
        )[Data]
    ),
    Filtered = Table.SelectRows(Data, each not Text.Contains(Text.From([Column2]), "TOPLAM")),
    Headers = Table.PromoteHeaders(Filtered, [PromoteAllScalars=true]),
    Rows = Table.SelectRows(Headers, each [#"S.NO."] <> "S.NO."),
   
    // Sadece POLİKLİNİK ADI ve BEKLEYEN SEVK SAYISI sütunlarını al
    #"Sütun Seç" = Table.SelectColumns(Rows, {"POLİKLİNİK ADI", "BEKLEYEN SEVK SAYISI"}),
   
    // BEKLEYEN SEVK SAYISI'nı sayıya çevir
    #"Tip Değiştir" = Table.TransformColumnTypes(#"Sütun Seç", {{"BEKLEYEN SEVK SAYISI", Int64.Type}}),
   
    // POLİKLİNİK ADI'na göre grupla ve topla
    #"Grupla ve Topla" = Table.Group(#"Tip Değiştir", {"POLİKLİNİK ADI"}, {
        {"TOPLAM", each List.Sum([BEKLEYEN SEVK SAYISI]), type number}
    }),
   
    // Boş veya null değerleri temizle
    #"Boşları Temizle" = Table.SelectRows(#"Grupla ve Topla", each [POLİKLİNİK ADI] <> null and [POLİKLİNİK ADI] <> ""),
   
    // TOPLAM'a göre büyükten küçüğe sırala
    #"Sırala" = Table.Sort(#"Boşları Temizle", {{"TOPLAM", Order.Descending}}),
   
    // Sıra numarası ekle (1'den başlayarak)
    #"Sıra Numarası Ekle" = Table.AddIndexColumn(#"Sırala", "S.NO", 1, 1),
   
    // Sütunları yeniden düzenle (S.NO, POLİKLİNİK ADI, TOPLAM)
    #"Sütunları Düzenle" = Table.ReorderColumns(#"Sıra Numarası Ekle", {"S.NO", "POLİKLİNİK ADI", "TOPLAM"})
in
    #"Sütunları Düzenle"