en ucuz fiyat hangisi ? yardım

[hypernovea]

ekte bulunan dosyada ülkeler için en ucuz fiyatı bulup hangi firma olduğunu vermesini nasıl sağlarız. bildiğim fonksiyonlarla sadece en ucuzunu buluyor, firmasını aldırmam gerekli.yardımcı olursanız sevinirim.

 

[a.akyurek]

ekte bulunan dosyada ülkeler için en ucuz fiyatı bulup hangi firma olduğunu vermesini nasıl sağlarız. bildiğim fonksiyonlarla sadece en ucuzunu buluyor, firmasını aldırmam gerekli.yardımcı olursanız sevinirim.

G2:

Control+shift+enter'le girilmesi gereken...

=MIN(IF($A$4:$A$27=F4,$D$4:$D$27))

H2:

=SUMPRODUCT(--($A$4:$A$27=F4),--($D$4:$D$27=G4))

I2:

=IF(COLUMNS($I2:I2)<=$H4,
      INDEX($B$4:$B$27,
         SMALL(IF($A$4:$A$27=$F4,
                       IF($D$4:$D$27=$G4,
                           ROW($B$4:$B$27)-ROW($B$4)+1)),
                   COLUMNS($I$2:I2))),
      "")

Yukardaki formülün control+shift+enter'le girilmesi, sonra sağa ve aşa kopyalanması gerekir.

Ekteki dosya türkçe bir sistemde bu formüllerin o sistemdeki geçerli biçimlerini verir.

 

[Korhan Ayhan]

Selamlar,

Örnek dosyanıza göre alternatif olarak aşağıdaki şekilde de kullanabilirsiniz.

G4 hücresine; (Ctrl+Shift+Enter ile formül girişini tamamlayın.)

=MİN(EĞER((($A$4:$A$27=F4)*($D$4:$D$27))>0;$D$4:$D$27))

I4 hücresine; (Bu formül ilk ucuz fiyatlı firmayı getirir.)

=İNDİS($B$4:$B$27;TOPLA.ÇARPIM((KAÇINCI(F4&"@"&G4;$A$4:$A$27&"@"&$D$4:$D$27;0))))

 

[a.akyurek]

Selamlar,

Örnek dosyanıza göre alternatif olarak aşağıdaki şekilde de kullanabilirsiniz.

G4 hücresine; (Ctrl+Shift+Enter ile formül girişini tamamlayın.)

=MİN(EĞER((($A$4:$A$27=F4)*($D$4:$D$27))>0;$D$4:$D$27))

I4 hücresine; (Bu formül ilk ucuz fiyatlı firmayı getirir.)

=İNDİS($B$4:$B$27;TOPLA.ÇARPIM((KAÇINCI(F4&"@"&G4;$A$4:$A$27&"@"&$D$4:$D$27;0))))

KAAN; 0,2
COST_CONTROL; 0,2
DAMON; 3,0

En ucuz kim?

 

[Korhan Ayhan]

Selamlar,

Sn. a.akyurek,

Sorunuzun cevabı; KAAN ve COST_CONTROL

Sizin verdiğiniz çözümde; en ucuz fiyatı ve bu fiyatı veren firma eğer birden fazla ise bunları listeliyor. Ben zaten çözümü verirken formülün en ucuz fiyatı veren ilk firmayı getirdiğini belirtmiştim. Tabiki sizin çözümünüz daha kullanışlı. Belki soruyu soran arkadaşımız bu haliyle kullanmak ister düşüncesiyle alternatif sunmak istedim.

 

[hypernovea]

Teşekkürler

yardımlarınızdan aşağıdaki sonuca ulaşabildim, çok teşekkürler

{=İNDİS($B$4:$B$27;TOPLA.ÇARPIM((KAÇINCI($F4&"@"&MİN(EĞER($A$4:$A$27=$F4;$D$4:$D$27));$A$4:$A$27&"@"&$D$4:$D$27;0))))}

 

[a.akyurek]

yardımlarınızdan aşağıdaki sonuca ulaşabildim, çok teşekkürler

{=İNDİS($B$4:$B$27;TOPLA.ÇARPIM((KAÇINCI($F4&"@"&MİN(EĞER($A$4:$A$27=$F4;$D$4:$D$27));$A$4:$A$27&"@"&$D$4:$D$27;0))))}

Neden? Bu çok zaman alan ve üstelikte eksik sonuç veren bir formül...

 

[hypernovea]

haklısınız... "0" olan değerleri en ucuz olarak alıyor. ancak öneride bulunulan formüllerden ancak bu kadarını yapabiliyorum, ancak istediğim sonuca tek formülle ulaşması ve değeri listede "0" dan büyük en küçük değeri hesaplaması...