Tarih formatında hata

[tamer42]

Merhaba Arkadaşlar,
Ekli dosyada gün, ay yıl bilgilerini birleştirerek Tarih formatına getirmek istediğimde; Gün ve Ay bilgilerini hücreye ters olarak yazıyor..

Nasıl bir düzenleme yapmam gerekir?

Dim LValue As String
Set Sh11 = Sheets("Sayfa1")

k = 2

     d1 = Sh11.Cells(k, 1).Value
     d2 = Sh11.Cells(k, 2).Value
     d3 = Sh11.Cells(k, 3).Value
     
myDate = DateSerial(d3, d2, d1)

LValue = Format(myDate, "dd/mm/yyyy")

Sh11.Range("G1") = LValue

Teşekkürler,

iyi Çalışmalar.

 

[YUSUF44]

Bu kodlar tarihi metin formatına dönüştürüyor. Hata da bundan kaynaklanıyor muhtemelen. Eğer metin olarak size lazım değilse aşağıdaki gibi kullanın:

Sub dTest()

Dim LValue As String
Set Sh11 = Sheets("Sayfa1")

k = 2
     d1 = Sh11.Cells(k, 1).Value
     d2 = Sh11.Cells(k, 2).Value
     d3 = Sh11.Cells(k, 3).Value
    
mydate = DateSerial(d3, d2, d1)

Sh11.Range("G1") = mydate
Sh11.Range("G1").NumberFormat = "dd/mm/yyyy"

End Sub

Hatta d1, d2 ve d3'e ihtiyaç olmadan aşağıdaki gibi olabilir:

Sub dTest()

Dim LValue As String
Set Sh11 = Sheets("Sayfa1")

k = 2
    
Sh11.Range("G1") = DateSerial(Sh11.Cells(k, 3), Sh11.Cells(k, 2), Sh11.Cells(k, 1))
Sh11.Range("G1").NumberFormat = "dd/mm/yyyy"

End Sub

,


Hatta anladığım kadarıyla döngüyle son satıra kadar kullanmak istiyorsunuz, şöyle olabilir:

Sub dTest()

Set Sh11 = Sheets("Sayfa1")
son = Sh11.Cells(Rows.Count, "A").End(3).Row

For k = 2 To son
    If IsNumeric(Sh11.Cells(k, 3)) And IsNumeric(Sh11.Cells(k, 2)) And IsNumeric(Sh11.Cells(k, 1)) Then
        Sh11.Cells(k, "D") = DateSerial(Sh11.Cells(k, 3), Sh11.Cells(k, 2), Sh11.Cells(k, 1))
        Sh11.Cells(k, "D").NumberFormat = "dd/mm/yyyy"
    Else
        Sh11.Cells(k, "D").ClearContents
    End If
Next

End Sub

 

[tamer42]

Sh11.Range("G1").NumberFormat = "dd/mm/yyyy"

Yusuf Hocam çok teşekkürler,