Veri Doğrulamada Kopyala Yapıştır

[umit1907]

Merhabalar,
Veri doğrulama uygulanmış bir hücreye kopyala özel yapıştır ile veri yapıştırabiliyoruz. burada veriler yanlış olsada kabul ediyor bunu makro ile engelleyebilirmiyiz. Böyle bir kod varmıdır.

 

[Korhan Ayhan]

Deneyiniz.

Doğrulama olan sayfanızın kod bölümüne uygulayınız.

Birkaç deneme yaptım. Düzgün çalışıyor gibi görünüyor.

Option Explicit

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim DataValidation As Variant
    On Error GoTo Son
    If Application.CutCopyMode = xlCopy Or Application.CutCopyMode = xlCut Then
        Application.EnableEvents = False
        If Target.Cells.Count = 1 Then
            On Error Resume Next
            DataValidation = Target.Validation.Formula1
            On Error GoTo 0
            If DataValidation <> Empty Then
                MsgBox "Seçtiğiniz hücrede veri doğrulama var!" & Chr(10) & "Kopyalama yapılamaz!", vbCritical
                Application.CutCopyMode = False
                GoTo Son
                Exit Sub
            End If
        Else
            On Error Resume Next
            Set DataValidation = Target.Cells.SpecialCells(xlCellTypeAllValidation)
            On Error GoTo 0
            If Not DataValidation Is Nothing Then
                MsgBox "Seçtiğiniz alanda veri doğrulama var!" & Chr(10) & "Kopyalama yapılamaz!", vbCritical
                Application.CutCopyMode = False
                Target.Cells(1, 1).Select
                GoTo Son
                Exit Sub
            End If
        End If
    End If
Son: Application.EnableEvents = True
End Sub

 

[umit1907]

Merhaba Korhan Abi eline teşekkürler.

 

[ANIL51]

Merhaba, Makro ile de çok yeni tanıştım, bilgim sınırlı. Dosyamda birden fazla sütün için veri doğrulaması yaptırmam gerekiyor. Sorum kopyala-yapıştır işleminde de "Veri Doğrulama" nın devam etmesini nasıl sağlarım. Bu konu açılmış verdiğiniz cevabı da gördüm fakat kullanım konusunda başarılı olamadım. Teşekkürler.

 

[Korhan Ayhan]

Merhaba,

Veri doğrulama işleminde bu sorun maalesef var. Birçok yapıştırma metodu olduğu için bunu kontrol altına almak zordur. Bu sebeple kopyala-yapıştır işlemini pasif hale getirmekte fayda var.

Üstte vermiş olduğum kodu veri doğrulama kullandığınız sayfanızın kod bölümüne uygularsanız. Kopyalama işleminden sonra hücre seçimi yaptığınızda hücrede doğrulama varsa size uyarı verecektir.

Ek olarak sayfaya veri giriş işlemlerini userform kullanarak yapabilirsiniz.