Varsa sil nasıl denir?

[Tevfik_Kursun]

Merhaba Arkadaşlar,
Acaba Deneme_Kutusu adlı TextBox varsa sil nasıl denir?
Saygılarımla

 

[Tevfik_Kursun]

Merhaba Arkadaşlar,

Sub Kutu_Sil()
    If Range(Array("Deneme_Kutusu")) Then
        ActiveSheet.Shapes.Range(Array("Deneme_Kutusu")).Select
        Selection.Delete
    End If
End Sub

If Range(Array("Deneme_Kutusu")) Then
satırda 1004 kodlu hata geliyor. Bu hata nasıl giderilir?
Saygılarımla

 

[Haluk]

Nesneyi eklerken "Set" ile atama yapıp, nesnenin ismini atarsanız, sonradan bulmak kolay olur....

Sub TextBox_Ekle()
    Set myBox = ActiveSheet.Shapes.AddTextbox(msoTextOrientationHorizontal, Range("B5").Top, Range("B5").Left, 100, 100)
    myBox.Name = "Deneme_Kutusu"
End Sub
'
Sub TextBox_Sil()
    For i = 1 To ActiveSheet.Shapes.Count
        If ActiveSheet.Shapes(i).Name = "Deneme_Kutusu" Then ActiveSheet.Shapes(i).Delete
    Next
End Sub

.

 

[Tevfik_Kursun]

Sayın Haluk Hocam,
Çok teşekkür ederim.
Saygılarımla

 

[Muzaffer Ali]

Merhaba.

Alternatif silme aşağıdaki gibi de yapılabilir.

Sub TextBox_Sil()
    ActiveSheet.Shapes("Deneme_Kutusu").Delete
End Sub

 

[Haluk]

Merhaba.

Alternatif silme aşağıdaki gibi de yapılabilir.

......

Sayfada nesneyi bulamadığı zaman hata verir....

.

 

[ÖmerFaruk]

.edit

 

[Haluk]

Alternatif

3 No'lu mesajdaki koddan (çok) farklı değil...

.

 

[ÖmerFaruk]

Pardon. Ben alttaki kodu yanlış görmüşüm.

 

[Korhan Ayhan]

Hata kontrolüde işe yarayabilir.

Option Explicit

Sub Varsa_Sil()
    Dim Nesne As Shape
    
    On Error Resume Next
    Set Nesne = Nothing
    Set Nesne = Sheets("Sheet1").Shapes("Deneme_Kutusu")
    On Error GoTo 0
    
    If Not Nesne Is Nothing Then
        Nesne.Delete
    Else
        MsgBox "Deneme_Kutusu isimli nesne bulunamadı!", vbCritical
    End If
End Sub

 

[Muzaffer Ali]

Hata kontrollü alternatif

Sub TextBox_Sil()
    On Error GoTo nesneyok
    ActiveSheet.Shapes("Deneme_Kutusu").Delete
    Exit Sub
nesneyok:
    MsgBox "'Deneme_Kutusu' adlı nesne bulunamıyor."
End Sub