Tarih ve Cari Koda göre toplama

[RALKAN]

Merhaba ,

Ek'te bulunan örnek dosyanın sayfa2 de bulunan verilerini veritabanından sorgu ile alarak sayfa 1 de şablondaki kriterlere göre toplamlarını (Kod ve tarih aralığında) getirmek istiyorum fakat " çoketopla - topla.çarpım ve topla eğer" gibi fonksiyonlarla bir türlü değerleri getiremedim.
Bu konuda yardımlarınızı rica ediyorum

 

[Huseyinkis]

Merhaba ,

Ek'te bulunan örnek dosyanın sayfa2 de bulunan verilerini veritabanından sorgu ile alarak sayfa 1 de şablondaki kriterlere göre toplamlarını (Kod ve tarih aralığında) getirmek istiyorum fakat " çoketopla - topla.çarpım ve topla eğer" gibi fonksiyonlarla bir türlü değerleri getiremedim.
Bu konuda yardımlarınızı rica ediyorum

Ekli Formulu Denemisiniz.

Formulu D8 hücresine kopyalayıp sonra sağa doğru çekiniz.

=TOPLA.ÇARPIM((Sayfa2!$A$2:$A$142=$A9)*(SAYIYAÇEVİR(Sayfa2!$E$2:$E$142)>=E$5)*(SAYIYAÇEVİR(Sayfa2!$E$2:$E$142)<=E$6)*(Sayfa2!$H$2:$H$142))-TOPLA.ÇARPIM((Sayfa2!$A$2:$A$142=$A9)*(SAYIYAÇEVİR(Sayfa2!$E$2:$E$142)>=E$5)*(SAYIYAÇEVİR(Sayfa2!$E$2:$E$142)<=E$6)*(Sayfa2!$I$2:$I$142))

 

[asi_kral]

Merhaba ,

Ek'te bulunan örnek dosyanın sayfa2 de bulunan verilerini veritabanından sorgu ile alarak sayfa 1 de şablondaki kriterlere göre toplamlarını (Kod ve tarih aralığında) getirmek istiyorum fakat " çoketopla - topla.çarpım ve topla eğer" gibi fonksiyonlarla bir türlü değerleri getiremedim.
Bu konuda yardımlarınızı rica ediyorum

Merhaba

=ÇOKETOPLA(BORC;VADE_TARİHİ;">="&D$5;VADE_TARİHİ;"<="&D$6;KODU;$A8)-ÇOKETOPLA(KAPANAN_TUTAR;K_VADE_TARIHI;">="&D$5;K_VADE_TARIHI;"<="&D$6;KODU;$A8)

Bu formülü dener misiniz_?

 

[excelci1]

SAYFA1 D8 e yazıp aşağı ve sağa doğru kopyalayın

=TOPLA.ÇARPIM(--(Sayfa2!$A$2:$A$142=$A8);--(Sayfa2!$D$2:$D$142<=D$6);--(Sayfa2!$D$2:$D$142>=D$5);--(Sayfa2!$H$2:$H$142))

not doğru çalışabilmesi için
sayfa 2 deki tarihlerin tarih olarak düzeltilmesi gerekiyor. metin olarak gözüktüğünden sonuç alamamışsınız.

ilk önce en üstteki tarihe f2 ile girip entıra basın
hızlıca tarihe çevirmek için boş bir hücreye 1 yazın ve kopyalayın
f2 entır yaptığınız hücreden itibaren hepsini seçip sağ tuş>özel yapıştır>değerleri > çarp işaretleyin ve tamam deyin. formül çalışacaktır.

 

[RALKAN]

Ekli Formulu Denemisiniz.

Formulu D8 hücresine kopyalayıp sonra sağa doğru çekiniz.

=TOPLA.ÇARPIM((Sayfa2!$A$2:$A$142=$A9)*(SAYIYAÇEVİR(Sayfa2!$E$2:$E$142)>=E$5)*(SAYIYAÇEVİR(Sayfa2!$E$2:$E$142)<=E$6)*(Sayfa2!$H$2:$H$142))-TOPLA.ÇARPIM((Sayfa2!$A$2:$A$142=$A9)*(SAYIYAÇEVİR(Sayfa2!$E$2:$E$142)>=E$5)*(SAYIYAÇEVİR(Sayfa2!$E$2:$E$142)<=E$6)*(Sayfa2!$I$2:$I$142))

Sayın HüseyinKis merhaba ,

Verdiğiniz formül Borç Alacak sütunları baz alınarak yapıldığında sonucu doğru veriyor fakat benim işlemim aşağıda ki şekilde olması gerekiyor.

Borç toplamı için -
Sayfa2 A sütundaki kodlar
Sayfa2 D sütundaki tarihler
Sayfa2 H sütundaki tutarlar

ve
- işlem için

Sayfa2 A sütundaki kodlar
Sayfa2 k sütundaki tarihler
Sayfa2 P sütundaki tutarlar

baz alınarak yapamıyorum.
Bu konuda yardımlarınızı rica edebilirmiyim.

 

[RALKAN]

Merhaba

=ÇOKETOPLA(BORC;VADE_TARİHİ;">="&D$5;VADE_TARİHİ;"<="&D$6;KODU;$A8)-ÇOKETOPLA(KAPANAN_TUTAR;K_VADE_TARIHI;">="&D$5;K_VADE_TARIHI;"<="&D$6;KODU;$A8)

Bu formülü dener misiniz_?

Merhaba sayın asi_kral ,

Önerdiğin formülü benzer şekilde denemiştim fakat sonuç gelmiyor.

Teşekkürler

 

[Huseyinkis]

120.0001 için haziran aynda 104728 sonucu verdi diğerleri sıfır.
120.0015 için ocak ayında 61218,40 sonucu verdi diğerleri sıfır.

=TOPLA.ÇARPIM((Sayfa2!$A$2:$A$142=$A8)*(SAYIYAÇEVİR(Sayfa2!$D$2:$D$142)>=D$5)*(SAYIYAÇEVİR(Sayfa2!$D$2:$D$142)<=D$6)*(Sayfa2!$H$2:$H$142))-TOPLA.ÇARPIM((Sayfa2!$A$2:$A$142=$A8)*(SAYIYAÇEVİR(Sayfa2!$K$2:$K$142)>=D$5)*(SAYIYAÇEVİR(Sayfa2!$K$2:$K$142)<=D$6)*(Sayfa2!$P$2:$P$142))

 

[RALKAN]

120.0001 için haziran aynda 104728 sonucu verdi diğerleri sıfır.
120.0015 için ocak ayında 61218,40 sonucu verdi diğerleri sıfır.

=TOPLA.ÇARPIM((Sayfa2!$A$2:$A$142=$A8)*(SAYIYAÇEVİR(Sayfa2!$D$2:$D$142)>=D$5)*(SAYIYAÇEVİR(Sayfa2!$D$2:$D$142)<=D$6)*(Sayfa2!$H$2:$H$142))-TOPLA.ÇARPIM((Sayfa2!$A$2:$A$142=$A8)*(SAYIYAÇEVİR(Sayfa2!$K$2:$K$142)>=D$5)*(SAYIYAÇEVİR(Sayfa2!$K$2:$K$142)<=D$6)*(Sayfa2!$P$2:$P$142))

Merhaba ,

Sonuç doğru çıkmakta teşekkür ederim.

İyi Çalışmalar