yeni sayfa ekleme

[ezkurtcan]

Merhaba,
sayfa kopyalama konusunda ufak bir yardıma ihtiyacım var. konuyu özetlemek gerekirse;
5-6 sayfadan oluşan excel tablomun ilk sayfasına bir buton koydum ve bu butona tıklayınca input box çıkıyor ve girdiğim kelimeyi sayfa adı yaparak sayfaların sonuna yeni bir sayfa ekliyor ama benim yapmak istediğim en son sayfayı kopyalayarak benim input boxa girdiğim ismi vermei. yardımcı olur mussunuz?

 

[N.Ziya Hiçdurmaz]

yanıt

Sub isimver()
On Error GoTo hata
Dim ad As String
ad = InputBox("Bir isim giriniz.")
Sheets(Sheets.Count).Name = ad
Exit Sub
hata:
MsgBox "Bir isim girmelisiniz.", vbInformation
End Sub

 

[ezkurtcan]

hocam pardon konuyu yanlış anlattım herhalde.
butona tıklayınca en son sıradaki sayfanın bir kopyasından oluşturacak ve ismini inputbox'tan alacak.

 

[Korhan Ayhan]

Selamlar,

Aşağıdaki kodu denermisiniz.

Option Explicit
 
Sub SAYFA_KOPYALA()
    Dim SAYFA_ADI As Variant
    
    SAYFA_ADI = Application.InputBox("Sayfa adı giriniz.")
    
    If SAYFA_ADI = False Then
    MsgBox "İşleminiz iptal edilmiştir.", vbInformation
    Exit Sub: End If
    
    If SAYFA_ADI = "" Then
    MsgBox "Lütfen sayfa adı giriniz. İşleminiz iptal edilmiştir.", vbInformation
    Exit Sub: End If
    
    Sheets(Sheets.Count).Copy After:=Sheets(Sheets.Count)
    
    On Error GoTo Devam
    ActiveSheet.Name = SAYFA_ADI
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
    Exit Sub
    
Devam:
    MsgBox "Aynı isimde sayfa bulunmaktadır. Eklenen son sayfa silinecektir.", vbCritical, "Dikkat !"
    Application.DisplayAlerts = False
    ActiveSheet.Delete
    Application.DisplayAlerts = True
End Sub

 

[omerceri]

Sub a()
Dim Message, Title, MyValue
Message = "Dosya İsmi yazınız" ' Set prompt.
Title = "DOSYA OLUŞTUR" ' Set title.

MyValue = InputBox(Message, Title)
say = Sheets.Count
Sheets(say).Copy After:=Sheets(say)
ActiveSheet.Name = MyValue

End Sub

 

[Korhan Ayhan]

Selamlar,

Buda benzer fakat "Error" (Hata) kontrolü yapılarak hazırlanmış başka bir örnek koddur.

Option Explicit
 
Sub SAYFA_KOPYALA()
    Dim SAYFA_ADI As Variant
 
    SAYFA_ADI = Application.InputBox("Sayfa adı giriniz.")
 
    If SAYFA_ADI = False Then
    MsgBox "İşleminiz iptal edilmiştir.", vbInformation
    Exit Sub: End If
 
    If SAYFA_ADI = "" Then
    MsgBox "Lütfen sayfa adı giriniz. İşleminiz iptal edilmiştir.", vbInformation
    Exit Sub: End If
 
    Sheets(Sheets.Count).Copy After:=Sheets(Sheets.Count)
 
    On Error Resume Next
    ActiveSheet.Name = SAYFA_ADI
    If Err = 1004 Then
    MsgBox "Aynı isimde sayfa bulunmaktadır. Eklenen son sayfa silinecektir.", vbCritical, "Dikkat !"
    Application.DisplayAlerts = False
    ActiveSheet.Delete
    Application.DisplayAlerts = True
    Else
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
    End If
End Sub

 

[erceee]

Merhaba arkadaşlar
Tekrar konu açmak istemedim o yüzden buraya yazıyorum. Benim sorunum en son çalışma sayfasını değil de, belirttiğim çalışma sayfasını kopyalamak. Her seferinde belirtmeyeceğim, örnek bir sayfa var, ekle butonu ile o sayfayı farklı isimle çoğaltmak.

Yardımcı olursanız sevinirim