Formülde yardım.

[mcetinkaya65]

2010 yılından buyanna toplu arşivde yaklaşık 200 yüz camini ödenen elektrik paraları var
E topla ile toplu arşivdeki aaa camisi toplam ne kadar elektrik harcamış görebiliyoruz.
Biz M2 Hücresinde yazan yılda ne kadar elektrik harcamış bunu görmek istiyoruz.Toplu arşivin K stunundaki ödeme tarihine göre
Saygılarımla..

 

[esahin1907]

merhaba,
Aşağıdaki formülü deneyiniz.

=TOPLAÇARPIM(--('TOPLU ARŞİV'!$D$2:$D$42=$D3);--(YIL('TOPLU ARŞİV'!$K$2:$K$42)=M$2);--('TOPLU ARŞİV'!$G$2:$G$42))

2010 yılından buyanna toplu arşivde yaklaşık 200 yüz camini ödenen elektrik paraları var
E topla ile toplu arşivdeki aaa camisi toplam ne kadar elektrik harcamış görebiliyoruz.
Biz M2 Hücresinde yazan yılda ne kadar elektrik harcamış bunu görmek istiyoruz.Toplu arşivin K stunundaki ödeme tarihine göre
Saygılarımla..

 

[mcetinkaya65]

Üstad!
#AD? hatası veriyor

 

[sakman26]

selam,
verilen formüldeki TOPLAÇARPIM yazısı TOPLA.ÇARPIM şeklinde olacak.
kolay gelsin..

 

[mcetinkaya65]

Sağ olun var olun.
Allah razı olsun
Topla çarpımdan sonraki -- işaretler ne anlama geliyor çözemedim.

 

[sakman26]

selam,
TOPLA.ÇARPIM formülünü farklı biçimlerde de yazabilirsiniz..

Sizdeki formül:
=TOPLA.ÇARPIM(--('TOPLU ARŞİV'!$D$2:$D$42=$D3);--(YIL('TOPLU ARŞİV'!$K$2:$K$42)=M$2);--('TOPLU ARŞİV'!$G$2:$G$42))
(Burada, -- nin kullanımı : eksi ile eksinin çarpımı artıdır mantığı vardır )

Diğer yazım şekillerinden örnekler :

=TOPLA.ÇARPIM(('TOPLU ARŞİV'!$D$2:$D$42=$D3)*(YIL('TOPLU ARŞİV'!$K$2:$K$42)=M$2)*('TOPLU ARŞİV'!$G$2:$G$42))

=TOPLA.ÇARPIM(('TOPLU ARŞİV'!$D$2:$D$42=$D3)*1;(YIL('TOPLU ARŞİV'!$K$2:$K$42)=M$2)*1;('TOPLU ARŞİV'!$G$2:$G$42)*1)

=TOPLA.ÇARPIM(('TOPLU ARŞİV'!$D$2:$D$42=$D3)/1;(YIL('TOPLU ARŞİV'!$K$2:$K$42)=M$2)/1;('TOPLU ARŞİV'!$G$2:$G$42)/1)

=TOPLA.ÇARPIM(('TOPLU ARŞİV'!$D$2:$D$42=$D3)^1;(YIL('TOPLU ARŞİV'!$K$2:$K$42)=M$2)^1;('TOPLU ARŞİV'!$G$2:$G$42)^1)

=TOPLA.ÇARPIM(('TOPLU ARŞİV'!$D$2:$D$42=$D3)+0;(YIL('TOPLU ARŞİV'!$K$2:$K$42)=M$2)+0;('TOPLU ARŞİV'!$G$2:$G$42)+0)

=TOPLA.ÇARPIM(('TOPLU ARŞİV'!$D$2:$D$42=$D3)-0;(YIL('TOPLU ARŞİV'!$K$2:$K$42)=M$2)-0;('TOPLU ARŞİV'!$G$2:$G$42)-0)

 

[esahin1907]

selam,
verilen formüldeki TOPLAÇARPIM yazısı TOPLA.ÇARPIM şeklinde olacak.
kolay gelsin..

merhaba,
ben İngilizce versiyon kullandığım için yazarken değiştirmiştim.
Sn. sakman26 cevaplamış.