içinde bulunulan hafta

[muddybank]

a sütününda tarih var.b sütününda o tarihin senenin kaçıncı haftası olduğu yazacak.eğer tarihler hep 2008 yılına aitse sorun yok.=(a1-27.12.2007)/7
gibi bi formülle bunun yapabilirsiniz.fakat 2009 yılından bir tarihe bunu yapınca doğal olarak hafta olarak 52 nin üzerinde bir sayı verecek.bunu nasıl çözeriz?

 

[Merhum İdris SERDAR]

Eğer haftanın başlangıç günü Pazar günü varsayılırsa;

=WEEKNUM(A1;1)
=HAFTASAY(A1;1)

veya:


=WEEKNUM(A1)
=HAFTASAY(A1)

Eğer haftanın başlangıç günü Pazartesi günü varsayılırsa;

=WEEKNUM(A1;2)
=HAFTASAY(A1;2)


.

 

[uzmanamele]

merhaba
excel dersanesi tarih zaman ?onksiyon örneklerini inceleyiniz

 

[muddybank]

#ad

#ad hatası veriyor.excel 2003 te

 

[Necdet]

Merhaba,

Dosyayı inceleyiniz.

 

[Merhum İdris SERDAR]

#ad hatası veriyor.excel 2003 te

ToolPak Çözümleyicisi = Analysys ToolPack eklentisinin yüklü olmaması durumunda bu fonksiyonlar #AD? / #NAME? hatası verir.

Bunun için bunu yüklemeniz gerekir.

Yükleme
a. Araçlar menüsünden Eklentiler'i tıklatın.
b. Kullanmak istediğiniz eklenti, Kullanılabilir eklentiler kutusundaki listede yoksa, Gözat'ı tıklatarak eklentinin yerini gösterin.
c. Kullanılabilir eklentiler kutusunda, yüklemek istediğiniz eklentinin yanındaki onay kutusunu işaretleyip Tamam'ı tıklatın.
d. Gerekirse, kur programındaki yönergeleri izleyin.

Yükleyemediyseniz;

Haftanın başlangıcı Pazar günü varsayıdığında;

=1+INT((A1-DATE(YEAR(A1+4-WEEKDAY(A1+6;1));1;5)+WEEKDAY(DATE(YEAR(A1+4-WEEKDAY(A1+6;1));1;3)))/7)
=1+INT((A1-DATE(YEAR(A1+4-WEEKDAY(E2+6));1;5)+WEEKDAY(DATE(YEAR(A1+4-WEEKDAY(A1+6));1;3)))/7)

Pazartesi ise;

=1+INT((A1-DATE(YEAR(A1+4-WEEKDAY(A1+6;2));1;5)+WEEKDAY(DATE(YEAR(A1+4-WEEKDAY(A1+6;2));1;3)))/7)


formüllerini kullanabilirsiniz.


INT=TAMSAYI
DATE=TARİH
YEAR=YIL
WEEKDAY=HAFTANINGÜNÜ

.

 

[muddybank]

31.12.2007

hafta başı pazartesi ye göre 31.12.2007 için 53 sayısını veriyor.bir yıl 52 hafta 31.12.2007 de 2008 yılının ilk haftası olması gerekmiyormu

 

[Merhum İdris SERDAR]

31 Aralık 2007 Pazartesi günüdür. Ve haftanın başlangıcını Pazartesi günü varsayılırsa, 31 Aralık 2007 Pazartesi günü 53. Haftanın başlangıcıdır. Ayrıca bu 2008 yılının da 1. Haftasıdır. Excel'den nasıl bir sonuç vermesini bekliyorsunuz?

Ben bunu böyle görmek istemiyorum derseniz. O zaman;

=IF(WEEKNUM(A1;2)=53;"gelecek yılın ilk haftası";WEEKNUM(A1;2))
=EĞER(HAFTASAY(A1;2)=53;"GELECEK YILIN İLK HAFTASI";HAFTASAY(A1;2))

Şekinde bir formül yazmanız gerekir.


Ayrıca, yukarıda yaptığımız tüm bilgi ve açıklamalar herhalde bir teşekkürü hakkediyordur. Değil mi?

.

 

[Ali]

WEEKNUM ve ISO WEEKNUM'a göre farkediyor.

Sayın yurttas'ında belirttiği gibi haftanın Pazartesi olmasına göre değişir.

53 hafta Weeknum' a göre

=TAMSAYI((A1-HAFTANINGÜNÜ(A1)-TARİH(YIL(A1);1;1))/7)+2

=TAMSAYI((A1-TARİH(YIL(A1);1;1)-HAFTANINGÜNÜ(A1))/7)+2

ISO WEEKNUM göre 1 hafta olarak kabul ettirecekseniz.

=TAMSAYI((A1-TOPLA(MOD(TARİH(YIL(A1-MOD(A1-2;7)+3);1;2);{1E+99;7})*{1;-1})+5)/7)

=TAMSAYI((A1-HAFTANINGÜNÜ(A1;2)-TARİH(YIL(A1+4-HAFTANINGÜNÜ(A1;2));1;4))/7)+2

 

[muddybank]

çok teşekkür erderim

emeğinize sağlık

 

[kamsal]

ToolPak Çözümleyicisi = Analysys ToolPack eklentisinin yüklü olmaması durumunda bu fonksiyonlar #AD? / #NAME? hatası verir.

Bunun için bunu yüklemeniz gerekir.

Yükleme
a. Araçlar menüsünden Eklentiler'i tıklatın.
b. Kullanmak istediğiniz eklenti, Kullanılabilir eklentiler kutusundaki listede yoksa, Gözat'ı tıklatarak eklentinin yerini gösterin.
c. Kullanılabilir eklentiler kutusunda, yüklemek istediğiniz eklentinin yanındaki onay kutusunu işaretleyip Tamam'ı tıklatın.
d. Gerekirse, kur programındaki yönergeleri izleyin.

Yükleyemediyseniz;

Haftanın başlangıcı Pazar günü varsayıdığında;

=1+INT((A1-DATE(YEAR(A1+4-WEEKDAY(A1+6;1));1;5)+WEEKDAY(DATE(YEAR(A1+4-WEEKDAY(A1+6;1));1;3)))/7)
=1+INT((A1-DATE(YEAR(A1+4-WEEKDAY(E2+6));1;5)+WEEKDAY(DATE(YEAR(A1+4-WEEKDAY(A1+6));1;3)))/7)

Pazartesi ise;

=1+INT((A1-DATE(YEAR(A1+4-WEEKDAY(A1+6;2));1;5)+WEEKDAY(DATE(YEAR(A1+4-WEEKDAY(A1+6;2));1;3)))/7)


formüllerini kullanabilirsiniz.


INT=TAMSAYI
DATE=TARİH
YEAR=YIL
WEEKDAY=HAFTANINGÜNÜ

.

Merhaba Sayın Yurttaş, ben her iki yönergenizide izledim fakat istediğim sonuca ulaşamadım. Yani toollpak yükleyemedim, verdiğiniz formülüde kullandım ama yinede hafta sayısını gösteremedim. Acaba sorun ne olabilir ? yardımcı olursanız sevinirim.
Saygılarımla

 

[Ali]

9 nolu mesajı ve aşağıdaki linkide inceleyebilirsiniz.

Tarih & Zaman & Saat Fonksiyonları Uygulamaları

.