Yavaş çalışan formül

[cerit]

Merhaba,
Formül işlemleri yavaşlatıyor, hızlı çalışacak alternatifi olabilir mi ?
EĞER(C6="";"";EĞERHATA(İNDİS(GİRİŞ!A:A&GİRİŞ!B:B&GİRİŞ!F:F;KAÇINCI("*"&C6&"*";GİRİŞ!G:G;0);1);" "))
Saygılar.

 

[Muzaffer Ali]

Merhaba.

Tam sütun başvurularını değiştirin.

Örnek: GİRİŞ!A:A yerine GİRİŞ!A1:A1000 yazın daha az başvuru daha fazla hız demektir.

 

[cerit]

hocam merhaba,
ilginize teşekkür ederim,
EĞER(C6="";"";EĞERHATA(İNDİS(GİRİŞ!A4:A200&GİRİŞ!B4:B200&GİRİŞ!F4:F200;KAÇINCI("*"&C6&"*";GİRİŞ!G4:G200;0);1);" "))
bu şekilde aralık seçtiğimde bazılarını getirmiyor.

 

[Muzaffer Ali]

Bu formül dizi formülüdür CTRL+SHIFT+ENTER ile giriş yapmalısınız.
Bunun dışında bir sorun görünmüyor.

Farklı bir çözüm olarak örnek olarak H sütununa ek bir sütun oluşturup =A4&B4&F4 formülü ile birleştirebilir ve bu sütunda arama yapabilirsiniz. Bu durumda dizi değil de normal formül kullanıp daha fazla hız kazanabilirsiniz.

=EĞER(C6="";"";EĞERHATA(İNDİS(GİRİŞ!H4:H200;KAÇINCI("*"&C6&"*";GİRİŞ!G4:G200;0));""))

Yapamazsanız dosyanızı ekleyin biz yapalım.

Dosyanızı dosya.co gibi bir paylaşım sitesine ekleyebilirsiniz.

 

[cerit]

hocam merhaba,
dosya büyük fakat,
=EĞER(C6="";"";EĞERHATA(İNDİS(GİRİŞ!A$4:A$200&GİRİŞ!B$4:B$200&GİRİŞ!F$4:F$200;KAÇINCI("*"&C6&"*";GİRİŞ!G$4:G$200;0);1);" "))
şeklinde çözüldü. Teşekkür ederim

 

[cerit]

merhaba,
=EĞER(C6="";"";EĞERHATA(İNDİS(GİRİŞ!A:A;KAÇINCI("*"&C6&"*";GİRİŞ!G:G;0))&İNDİS(GİRİŞ!B:B;KAÇINCI("*"&C6&"*";GİRİŞ!G:G;0))&İNDİS(GİRİŞ!F:F;KAÇINCI("*"&C6&"*";GİRİŞ!G:G;0));" "))
bu şekilde aralık seçmeden alternatif buldum.

 

[cerit]

merhaba,
EĞER(D4="";"";ÇOKETOPLA(OCAK!D:d;OCAK!C:C;D4))
bu formülün daha hızlı çalışan alternatifi olabilir mi?
Saygılar.

 

[Muzaffer Ali]

Merhaba.

=EĞER(D4="";"";ÇOKETOPLA(OCAK!D2:D1000;OCAK!C2:C1000;D4))

yada son satırı dinamik olarak belirlemek isterseniz.

=EĞER(D4="";"";ÇOKETOPLA(OCAK!D2:D&KAÇINCI(9999999;OCAK!D:D);OCAK!C2:C&KAÇINCI(9999999;OCAK!C:C);D4))

 

[cerit]

Hocam merhaba,
İlginize teşekkür ederim,
Satır sayısı değiştiğinden dolayı, aralık seçmeden daha uygun formül.
Fakat formülü çalıştıramadım.

 

[Korhan Ayhan]

Formüle DOLAYLI fonksiyonu eklenmelidir.

 

[Muzaffer Ali]

Uyarı için teşekkürler Korhan bey.

Formülü denemeden paylaştım.
Bu formülü deneyin.

=EĞER(D4="";"";ÇOKETOPLA(DOLAYLI("OCAK!D2:D"&KAÇINCI(9999999;OCAK!D:D));DOLAYLI("OCAK!C2:C"&KAÇINCI("zzz";OCAK!C:C));D4))