Hücrenin içeriğinde Sayısal Bir Değer olup olmadığının tespit dilmesi

[tamer42]

Merhaba,

Hücrenin Sayısal Bir Değer İçerip İçermediğinin Tespit Edilmesi için aşağıdaki kod hücre sadece sayısal veri içeriyorsa çalışıyor,

yalnız harf ve rakam karışık olduğunda da ; rakam içeriyorsa sonuç almamız için nasıl bir düzenleme yapmamız gerekecektir?

Örnek: Hücre içeriği "abc12d5ef" olduğunda, burada sayısal veri var, bu durumda sayısal veri olduğunun tespitini nasıl yapabiliriz?

Sub InfoExample22()

Dim cell As Range

For Each cell In Selection

If Not IsEmpty(cell) And IsNumeric(cell.Value) Then

MsgBox cell.Address

End If

Next
End Sub

Teşekkürler,

iyi hafta sonları...

 

[Korhan Ayhan]

Deneyiniz.

Sub InfoExample22()
    Dim cell As Range, X As Byte
    
    For Each cell In Selection
        If Not IsEmpty(cell) Then
            For X = 0 To 9
                If InStr(1, cell.Value, X) > 0 Then
                    MsgBox cell.Address
                    Exit For
                End If
            Next
        End If
    Next
End Sub

 

[Ömer]

Alternatif:

Sub InfoExample22()

    Dim cell As Range, r As Object
  
    Set r = CreateObject("VBscript.RegExp")
    r.Global = True
    r.Pattern = "[^0-9]"
  
    For Each cell In Selection
        If r.Replace(cell, "") <> "" Then MsgBox cell.Address
    Next
  
End Sub

 

[tamer42]

Sub InfoExample22() Dim cell As Range, X As Byte For Each cell In Selection If Not IsEmpty(cell) Then For X = 0 To 9 If InStr(1, cell.Value, X) > 0 Then MsgBox cell.Address Exit For End If Next End If Next End Sub

Teşekkür ederim Korhan Hocam

 

[Korhan Ayhan]

Bunlar da başka alternatifler;

Sub InfoExample22()
    Dim cell As Range
  
    For Each cell In Selection
        If Not IsEmpty(cell) Then
            If cell.Value Like "*[0-9]*" Then MsgBox cell.Address
        End If
    Next
End Sub

Sub InfoExample22()
    Dim cell As Range
   
    For Each cell In Selection
        If Not IsEmpty(cell) Then
            If Evaluate("=COUNT(FIND({0,1,2,3,4,5,6,7,8,9},""" & cell.Value & """,1))") Then MsgBox cell.Address
        End If
    Next
End Sub

 

[tamer42]

Sub InfoExample22() Dim cell As Range For Each cell In Selection If Not IsEmpty(cell) Then If cell.Value Like "*[0-9]*" Then MsgBox cell.Address End If Next End Sub

Çok teşekkür ederim Korhan Hocam
iyi pazarlar.

 

[mehmetuca]

Değerli hocalarım Formülle çözümü var mı?

 

[Korhan Ayhan]

A1 için,

=BAĞ_DEĞ_SAY(BUL({0;1;2;3;4;5,6;7;8;9};A1))

 

[Seceren]

"A1" İçin
Alternatif:

=BAĞ_DEĞ_SAY(BUL({0\1\2\3\4\5\6\7\8\9};A1))

=EĞER(BAĞ_DEĞ_SAY(BUL({0\1\2\3\4\5\6\7\8\9};A1))>0=DOĞRU;"RAKAM VAR";"RAKAM YOK")

 

[mehmetuca]

Teşekkür Ederim cevaplarınız için.

 

[izcik]

Sub test()
    Cells.SpecialCells(xlCellTypeConstants, 23).Interior.ColorIndex = 3
    Cells.SpecialCells(xlCellTypeFormulas, 23).Interior.ColorIndex = 3
End Sub

Tamer42 uzmanım, hücreleri renklendiren bu kodları da deneyebilirsiniz