Var Olan Verilere Göre Tablo Oluşturma

[Astalavista58]

Merhaba hayırlı akşamlar, benim yapmak istediğim ekteki örnek tabloda, Sayfa1'de "A" sütununda yer alan şehir isimlerinin, B, C, D sütunlarında sadece veri olanları, Sayfa2'de tablo olarak bana versin. Makro ile nasıl yapabilirim, yardımcı olabilir misiniz.

 

[Korhan Ayhan]

Sayfa2'nin kod bölümüne uygulayınız.

Sayfa1'den Sayfa2'ye geçtiğinizde kod sonuç verecektir.

Option Explicit

Private Sub Worksheet_Activate()
    Dim S1 As Worksheet, S2 As Worksheet, Son As Long, Y As Byte
    Dim Veri As Variant, X As Long, Say As Long, Kontrol As Boolean
    
    Set S1 = Sheets("Sayfa1")
    Set S2 = Sheets("Sayfa2")
    
    S2.Range("A2:D" & S2.Rows.Count).Clear
    
    Son = S1.Cells(S1.Rows.Count, 1).End(3).Row
    If Son < 3 Then Son = 3
    
    Veri = S1.Range("A2:D" & Son).Value
    
    ReDim Liste(1 To Son, 1 To 4)
    
    For X = LBound(Veri, 1) To UBound(Veri, 1)
        Kontrol = False
        For Y = 2 To 4
            If Veri(X, Y) <> "" Then
                Kontrol = True
                Exit For
            End If
        Next
        If Kontrol = True Then
            Say = Say + 1
            Liste(Say, 1) = Veri(X, 1)
            Liste(Say, 2) = Veri(X, 2)
            Liste(Say, 3) = Veri(X, 3)
            Liste(Say, 4) = Veri(X, 4)
        End If
    Next
    
    If Say > 0 Then
        S2.Range("A2").Resize(Say, 4) = Liste
        S2.Range("A2").Resize(Say, 4).Borders.LineStyle = 1
        S2.Range("B:D").HorizontalAlignment = xlCenter
        MsgBox "Veri aktarımı tamamlanmıştır.", vbInformation
    Else
        MsgBox "Uygun veri bulunamadı!", vbExclamation
    End If

    Set S1 = Nothing
    Set S2 = Nothing
End Sub

 

[Astalavista58]

Korhan Bey çok teşekkür ederim, kod çalışıyor elinize sağlık.

 

[NIGRA]

Merhaba hayırlı akşamlar, benim yapmak istediğim ekteki örnek tabloda, Sayfa1'de "A" sütununda yer alan şehir isimlerinin, B, C, D sütunlarında sadece veri olanları, Sayfa2'de tablo olarak bana versin. Makro ile nasıl yapabilirim, yardımcı olabilir misiniz.

Neden pivot tablo ile yapmayı tercih etmediniz acaba merak ettim.

 

[Astalavista58]

Verileri sürekli farklı Excel dosyalarından makro ile alıyorum, bu şekil daha kolay geldi. Pivot ile hiç denemedim doğrusu.