34 kolonu listboxta listeleme

[AKTAY27]

meraba arkadaşlar

data sayfasıda A:AI sütununa kadar veri var kriter olarak B kolonunu yani tarihi kullanmak istiyorum textbox1 vazdığım tarihin verilerini listbox1'de görebilirmiyiz.yoksa 10 sütunu aşamazmıyız.

 

[Orion1]

10 sütunu aşamazmıyız

Listbox'ta 10 sütunu aşıp istediğiniz sütun kadar listeleyebilirsiniz
Ekli dosyayı inceleyiniz.

Private Sub CommandButton1_Click()
ReDim myarr(1 To 35, 1 To 1)
ListBox1.RowSource = ""
If Not IsDate(TextBox1.Value) Then
    MsgBox "Yanlış tarih girişi..!!", vbCritical, "DİKKAT"
    TextBox1.SetFocus
    Exit Sub
End If
For i = 2 To Sheets("data").Cells(65536, "B").End(xlUp).Row
    If CDate(Cells(i, "B").Value) = CDate(TextBox1.Value) Then
        a = a + 1
        ReDim Preserve myarr(1 To 35, 1 To a)
        For k = 1 To 35
            myarr(k, a) = Cells(i, k).Value
        Next k
        myarr(2, a) = Format(myarr(2, a), "dd.mm.yyyy")
    End If
Next i
ListBox1.Column = myarr
End Sub

 

[AKTAY27]

TeŞekkÜrler Orİon2

Benİ BÜyÜk Bİr Dertten Kurtardin Allahta Senİ Darda Koymaz İnŞ.

Bİr Şey Daya İstİyebİlİrmİyİm
ÖrneĞİn 01.02.2008 Tarİhİnde Sevkİyatlari Lİsteledİk Dİyelİm Bİr Butonla Yardimiyla Lİstelenenlerİ Sayfa 2 Aktaracak Ve Data Sayfasina İse AI SÜtununa "F" İŞaretİ Koyacak ve Başlıkları sabit olarak gösterebilirmiyiz. TeŞekkÜrler

 

[Orion1]

TeŞekkÜrler Orİon2

Benİ BÜyÜk Bİr Dertten Kurtardin Allahta Senİ Darda Koymaz İnŞ.

Bİr Şey Daya İstİyebİlİrmİyİm
ÖrneĞİn 01.02.2008 Tarİhİnde Sevkİyatlari Lİsteledİk Dİyelİm Bİr Butonla Yardimiyla Lİstelenenlerİ Sayfa 2 Aktaracak Ve Data Sayfasina İse AI SÜtununa "F" İŞaretİ Koyacak ve Başlıkları sabit olarak gösterebilirmiyiz. TeŞekkÜrler

data sayfasındaki A sütunundaki sıra numaraları artan şekilde ve doğru sırada olması gerekiyor.
Ekli dosyayı inceleyiniz.

Private Sub CommandButton2_Click()
Dim sat As Long, i As Long, k As Byte
If MsgBox("Listeyi Sayfa2'ye Aktarmak istiyormusunuz?", vbYesNo + vbInformation, "KAYIT") = vbNo Then Exit Sub
sat = Sheets("Sayfa2").Cells(65536, "B").End(xlUp).Row + 1
For i = 0 To ListBox1.ListCount - 1
    Sheets("data").Cells(ListBox1.List(i, 0) + 1, "AI").Value = "F"
    For k = 1 To 35
        Sheets("Sayfa2").Cells(sat, k).Value = ListBox1.List(i, k - 1)
    Next k
    sat = sat + 1
Next i
MsgBox "Liste Sayfa2'ye Aktarıldı..!!", vbOKOnly + vbInformation, "KAYIT"
End Sub

 

[AKTAY27]

teşekkürler orion2 eline emeğine sağlık