text kaydetmek (formatlı)

[k0081]

Merhaba arkadaşlar;

buton yardımı ile excel tablomdaki değerleri bir text dosyasına oluşturmak istiyorum. text içeriği;

"panel",2.00,4.00,0.00,"blok1",1 bu biçimde olması gerekli..

örnek dosyaları ekliyorum

Ekli dosyayı görüntüle kitap1.rar

yardımcı arkadaşlara şimdiden teşekkürler..

 

[Necdet]

Merhaba,

Aşağıdaki kodları dener misiniz?

Private Sub CommandButton1_Click()
 
    Dim i       As Long, _
        Satir   As String, _
        b       As String, _
        c       As String, _
        d       As String, _
        Yol     As String, _
        Dosya   As String
    
    Yol = Application.ThisWorkbook.Path & Application.PathSeparator
    Dosya = "Deneme.txt"
    
    Open Yol & Dosya For Output As #1
    
    For i = 2 To Cells(Rows.Count, "A").End(3).Row
        b = Replace(Format(Cells(i, "B"), "0.00"), ",", ".")
        c = Replace(Format(Cells(i, "C"), "0.00"), ",", ".")
        d = Replace(Format(Cells(i, "D"), "0.00"), ",", ".")
        
        Satir = """" & Cells(i, "A") & """" & "," & _
                b & "," & _
                c & "," & _
                d & "," & _
                """" & Cells(i, "E") & """" & "," & _
                Cells(i, "F")
                
        Print #1, Satir
    Next i
    
    Close #1
    
    MsgBox "Text Dosyası OLUŞTURULMUŞTUR......", vbInformation, "N. YEŞERTENER"
    
End Sub

 

[k0081]

Necdet Yeşertener;

hocam çok teşekkürler.. tamamdır.. elinize yüreğinize sağlık..

 

[Necdet]

Güle güle kullanınız.