Soru 2 Farklı koşul ile tablodan veri çekmek

[Melih KAYA]

Merhaba, aşağıda örneğini verdiğim durum için formül yazımın da yardımcı olabilir misiniz?
Tablo 1 de yer alan değerlere göre tablo 2 de B2 ve C3 hücrelerine formül ile veri atayamadım.
Not 1: Tablo 1 "B" ve "C" sütunlarında bulunan veriler açılır listeden gelmekte.
Not 2: Tablo2 "A" sütunu tablo 1 den formül ile gelmektedir.

Tablo 1 Genel veriler

	A	B	C
1	Araç Adı	Yakıt türü	Motor Tipi
2	X	Motorin	2R
3	X	Benzin	1R
4	Q	Benzin	3R
5	Q	Motorin	2R

Tablo 2

	A	B	C
1	Araç Adı	Motorin motor tipi	Benzin motor tipi
2	X	?	?
3	Q	?	?

 

[Korhan Ayhan]

Merhaba,

Kullandığınız sürümde ÇAPRAZARA fonksiyonu varsa deneyiniz.

B2;

=ÇAPRAZARA(1;(Sheet1!$A$1:$A$5=$A2)*(SOLDAN(Sheet1!$B$1:$B$5;7)="Motorin");Sheet1!$C$1:$C$5)

C2;

=ÇAPRAZARA(1;(Sheet1!$A$1:$A$5=$A2)*(SOLDAN(Sheet1!$B$1:$B$5;6)="Benzin");Sheet1!$C$1:$C$5)

 

[Korhan Ayhan]

Bu da eski sürümler için alternatif...

B2;

=İNDİS(Sheet1!C$1:C$5;TOPLAMA(15;6;SATIR(Sheet1!A$1:A$5)/((Sheet1!A$1:A$5=$A2)*(SOLDAN(Sheet1!B$1:B$5;7)="Motorin"));1))

C2;

=İNDİS(Sheet1!C$1:C$5;TOPLAMA(15;6;SATIR(Sheet1!A$1:A$5)/((Sheet1!A$1:A$5=$A2)*(SOLDAN(Sheet1!B$1:B$5;6)="Benzin"));1))

 

[Melih KAYA]

Korhan Bey,
Cevaplarınız için çok teşekkür ederim. Eski sürüm olduğu için indis olarak verdiğiniz formülü kullandım.

İlk cevabımı yazarken formülün hatalı olduğu şeklinde bir yazım yapmışım kusura bakmayın.

Teşekkür ederim.