2 sütun karşılaştırması

[modoste]

merhabalar sayın hocalarım
Sayın İdris Serdar hocamızın paylaşmış olduğu 2 sütun karşılaştırma dosyasını
kendi dosyamın içine ekleyerek sonuçlar almaya çalıştım.

sorum ise 2 Sütun Karş. sekmesindeki E-F-G-H-I-J-K sekmelerinde formüllerle bulunmuş olan sonuçların [boşluksuz ve benzersiz] olarak listelenmesidir.

 

[Ali]

Eğer doğru anladı isem

J4 hücresindeki formül yerine

=EĞERHATA(İNDİS(C$4:C$100;KAÇINCI(DOĞRU;EĞERSAY(D$4:D$100;C$4:C$100)*DEĞİL(EĞERSAY($J$3:J3;C$4:C$100))>0;0));"")

yazıp CTRL+SHIFT+ENTER tuşlarına basarak dizi formülü oluşturup aşağı doğru çekiniz.

 

[modoste]

sayın Ali hocam sadece J sütununda değil E-F-G-H-I-K sütunlarında bulunan sonuçlarında boşluksuz ve benzersiz olarak listelenmesi isteğim şey

J4 formülü uyguladım sonuç doğru sonuç vermedi sayın Ali Hocam

 

[Ali]

Liste1'de Benzersiz

E4 hücresine

=EĞERHATA(İNDİS(C$4:C$100;KAÇINCI(0;EĞER(C$4:C$100<>"";EĞER(C$4:C$100<>"";EĞERSAY(E$3:E3;C$4:C$100)));0));"")

yazıp CTRL+SHIFT+ENTER tuşlarına basarak dizi formülü oluşturup aşağı doğru çekiniz.

Liste2'de Benzersiz

=EĞERHATA(İNDİS(D$4:D$100;KAÇINCI(0;EĞER(D$4:D$100<>"";EĞER(D$4:D$100<>"";EĞERSAY(F$3:F3;D$4:D$100)));0));"")

yazıp CTRL+SHIFT+ENTER tuşlarına basarak dizi formülü oluşturup aşağı doğru çekiniz.

İki Listede ortak olan (Boşluksuz)

=EĞERHATA(İNDİS(C$4:C$100;KAÇINCI(DOĞRU;EĞERSAY(D$4:D$100;C$4:C$100)*DEĞİL(EĞERSAY($J$3:J3;C$4:C$100))>0;0));"")

yazıp CTRL+SHIFT+ENTER tuşlarına basarak dizi formülü oluşturup aşağı doğru çekiniz.

Diğerlerine vaktim olduğunda bakarım.

 

[modoste]

diğerlerinide bekliyorum hocam çözümleri uyguladım sonuçlar doğru
özellikle K4 deki formül en önemlisi Ali Hocam

 

[Ali]

diğerlerinide bekliyorum hocam çözümleri uyguladım sonuçlar doğru
özellikle K4 deki formül en önemlisi Ali Hocam

O önemli ise onuda cevaplayalım.

İki Listede benzersiz olan

K3 hücresini sil orası boş olsun.

K4 hücresine

=EĞERHATA(EĞERHATA(İNDİS($C$4:$C$100;KAÇINCI(0;EĞERSAY($K$3:K3;$C$4:$C$100);0));İNDİS($D$4:$D$100;KAÇINCI(0;EĞERSAY($K$3:K3;$D$4:$D$100);0)));"")

yazıp CTRL+SHIFT+ENTER tuşlarına basarak dizi formülü oluşturup aşağı doğru çekiniz.

 

[modoste]

Teşekkür ederim Ali Hocam
son formülüde uyguladım sonuçlar tam oldu
G-H-I daki formüller için çözümünüzü bekliyorum hocam

 

[Ali]

G nin cevabını vermiştim.

İki Listede ortak olan (Boşluksuz) kısmında 4. nolu mesajda.

 

[Ali]

Liste-1 de olup Liste-2 de olmayan

Sizin dosyanızda Liste 1'in hepsi Liste2 de var boş gelebilir farklı değer olduğunda gözükecektir.

=EĞERHATA(İNDİS($C$4:$C$100;KÜÇÜK(EĞER(SIKLIK(EĞER($C$4:$C$100<>"";EĞER(1-ESAYIYSA(KAÇINCI($C$4:$C$100;$D$4:$D$100;0));KAÇINCI($C$4:$C$100;$C$4:$C$100;0)));SATIR($C$4:$C$100)-SATIR($C$4)+1);SATIR($C$4:$C$100)-SATIR($C$4)+1);SATIRSAY(H$4:H4)));"")

yazıp CTRL+SHIFT+ENTER tuşlarına basarak dizi formülü oluşturup aşağı doğru çekiniz.

Liste-2 de olup Liste-1 de olmayan

=EĞERHATA(İNDİS($D$4:$D$100;KÜÇÜK(EĞER(SIKLIK(EĞER($D$4:$D$100<>"";EĞER(1-ESAYIYSA(KAÇINCI($D$4:$D$100;$C$4:$C$100;0));KAÇINCI($D$4:$D$100;$D$4:$D$100;0)));SATIR($D$4:$D$100)-SATIR($D$4)+1);SATIR($D$4:$D$100)-SATIR($D$4)+1);SATIRSAY(I$4:I4)));"")

yazıp CTRL+SHIFT+ENTER tuşlarına basarak dizi formülü oluşturup aşağı doğru çekiniz.

 

[modoste]

Sayın Ali Hocam
çok teşekkür ederim emeğinize sağlık hocam
sizin excel ile ilgili özel çalışmalarınız veyahut sizi takip edebileceğim bir site var mıdır.
Sayın İdris Hocamı takip ediyorum sizide takip etmek isterim.

 

[modoste]

Sayın Ali Hocam bu soru grubuna girer diye buraya sormak istedim
3 Sütunda verileri tek bir sütunda benzersiz listelemesi (Kesişimlerini) ve (Birleşimlerini)

 

[Ali]

3 sütunda ortak olanların benzersiz listesi

Veriler A1:C10 aralığında ise ve F2 hücresinden itibaren listeleyeceğinizi varsayarak,

=EĞERHATA(İNDİS(A$1:A$100;KAÇINCI(DOĞRU;EĞERSAY(B$1:B$100;A$1:A$100)*EĞERSAY(C$1:C$100;A$1:A$100) *DEĞİL(EĞERSAY($F$1:F1;A$1:A$100))>0;0));"")

yazıp CTRL+SHIFT+ENTER tuşlarına basarak dizi formülü oluşturup aşağı doğru çekiniz.

 

[Ali]

3 sütunda ortak olanların listesi

D1 hücresine 0 (sıfır) yazın

D2 hücresine aşağıdaki formülü

=EĞERHATA(EĞERHATA(EĞERHATA(İNDİS($A$1:$A$100;KAÇINCI(0;EĞERSAY($D$1:D1;$A$1:$A$100);0));İNDİS($B$1:$B$100;KAÇINCI(0; EĞERSAY($D$1:D1;$B$1:$B$100);0)));İNDİS($C$1:$C$100;KAÇINCI(0;EĞERSAY($D$1:D1;$C$1:$C$100); 0)));"")

yazıp CTRL+SHIFT+ENTER tuşlarına basarak dizi formülü oluşturup aşağı doğru çekiniz.

 

[modoste]

sayın ali hocam dediklerinizi uyguladım sonuçlar tam
2 sütunda yada 3 sütunda kesişim ve birleşim işlemlerinin boşluksuz sıralamalsını yaparken verilerin olduğu sütunları birleşik yazdık
mesela verilerin biri A3:A10 arasında diğeri D310 arasında bir sonrakide K3:K10 arasında olursa bu durumda çözümler yapabilir miyiz.

 

[Ali]

Farklı sütunlarda olmasının sakıncası yok.

3 sütunda ortak olanların listesi örneği için

Bir kısmı A sütununda, Bir kısmı D sütununda diğer ver K sütununda olsun.

M2 hücresinden aşağı doğru listeleneceğini varsayalım.

M1 hücresine 0(sıfır) yazın

M2 hücresine

=EĞERHATA(EĞERHATA(EĞERHATA(İNDİS($A$1:$A$100;KAÇINCI(0;EĞERSAY($M$1:M1;$A$1:$A$100);0));İNDİS($D$1:$D$100;KAÇINCI(0; EĞERSAY($M$1:M1;$D$1:$D$100);0)));İNDİS($K$1:$K$100;KAÇINCI(0;EĞERSAY($M$1:M1;$K$1:$K$100); 0)));"")

yazıp CTRL+SHIFT+ENTER tuşlarına basarak dizi formülü oluşturup aşağı doğru çekiniz.

 

[modoste]

sayın hocam verdiğiniz formül 3 sütunda birleşimin benzersiz formülü oldu
3 sütunda kesişim için olan formülü yazabilir misiniz.

 

[mhaluksen]

sayın Ali hocam dediğiniz formüllerin bitik halini excel de uygulanmış dosya halinde atabilir misiniz? Şimdiden çok teşekkürler

 

[Ali]

Sn mhaluksen

Müsait olduğum bir zaman toplu bir dosya haline getireyim.

 

[Ali]

3 sütunda kesişim için olan formülü yazabilir misiniz.

D1 hücresinde 0 olsun

D2 hücresine

=EĞERHATA(EĞERHATA(EĞERHATA(İNDİS($A$2:$A$100;KAÇINCI(0;EĞERSAY(D$1:$D1;$A$2:$A$100);0));İNDİS($B$2:$B$100;KAÇINCI(0;EĞERSAY(D$1:$D1;$B$2:$B$100);0)));İNDİS($C$2:$C$100;KAÇINCI(0;EĞERSAY(D$1:$D1;$C$2:$C$100);0)));"")

yazıp CTRL+SHIFT+ENTER tuşlarına basarak dizi formülü oluşturup aşağı doğru çekiniz.

 

[modoste]

sayın Ali hocam 19 nolu mesajınızdaki formül veriler A-B-C de ise yani sütunlar bitişik iken oldu
(çok cevap yazdığınızdan karıştı hocam herhalde)

15 nolu mesajınızda veriler A-D-k sütunlarında iken 3 sütun için kesişim formülünü yazabilir misiniz
15 nolu mesajdaki formülünüz 3 sütunda birleşim formülü idi bunun kesişim olanı gerekiyor Sayın Hocam