VBA Combobox hücreye veri aktarma

[matit35]

Öncelikle forumda çok aradığımı ama bulamadığımı belirtmeliyim. Şimdiden teşekkür ederim. Sorum şu;

Excel VBA da combobox'un değerlerini Sayfa2 A1:A10 arasından alıp, seçildiği taktirde değerlerin Sayfa1 A1 hücresine yazılmasını istiyorum.

Bu işlemi commandbutton ile yapmak istiyorum. Yani butona her basışta Değer A1, A2 A3 e yazılarak devam etmesini istiyorum. Bunun için gerekli kodu yazabilirseniz çok sevinirim. Çok teşekkürler.

 

[Orion1]

sitede bu konu ile çok örnek var.
Adeta bunlarla dolu.
aşağıdaki kodlar işinizi görecektir.Bir butona yapıştırınız.

Dim s1 As Worksheet, sat As Long
Set s1 = Sheets("Sayfa1")
sat = s1.Cells(Rows.Count, "A").End(xlUp).Row + 1
s1.Cells(sat, "A").Value = ComboBox1.Value

 

[matit35]

Dosya da ekleyemedim ama bu formul ile Sayfa 2 A sütunundaki verileri verileri sayfa 1 e yazdıramadım. Comboboxta sayfa 2 deki veriler görünmüyor.

 

[matit35]

Deniyorum ama olmuyor. Bir şeyi yanlış yapıyorum. Liste görünmüyor.

 

[Korhan Ayhan]

Bir form oluşturun. Form üzerine bir adet Combobox ekleyin.

Formunuzun kod bölümüne aşağıdaki kodu uygulayın.

Dim S1 As Worksheet, S2 As Worksheet, Satir As Long

Private Sub CommandButton1_Click()
    If S1.Range("A1") = "" Then
        Satir = 1
    Else
        Satir = S1.Cells(S1.Rows.Count, 1).End(3).Row + 1
    End If
    S1.Cells(Satir, 1) = ComboBox1
    MsgBox "Kayıt işlemi tamamlanmıştır.", vbInformation
End Sub

Private Sub UserForm_Initialize()
    Set S1 = Sheets("Sayfa1")
    Set S2 = Sheets("Sayfa2")
    ComboBox1.RowSource = "'" & S2.Name & "'!A1:A10"
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    Set S1 = Nothing
    Set S2 = Nothing
End Sub

 

[matit35]

Korhan Bey cevabınız için çok teşekkürler. Command butona tıkladığımda

If S1.Range("A1") = "" Then sarı uyarı veriyor.

Liste falan görünüyor ama.

 

[matit35]

Tamam hallettim çok teşekkür ederim Korhan Bey