Şarta Bağlı Eğersay...

[altan888]

Merhabalar, Sağdaki Ödeme listesini üstteki vade aralığına göre, soldaki çok uzun Fatura listesinde olan firma isimlerini mükerrer olmayacak şekilde listelemek istiyorum, ancak çok uğraştığım halde ya eksik firma ismi geliyor ya da mükerrer isimler listeleniyor, manuel yaptığım ve kırmızıya boyadığım olması gerekenleri getirtebileceğim bir formül konusunda yardımcı olmanızı rica ederim, Yardımlar için şimdiden teşekkürler. İyi günler.

 

[Ömer]

Merhaba,

Yardımcı sütunlara gerek kalmadan.

I4 e yazıp dizi formülüne çevirdikten sonra alt satırlara kopyalayın.

=EĞERHATA(İNDİS($C$2:$C$50;KÜÇÜK(EĞER(SIKLIK(EĞER($D$2:$D$50>=$I$2
 ;EĞER($D$2:$D$50<=$J$2;KAÇINCI("~"&$C$2:$C$50;$C$2:$C$50&"";0)))
  ;SATIR($C$2:$C$50)-SATIR($C$2)+1);SATIR($C$2:$C$50)-SATIR($C$2)+1)
   ;SATIRSAY($I$4:I4)));"")

.

 

[altan888]

Merhaba,

Yardımcı sütunlara gerek kalmadan.

I4 e yazıp dizi formülüne çevirdikten sonra alt satırlara kopyalayın.

=EĞERHATA(İNDİS($C$2:$C$50;KÜÇÜK(EĞER(SIKLIK(EĞER($D$2:$D$50>=$I$2
 ;EĞER($D$2:$D$50<=$J$2;KAÇINCI("~"&$C$2:$C$50;$C$2:$C$50&"";0)))
  ;SATIR($C$2:$C$50)-SATIR($C$2)+1);SATIR($C$2:$C$50)-SATIR($C$2)+1)
   ;SATIRSAY($I$4:I4)));"")

.

Merhabalar Ömer Bey, yardım için çok teşekkür ederim, ancak bu çözümü işyerinde başka tablolarda da uygulayabilmem için formulünüzü anlamam gerekiyor, eğer size zahmet olmayacaksa formülü 2-3 parçaya bölme imkanınız var ise anlamam daha kolay olacak, yardımcı sütunlarla 2-3 aşamada daha anlayarak çözüyorum, yardımcı olmanızı rica eder, iyi günler dilerim.

 

[Ömer BARAN]

Merhaba.

Alternatif olsun.
Daha anlaşılır olduğunu sanıyorum.

-- B4 hücresine uygulayın ve liste boyunca kopyalayın.
(koşullara uyan satırların, firma ismine ilk rastlandığında satır numaraları tespit ediliyor)

=[COLOR="red"]EĞER[/COLOR](D4<$I$2;"";[COLOR="red"]EĞER[/COLOR](D4>$J$2;"";[COLOR="red"]EĞER[/COLOR]([COLOR="red"]TOPLA.ÇARPIM[/COLOR](($C$3:C3=C4)*($D$3:D3>=$I$2)*($D$3:D3<=$J$2))=0;[COLOR="Red"]SATIR[/COLOR]();"")))

-- H4 hücresine uygulayın ve aşağı doğru kopyalayın.
(küçüklük sırasına göre bu satır numaraları çağrılıyor)

=[COLOR="red"]EĞER[/COLOR]([COLOR="red"]SATIR[/COLOR](A1)>[COLOR="red"]EĞERSAY[/COLOR]($B$4:$B$43;">0");"";[COLOR="red"]KÜÇÜK[/COLOR]($B$4:$B$43;[COLOR="red"]SATIR[/COLOR](A1)))

-- I4 hücresine uyglayın ve aşağı doğru kopyalayın.
(satır numaralarına göre firma isimleri çağrılıyor)

=[COLOR="red"]EĞER[/COLOR](H4="";"";[COLOR="red"]İNDİS[/COLOR]($C$4:$C$43;H4-3;0))

 

[altan888]

Merhaba.

Alternatif olsun.
Daha anlaşılır olduğunu sanıyorum.

-- B4 hücresine uygulayın ve liste boyunca kopyalayın.
(koşullara uyan satırların, firma ismine ilk rastlandığında satır numaraları tespit ediliyor)

=[COLOR="red"]EĞER[/COLOR](D4<$I$2;"";[COLOR="red"]EĞER[/COLOR](D4>$J$2;"";[COLOR="red"]EĞER[/COLOR]([COLOR="red"]TOPLA.ÇARPIM[/COLOR](($C$3:C3=C4)*($D$3:D3>=$I$2)*($D$3:D3<=$J$2))=0;[COLOR="Red"]SATIR[/COLOR]();"")))

-- H4 hücresine uygulayın ve aşağı doğru kopyalayın.
(küçüklük sırasına göre bu satır numaraları çağrılıyor)

=[COLOR="red"]EĞER[/COLOR]([COLOR="red"]SATIR[/COLOR](A1)>[COLOR="red"]EĞERSAY[/COLOR]($B$4:$B$43;">0");"";[COLOR="red"]KÜÇÜK[/COLOR]($B$4:$B$43;[COLOR="red"]SATIR[/COLOR](A1)))

-- I4 hücresine uyglayın ve aşağı doğru kopyalayın.
(satır numaralarına göre firma isimleri çağrılıyor)

=[COLOR="red"]EĞER[/COLOR](H4="";"";[COLOR="red"]İNDİS[/COLOR]($C$4:$C$43;H4-3;0))

Ömer Baran Bey, merhabalar,
Belki zahmet verdim biliyorum ancak uzun formüllere yeni yeni alışıyorum, bir yerden sonra ipin ucunu kaçırıyorum ve toparlıyamıyorum, bu şekilde çok hoşuma gitti ve çözüm için çok çok teşekkür ederim, emeğinize sağlık , saygılar, iyi günler dilerim.

 

[Ömer BARAN]

Ömer Baran Bey, merhabalar,
Belki zahmet verdim biliyorum ancak uzun formüllere yeni yeni alışıyorum, bir yerden sonra ipin ucunu kaçırıyorum ve toparlıyamıyorum, bu şekilde çok hoşuma gitti ve çözüm için çok çok teşekkür ederim, emeğinize sağlık , saygılar, iyi günler dilerim.

Estağfurullah. Önemli olan ihtiyacın görülmesi.

Bir'den çok işlevin kullanıldığı formülleri,
işlev parantezlerini takip ederek parçalara ayırın ve
duruma göre aynı satırda veya aynı sütunda hücreye uygulayın ve
asıl formülün kopyalanma yönüne göre kopyalayıp bu formül parçasının ürettiği değerleri gözlemleyin.

Bu şekilde işlevler ve dolayısıyla da formülün tümü daha iyi anlaşılacaktır.

Sanmayın ki; cevap yazan bizler, her formülü = diye başlayıp doğrudan yazıyor.
Şahsen ben, çok işlevin kullanıldığı formülleri parçalar halinde uygular, sonra bunları tek formülde toplayarak cevap yazarım.

Kolay gelsin.
.