Tarihlere göre tablodaki verileri ilgili aylara taşımak

[Mesafe]

Yanlarında tarihler olan bir tablom var ve bu tablomdaki ürünleri tarihlerine göre ilgili aylara taşımak istiyorum. Örnek dosyada da manuel olarak verileri taşıdım net bir şekilde görülebilir, bunu formül ile yapabilmek mümkün mü ?

 

[Korhan Ayhan]

Merhaba,

Eğer işinize makrolu çözüm yararsa ekteki örnek dosyayı inceleyiniz.

Kullanılan kod;

Option Explicit
 
Sub AYLIK_ÖZET_RAPOR()
    Dim S1 As Worksheet, S2 As Worksheet, Hücre As Range
    Dim AY As String, BUL As Range, Satır As Long
    
    Application.ScreenUpdating = False
    
    Set S1 = Sheets("Sayfa1")
    Set S2 = Sheets("Sayfa2")
    
    S2.Range("A3:AJ" & Rows.Count).ClearContents
    
    For Each Hücre In S1.Range("D3:G" & S1.Cells(Rows.Count, 1).End(3).Row)
        If Hücre.Value <> "" Then
            AY = Format(Hücre.Value, "mmmm")
            Set BUL = S2.Cells.Find(AY)
            If Not BUL Is Nothing Then
                Satır = S2.Cells(Rows.Count, BUL.Column).End(3).Row + 1
                S2.Cells(Satır, BUL.Column) = S1.Cells(Hücre.Row, 1)
                S2.Cells(Satır, BUL.Column + 1) = S1.Cells(Hücre.Row, 2)
                S2.Cells(Satır, BUL.Column + 2) = S1.Cells(Hücre.Row, 3)
            End If
        End If
    Next
 
    S2.Cells.EntireColumn.AutoFit
    S2.Select
    
    Set BUL = Nothing
    Set S1 = Nothing
    Set S2 = Nothing
    
    Application.ScreenUpdating = True
    
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[bogazincocugu]

selamlar,

dosyanızda her ürün için aynı ayda bir gün bulunuyor. iki kere şubat yazma ihitmali var mıdır?

eğer öyleyse toplam almanız gerekecek cünkü...

 

[Mesafe]

Korhan Bey, çok teşekkür ederim. vermiş olduğunuz kodlar ile 500 satırlık listemi birkaç saniyede aylara ayırabildim. Allah razı olsun.

Formül ile çözüm getirmiş arkadaşlarında alternatif çözümlerini paylaşmalarını rica ederim.

 

[Mesafe]

selamlar,

dosyanızda her ürün için aynı ayda bir gün bulunuyor. iki kere şubat yazma ihitmali var mıdır?

eğer öyleyse toplam almanız gerekecek cünkü...

Her sütunda bir tarih var ve diğer sutunda aynı aya ait bir tarih olmuyor. her sutunda ayrı bir ayın tarihi var

 

[webuyeislemleri]

Aylara göre ekte ki dosyayı nasıl düzenlerim

Sizin makroyu ekteki dosyaya uygulayamadım yardımlarınızı bekliyorum.