Satır Silmek

[iplikci_80]

Arkadaşlar merhabalar, EK 'te gönderdiğim örnekte yapmak istediğim şey veri tabanı sekmesinin G sütununa herhangi bir tarih değeri girildiğinde o satırı silip arşiv sekmesine atılmasını sağlamak ve silinen o satırın izin ve liste sekmelerinde karşılığı olan satırların da silinmesini sağlayarak arşiv sekmesine atılanların küçükten büyüğe sıralamasını sağlamak istiyorum ve yardımlarınızı bekliyorum. Yardımlarınız için şimdiden çok teşekkür ederim.

 

[Necdet]

Merhaba,

Aşağıdaki kodları "VERİ TABANI" sayfasının kod bölümüne kopyalayıp deneyiniz.

Private Sub Worksheet_Change(ByVal Target As Range)
    
    If Intersect(Target, [G:G]) Is Nothing Or Target.Row < 5 Then Exit Sub
    
    Dim SicilNo
    Dim c       As Range
    Dim i       As Long
    Dim AdSoyad As String
    
    AdSoyad = Cells(Target.Row, "B")
        
    Evet = MsgBox(AdSoyad & " SİLİNECEK, EMİN MİSİNİZ?", vbYesNo)
    If Evet = vbYes Then
        Application.EnableEvents = False
        SicilNo = Cells(Target.Row, "A")
        Set c = Sheets("İZİN").Range("B:B").Find(SicilNo, LookIn:=xlValues, LookAt:=xlWhole)
        If Not c Is Nothing Then Sheets("İZİN").Rows(c.Row & ":" & c.Row).Delete
        Set c = Nothing
        Set c = Sheets("LİSTE").Range("B:B").Find(SicilNo, LookIn:=xlValues, LookAt:=xlWhole)
        If Not c Is Nothing Then Sheets("LİSTE").Rows(c.Row & ":" & c.Row).Delete
        Set c = Nothing
        i = Sheets("ARŞİV").Cells(Rows.Count, "A").End(3).Row + 1
        If i < 5 Then i = 5
        Rows(Target.Row & ":" & Target.Row).Copy Sheets("ARŞİV").Range("A" & i)
        Sheets("ARŞİV").Range("A5:DM" & i).Sort Key1:=Sheets("ARŞİV").Range("A1")
        Rows(Target.Row & ":" & Target.Row).Delete
        Application.EnableEvents = True
    End If
    
End Sub

 

[iplikci_80]

Necdet bey ilginize çok teşekkür ederim. Fakat liste sekmesinde ki satırın silinmesini ve arşiv sekmesinin küçükten büyüğe sıralamasının yapılmasını da istiyorum. Tekrar teşekkür ederim.

 

[Necdet]

Merhaba,

Kodlar yenilenmiştir.

 

[iplikci_80]

Necdet Bey ayırdığınız zaman ve harcadığınız emek için çok teşekkür ederim.

 

[Necdet]

Necdet Bey ayırdığınız zaman ve harcadığınız emek için çok teşekkür ederim.

Güle güle kullanınız.