etopla ile ilgili bi istek

[modoste]

ekte sorum belirtiliyo

 

[Ömer]

Merhaba,

=TOPLA.ÇARPIM(($A$2:$A$34=F2)*($C$2:$C$34+$E$2:$E$34))

Denermisiniz..

 

[modoste]

tşkkr ettim diğerlerinede uygulandı peki ben C-E-G-I gibi birbirini 1 sutun er atlayarak devam eden sutunlarda değerler osla ve toplatmak istesem ????? C2:C34+E2:E34+G2:G34... gibi devam eden tablolarımda var

 

[Ömer]

tşkkr ettim diğerlerinede uygulandı peki ben C-E-G-I gibi birbirini 1 sutun er atlayarak devam eden sutunlarda değerler osla ve toplatmak istesem ????? C2:C34+E2:E34+G2:G34... gibi devam eden tablolarımda var

=TOPLA.ÇARPIM(($A$2:$A$34=F2)*($C$2:$C$34+$E$2:$E$34+$G$2:$G$34))

Gibi kullanabilirsiniz..

 

[modoste]

tabloma Dayanarak Soruma eklemem su ben A sutununa tarihler yazdım ve istedim ki C,E,G,I,K... diyelim 50 tane (sutun) daki değerleri otomatik toplatsak yani($C$2:$C$34+$E$2:$E$34+$G$2:$G$34....)bunu her defasında uzun uzadıya yazmaktan başka formülasyon olabilirmi

 

[Ömer]

tabloma Dayanarak Soruma eklemem su ben A sutununa tarihler yazdım ve istedim ki C,E,G,I,K... diyelim 50 tane (sutun) daki değerleri otomatik toplatsak yani($C$2:$C$34+$E$2:$E$34+$G$2:$G$34....)bunu her defasında uzun uzadıya yazmaktan başka formülasyon olabilirmi

=TOPLA.ÇARPIM(($A$2:$A$34=F2)*(TEK(YERİNEKOY($C$1:$E$1;"KANTAR";""))=--YERİNEKOY($C$1:$E$1;"KANTAR";""))*($C$2:$E$34))

Aralıkları kendi dosyanıza uyarlarsınız..

.

 

[Ali]

Ekteki örneği inceleyiniz.

Yeşil ve Sarı alan olarak belirledim.

 

[modoste]

tşkkr ettim 2 çözümde doğru sonuçlar veriyo espiyonajl size sorum siz"kantar" yazdınızya yerinekoy formülünde en formülü tam anlamasamda mesela oralardabaşlık adları gibi bişe olmazsa nasıl olabilirdi alinin çözümüde (MOD(SÜTUN($C$2:$H$34);2)=0) bu detayı anlayamadım birinde ;1 diğerinde ;2

 

[Ömer]

tşkkr ettim 2 çözümde doğru sonuçlar veriyo espiyonajl size sorum siz"kantar" yazdınızya yerinekoy formülünde en formülü tam anlamasamda mesela oralardabaşlık adları gibi bişe olmazsa nasıl olabilirdi alinin çözümüde (MOD(SÜTUN($C$2:$H$34);2)=0) bu detayı anlayamadım birinde ;1 diğerinde ;2

Verileriniz Kantar1, Kantar2..şeklinde devam ettiği için Kantarları kaldırım numaraları kulllanarak bu numaralardan tek olan sütunları alıp toplattım. Yeni verileriniz görmeden net birşey söylemem güç olur.

Fakat Ali Bey' in verdiği formül yazı karakterlerine bakmadan belirlenen aralıktaki sütunların tek olanını ve çift olanlarını toplamaktadır, bu formül daha pratik olduğu için Ali Bey'in yazdığı formülü kullanmanızı tavsiye ederim. Formüldeki 1 ve 0 değerleri sütunların tek yada çift olduğunu belirlemek için kullanılmıştır, 1 değeri tek sütunlar için 0 değeri çift sütunlar içindir..

.

 

[Ali]

Alinin çözümüde (MOD(SÜTUN($C$2:$H$34);2)=0) bu detayı anlayamadım birinde ;1 diğerinde ;2

Verdiğim örnekte mesala C36 hücresine

=SÜTUN(C2) yazıp H36 hücresine kadar çekiniz sırayla 3,4,5,6 şeklinde

artacaktır. Tekleri ayrı çiftleri ayrı gruplandırırsak sorumuzun büyük bir kısmını halledeceğiz.

Bunun için 2 ile tam bölünen ve bölünmeyeler diye ayıralım. Bunun için MOD kullandık.

Şimdide

C37 hücresine

=MOD(SÜTUN(C2);2)

yazıp H37 hücresine kadar çekiniz. Sırayla 1,0,1,0.. şeklinde ilerlediğini göreceksiniz.


=TOPLA.ÇARPIM(($A$2:$A$34=I2)*(MOD(SÜTUN($C$2:$H$34);2)=1);$C$2:$H$34)

Kırmızı olan kısımla dedik ki C2:H34 aralığında sütunu 1 ile eşleşenlerin

ve $A$2:$A$34=I2 deki tarihe denk gelen $C$2:$H$34 aralığındaki toplamı al.

MOD(SÜTUN($C$2:$H$34);2)=0 olarak kullandığımızda ise 0 ile eşleşenlerin toplamını almış olduk.

 

[modoste]

espiyonajl ve ali beye ekte bu tip sorularımdaki genel isteğim galiba onu sormaya çalıştım

 

[Ömer]

espiyonajl ve ali beye ekte bu tip sorularımdaki genel isteğim galiba onu sormaya çalıştım

Ali Bey' in yazdığı formülden yola çıkarak..

3 sütun atlayarak,

=TOPLA.ÇARPIM(($A$2:$A$34=M2)*(MOD(SÜTUN($C$2:$L$34);3)=0);$C$2:$L$34)

5 sütun atlayarak,

=TOPLA.ÇARPIM(($A$2:$A$34=M2)*(MOD(SÜTUN($C$2:$L$34);4)=3);$C$2:$L$34)

Kullanabilirsiniz..