İki tarih arasındaki "belirli süreyi" hesaplama

[meydan]

Arkadaşlar kolay gelsin;
Belki çok basit bir cevabı vardır ama ben bulamadım, sorum şu;
İki hücreye tarih giriyorum ve bu tarihler arasında hangi aydan kaç gün olduğunu hesaplamam lazım. örneğin; 15/01.2020 - 10/03.2020 tarihleri arasında Ocak'tan kaç gün, Şubat'tan kaç gün, Mart'tan kaç gün var gibi.
Şimdiden teşekkürler...

 

[Merhum İdris SERDAR]

.

Buradaki dosyayı inceleyin.

İki Tarih Arası Gün Dağılımı – Excel Gurusu

.

 

[Hepgel]

Merhaba @meydan

Deneyiniz.

Küçük tarih A1 de yazılıysa büyük tarih B1 de yazılıysa formülü herhangi bir hücreye uygulayıp aşağı doğru kopyalayın.

=EĞER(SERİAY($A$1;SATIR(A1)-1)>SERİAY($B$1;0);"";MİN($B$1;SERİAY($A$1;SATIR(A1)-1))-MİN($B$1;MAK($A$1;SERİAY($A$1;SATIR(A1)-2)+1))+1)

 

[Hepgel]

Merhaba @meydan

Deneyiniz.

Küçük tarih A1 de yazılıysa büyük tarih B1 de yazılıysa formülü herhangi bir hücreye uygulayıp aşağı doğru kopyalayın.

=EĞER(SERİAY($A$1;SATIR(A1)-1)>SERİAY($B$1;0);"";MİN($B$1;SERİAY($A$1;SATIR(A1)-1))-MİN($B$1;MAK($A$1;SERİAY($A$1;SATIR(A1)-2)+1))+1)

Gün sayılarını beli bir hücreden sağa doğru elde etmek için, verdiğim formüldeki SATIR ları SÜTUN yapmanız yeterli.

 

[meydan]

İkinize de teşekkür ederim @Hepgel @İdris SERDAR ama iki formülde de şöyle bir sıkıntı var; ilk tarihin ayını başlangıç olarak alıyor. Bende Ocak'tan başlayıp Aralık'ta biten 12 aylık bir seri var. Benim istediğim; ilk tarih Ocak değil de Şubat veya Mart olursa o aya kadar "0" yazsın veya boş geçsin.

 

[Merhum İdris SERDAR]

.

Bir de buna bakın.

İndir gündağ

Dosyayı indir gündağ

dosya.co

.

 

[Hepgel]

Bu şekilde denermisiniz.

=EĞER(YADA(SATIR(A1)<AY($A$1);SATIR(A1)>AY($B$1));0;MİN($B$1;SERİAY(TARİH(YIL($A$1);SATIR(A1);1);0))-MAK($A$1;TARİH(YIL($A$1);SATIR(A1);0)))

 

[meydan]

Teşekkürler @İdris SERDAR

 

[meydan]

Bu şekilde denermisiniz.

=EĞER(YADA(SATIR(A1)<AY($A$1);SATIR(A1)>AY($B$1));0;MİN($B$1;SERİAY(TARİH(YIL($A$1);SATIR(A1);1);0))-MAK($A$1;TARİH(YIL($A$1);SATIR(A1);0)))

Çok teşekkür ederim hocam.

 

[Hepgel]

Rica Ederim.
İyi Çalışmalar.

 

[meydan]

Çok özür dileyerek ufak bir düzeltme talep edebilir miyim; formülü bitiş tarihinden 1 gün öncesi olacak şekilde düzenleyebilir miyiz?
Mesele 01.02.2020 - 01.03.2020 tarihlerini girdiğimde sonuç "Şubat: 29" "Mart: 0" çıkması lazım ama
Sayın @Hepgel hocamın formülünde; "Şubat: 28" "Mart: 1"
@İdris SERDAR hocamın formülünde; "Şubat: 29" "Mart: 1" çıkıyor

 

[Hepgel]

Deneyiniz.

=EĞER(YADA($A$1="";$B$1="";$A$1>$B$1);0;MAK($A$1-1;MİN($B$1-1;SERİAY(TARİH(YIL($A$1);SATIR(A1);1);0)))-MİN($B$1-1;MAK($A$1-1;TARİH(YIL($A$1);SATIR(A1);0))))

 

[Merhum İdris SERDAR]

.
Şeklinde deneyin.

MAX(0;(MIN(Bitiş-1;DATE(YEAR(D$5);MONTH(D$5)+1;0))-MAX(Başlangıç;D$5)+1))

.

 

[Hepgel]

Küçük tarih A1 de büyük tarih B1 deyse ve son gün dikkate alınmayacaksa

=MİN($B$1-1;MAK($A$1-1;TARİH(YIL($A$1);SATIR(A1)+1;0)))-MİN($B$1-1;MAK($A$1-1;TARİH(YIL($A$1);SATIR(A1);0)))

.

 

[meydan]

Küçük tarih A1 de büyük tarih B1 deyse ve son gün dikkate alınmayacaksa

=MİN($B$1-1;MAK($A$1-1;TARİH(YIL($A$1);SATIR(A1)+1;0)))-MİN($B$1-1;MAK($A$1-1;TARİH(YIL($A$1);SATIR(A1);0)))

.

Çok teşekkür ederim @Hepgel hocam, bu sefer tamamdır

 

[Hepgel]

@meydan
Rica ederim
Dönüş yaptığınız için, Teşekkür ederim.
İyi Çalışmalar.