Tek Sütun Tek Satır için sil sorunu.

[vardar07]

Merhaba Arkadaşlar.
Sayın Koray beyin çalışmasından kendime bir uyarlama yapmaya çalışıyorum. Ancak aşağıdaki kodu bir türlü uyarlayamadım. Kodu "DATA" sayfasında "A" sütununda bilgi silmek için yardımlarınızı rica ediyorum. Şimdiden teşekkürler.

 Private Sub CommandButton3_Click() 'KAYIT SİL TUŞU 
    If ListBox1 = Empty Then
    MsgBox "Veri kaydı bulunamamıştır.", vbExclamation, "Dikkat !"
    Exit Sub
    End If
    If ListBox1.ListIndex < 0 Then
    MsgBox "Lütfen listeden veri seçimi yapınız.", vbExclamation, "Dikkat !"
    Exit Sub
    End If 
    If MsgBox("Seçtiğiniz kayıt silinecektir onaylıyor musunuz ?", vbCritical + vbYesNo, "Dikkat !") = vbYes Then 
    ListBox1.RowSource = Empty
    Range("A" & ActiveCell.Row, "J" & ActiveCell.Row).ClearContents
   Range("A2:J65536").Sort Key1:=Range("A2"), Order1:=xlAscending, Header:=xlGuess, _
    OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, DataOption1:=xlSortNormal
    Range("A2") = 1
    Range("A2").AutoFill Destination:=Range("A2:A" & Range("B65536").End(3).Row), Type:=xlFillSeries 
    With DEPARTMAN.ListBox1
        .BackColor = vbYellow
        .ColumnCount = 9
        .ColumnWidths = "100;100;100;100;100;100;100;120;100"
        .ForeColor = vbRed
        If Sheets("DATA").Range("A2") = Empty Then
        .RowSource = Empty
        Else
        .RowSource = "DATA!B2:J" & [DATA!A65536].End(3).Row
        End If
    End With 
    MsgBox "Kayıt silme işlemi tamamlanmıştır.", vbInformation, "Kayıt Silme İşlemi" 
    Else 
    MsgBox "Kayıt silme işlemi iptal edilmiştir.", vbInformation, "İşlem İptali" 
    End If 
End Sub

 

[Necdet]

Merhaba,

Ya sorunuzda birşey var ya kodlarda. Satır silmek için o kadar uzun kod yazmaya gerek yok.

Private Sub CommandButton3_Click()
    Sheets("DATA").Range("A:A").ClearContents
End Sub

 

[vardar07]

Merhaba,

Ya sorunuzda birşey var ya kodlarda. Satır silmek için o kadar uzun kod yazmaya gerek yok.

Private Sub CommandButton3_Click()
    Sheets("DATA").Range("A:A").ClearContents
End Sub

Öncelikle ilginize teşekkür ederim . Tek sütun derken sadece listbox'dan seçilen veriyi silecek.Ekte Korhan beyin çalışması var "DEPARTMAN_TANIMLAMA" Formunda commandbutton3'e uyarlamak istedim.

 

[Korhan Ayhan]

Merhaba,

İlgili formun kod bölümüne aşağıdaki kodları ekleyin.

Not : Benim anlattığım konu tamamlanmamış olabilir. Fakat forumda o kadar çok örnek var ki, incelediğinizde kendinizde rahatlıkla yapabilirsiniz. Zaten örneği aldığınız başlıktaki amacımız sizlere konuları en ince ayrıntısına kadar anlatarak kavramanızı sağlamaktır. Konuları kavradıktan sonra bol bol pratik ile bilgilerinizi pekiştirebilirsiniz.

Private Sub ListBox1_Click()
    If ListBox1 = Empty Then
        MsgBox "Veri kaydı bulunamamıştır.", vbExclamation, "Dikkat !"
        Exit Sub
    End If
 
    TextBox1 = ListBox1
End Sub

Private Sub CommandButton3_Click() 'KAYIT SİL TUŞU
    Dim BUL As Range
 
    If ListBox1 = Empty Then
        MsgBox "Veri kaydı bulunamamıştır.", vbExclamation, "Dikkat !"
        Exit Sub
    End If
 
    If ListBox1.ListIndex < 0 Then
        MsgBox "Lütfen listeden veri seçimi yapınız.", vbExclamation, "Dikkat !"
        Exit Sub
    End If
 
    If MsgBox("Seçtiğiniz kayıt silinecektir onaylıyor musunuz ?", vbCritical + vbYesNo, "Dikkat !") = vbYes Then
        ListBox1.RowSource = Empty
        Set BUL = Sheets("PARAMETRELER").Range("A:A").Find(TextBox1, , , xlWhole)
        If Not BUL Is Nothing Then
            BUL.Delete
            Sheets("PARAMETRELER").Range("A2:A65536").Sort Key1:=Sheets("PARAMETRELER").Range("A2"), Order1:=xlAscending
 
            With DEPARTMAN_TANIMLAMA.ListBox1
                .BackColor = vbYellow
                .ForeColor = vbRed
                If Sheets("PARAMETRELER").Range("A2") = Empty Then
                .RowSource = Empty
                Else
                .RowSource = "PARAMETRELER!A2:A" & Sheets("PARAMETRELER").Range("A65536").End(3).Row
                End If
            End With
            MsgBox "Kayıt silme işlemi tamamlanmıştır.", vbInformation, "Kayıt Silme İşlemi"
        End If
    Else
        MsgBox "Kayıt silme işlemi iptal edilmiştir.", vbInformation, "İşlem İptali"
    End If
End Sub

 

[vardar07]

Merhaba,

İlgili formun kod bölümüne aşağıdaki kodları ekleyin.

Not : Benim anlattığım konu tamamlanmamış olabilir. Fakat forumda o kadar çok örnek var ki, incelediğinizde kendinizde rahatlıkla yapabilirsiniz. Zaten örneği aldığınız başlıktaki amacımız sizlere konuları en ince ayrıntısına kadar anlatarak kavramanızı sağlamaktır. Konuları kavradıktan sonra bol bol pratik ile bilgilerinizi pekiştirebilirsiniz.

Çok teşekkür ederim. Kolay gelsin.