Çoklu kritere göre toplam almak

[Murat OSMA]

Harikasın Erdem, ellerine zihnine sağlık. k::​

 

[Erdem Akdemir]

Harikasın Erdem, ellerine zihnine sağlık. k::​

Teşekkür ederim Murat'ım.:hey:

 

[Ömer]

Sayın kuvari,
Bende tebrik ederim,güzel çözüm.

Çoketopla mantığıyla alternatif olsun:

=TOPLA(EĞER(DÇARP(--(H2:J10<>"");[COLOR="red"]{1\1\1}[/COLOR])
 ;ÇOKETOPLA(D2:D20;A2:A20;H2:H10&"*";B2:B20;I2:I10&"*";C2:C20;J2:J10&"*")))

Dizi formülüdür.

Sütun sayısı sabit olduğu için {1\1\1} kullandım. Dinamik olması için DEVRİK_DÖNÜŞÜM(SÜTUN(H2:J10)^0) kullanabilirsiniz.

.

 

[Erdem Akdemir]

Ömer bey teşekkür ederim.
Sizde formülü oldukça kısaltmışsınız.
Çoketopla'ın bu şekilde kullanılabileceğini bilmiyordum. Sayenizde yeni birşey öğrendim.

 

[Korhan Ayhan]

Değerli Arkadaşlar,

Hepinize ayrı ayrı teşekkür ederim. Ben şimdi bunu son eklediğim dosyaya uyarlamaya çalışayım. Sanırım becerebilirim.

 

[bzace]

Merhabalar,
Korhan Bey,
Ömer Bey'in verdiği formül sizin kriterleriniz için tam sonucu veriyor mu? Aşağıdaki formül ile farklı farklı denemeler yaptım sonuçlar farklı çıkıyor.
Soruyu ben mi anlayamadım acaba :???:

Sn. Sakman26'nın yardımcı sütun kullandığı örnek ile aynı sonuçları alıyorum.

Hata varsa çözmem için bu formülü deneyip bilgi verir misiniz?

=TOPLA(EĞER(E2:E5>0;DEVRİK_DÖNÜŞÜM(A1:A12)=E2:E5;1)*
  EĞER(F2:F5>0;DEVRİK_DÖNÜŞÜM(B1:B12)=F2:F5;1)*
    EĞER(G2:G5>0;DEVRİK_DÖNÜŞÜM(C1:C12)=G2:G5;1)*
  DEVRİK_DÖNÜŞÜM(D1:D12))
[COLOR="Blue"]Formül dizi formülüdür.CTRL+SHIFT+ENTER ile tamamlayınız.[/COLOR]

Referans aldığım aralıklar (resim);


Not: İlgi çekici sorularınızın devamı gelmesi ümidiyle Saygılar,

 

[Korhan Ayhan]

Sn. bzace,

Test sonuçları ektedir.

Örnek Dosya

 

[sakman26]

selamlar,
benim formüldeki problem, MBUL ile yapılmasından dolayı
boşta duran b harfi beyaz da da bulunduğundan fazladan bunların toplamını da alıyor.
Diğer bir deyişle , harf kolonundaki yalnız olan b yi c yaptığınızda (ki c harfi renklerde ve şehirde bulunmuyor) doğru sonuç üretiyor. Tabi ki b yi a yaparsanız a hem renklerde var hem şehirlerde var. Sonuç çok farklı çıkacak..
Sonuçta;
Bu sayede, çabuk gözden kaçan ama dikkat edilmesi gereken önemli bir noktayı da öğrenmiş oldum.
Teşekkürler..

 

[Erdem Akdemir]

Merhaba,

Şunu fark ettim ki Ömer bey'in yazdığı formülde kriterlerin benzersiz olma şartı var. Mesela veride renk kısmında beyaz ve beyazlık gibi iki renk olsun. Eğer kriter alanında beyaz seçeneği varsa "*" işaretinden dolayı beyazlık'ta toplama dahil edilecektir.

 

[Ömer]

Merhaba,

Şunu fark ettim ki Ömer bey'in yazdığı formülde kriterlerin benzersiz olma şartı var. Mesela veride renk kısmında beyaz ve beyazlık gibi iki renk olsun. Eğer kriter alanında beyaz seçeneği varsa "*" işaretinden dolayı beyazlık'ta toplama dahil edilecektir.

Merhaba,

Haklısınız. Bahsettiğiniz denemeyi yapmadım.

Bu doğrultuda sonuçlarda hata varsa;

H2:H10&"*"

yukarıdaki kısım yerine(tüm seçenekler için) aşağıdaki kısım yazılırsa sorun kalmaz diye düşünüyorum.

EĞER(H2:H10="";"*";H2:H10)

.

 

[Erdem Akdemir]

Merhaba,

Bahsettiğiniz denemeyi yapmadım.

Bu doğrultuda sonuçlarda hata varsa;

H2:H10&"*"

yukarıdaki kısım yerine(tüm seçenekler için) aşağıdaki kısım yazılırsa sorun kalmaz diye düşünüyorum.

EĞER(H2:H10="";"*";H2:H10)

.

Ömer bey merhaba,

Hatalı değil sadece böyle bir olasılık var onu söylemek istedim.
Belki'de ihtiyaca göre öyle olması da gerekebilir.

 

[Ömer]

Sayın kuvari,

Haklısınız. Deneme yapmadığım için o şekilde belirtmiştim.
Olasılık varsa hatalı sonuç üretmesi bir gün kaçınılmaz olur. Bu yüzden eğer şartını ilave etmek daha doğru olacaktır.

=TOPLA(EĞER(DÇARP(--(H2:J10<>"");{1\1\1})
 ;ÇOKETOPLA(D2:D20
  ;A2:A20;EĞER(H2:H10="";"*";H2:H10)
  ;B2:B20;EĞER(I2:I10="";"*";I2:I10)
  ;C2:C20;EĞER(J2:J10="";"*";J2:J10))))

.

 

[Korhan Ayhan]

Ekteki dosyaya uyarlamayı başaramadım.

Tekrar yardımcı olabilir misiniz?