Tarihleri, ayrı bir tabloda gösterilmesi

[1903emre34@gmail.com]

Merhabalar,

Sayfa 1'de yer alan A sütünda firmaların (A ve B) denetim tarihleri, B sütünda isimleri gözükmektedir; ben istiyorum ki firma isim seçip tarihleri küçükten büyüğe tablo halinde sıralanması istiyorum istenen sayfa2 yer almıştır. nasıl kod oluşturabiliriz (Tablo en fazla 5 satır şeklinde)

http://s9.dosya.tc/server2/9z2it0/TARIH_.zip.html

 

[Korhan Ayhan]

Deneyiniz.

Sub FİRMA_BAZINDA_TARİH_LİSTESİ()
    Dim S1 As Worksheet, S2 As Worksheet
    Dim Firma As String, Son As Long, Veri As Range
    Dim Satir As Long, Sutun As Integer
    
    Set S1 = Sheets("Sayfa1")
    Set S2 = Sheets("Sayfa2")
    
    Firma = UCase(Replace(Replace(S2.Range("D6").Value, "ı", "I"), "i", "İ"))
    Son = S1.Cells(S1.Rows.Count, 1).End(3).Row
    S2.Range("D7:L12").ClearContents
    Satir = 7
    Sutun = 4
    
    For Each Veri In S1.Range("B2:B" & Son)
        If UCase(Replace(Replace(Veri.Value, "ı", "I"), "i", "İ")) = Firma Then
            S2.Cells(Satir, Sutun) = Veri.Offset(0, -1).Value
            Satir = Satir + 1
            If Satir > 12 Then
                Satir = 7
                Sutun = Sutun + 1
            End If
        End If
    Next
    
    S2.Cells.EntireColumn.AutoFit

    Set S1 = Nothing
    Set S2 = Nothing
    
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[1903emre34@gmail.com]

çok teşekkürler,

iyi çalışmalar