Soru Sıralama

[NADİR YILDIZ]

arkadaşlar

örnek dosyamda I ve J sütunlarını aynı butonda hem muh.koduna göre sıralama hemde ünvana göre sıralama yapmak istiyorum.
benim tercihime göre sıralama yapacak

iyi çalışmalar

 

[NADİR YILDIZ]

arkadaşlar çözüm önerisi olan varmı ?

 

[veyselemre]

Çalıştırmadan önce I sütunundan bir hücre seçili ise I sütununa göre sıralayacak, diğer hallerde J sütununa göre sıralayacak.

Sub test()
    If Selection.Column = 9 Then
        Range("I4:J" & Cells(Rows.Count, "I").End(3).Row).Sort [I5], , [J5], , , , , xlYes
    Else
        Range("I4:J" & Cells(Rows.Count, "I").End(3).Row).Sort [J5], , [I5], , , , , xlYes
    End If
End Sub

 

[Korhan Ayhan]

Alternatif;

"Inputbox" uygulaması ile seçenekli sıralama yapılmaktadır.

Option Explicit

Sub Sirala()
    Dim Opsiyon As Byte
    
    Opsiyon = InputBox("Sıralama opsiyonunu giriniz..." & vbLf & vbLf & _
                       "1 yazarsanız I sütununa göre sıralama yapabilirsiniz." & vbLf & _
                       "2 yazarsanız J sütununa göre sıralama yapabilirsiniz." & vbLf & _
                       "3 yazarsanız I-J sütunlarına göre sıralama yapabilirsiniz.", "SIRALAMA OPSİYONU", 1)
                       
    If Opsiyon >= 1 And Opsiyon <= 3 Then
        Select Case Opsiyon
            Case 1
                Range("I4:J" & Rows.Count).Sort Range("I5"), xlAscending, , , , , , xlYes
            Case 2
                Range("I4:J" & Rows.Count).Sort Range("J5"), xlAscending, , , , , , xlYes
            Case 3
                Range("I4:J" & Rows.Count).Sort Range("I5"), xlAscending, Range("J5"), , xlAscending, , , xlYes
        End Select
        MsgBox "Veriler sıralanmıştır.", vbInformation
    Else
        MsgBox "1-2-3 değerlerinden birisini yazabilirsiniz!", vbExclamation
    End If
End Sub
[/code9

 

[NADİR YILDIZ]

Veysel bey teşekkür ederim.

tam istediğim gibi olmuş

iyi çalışmalar

 

[NADİR YILDIZ]

Korhan bey teşekkür ederim.
her zamanki gibi üstatlığınızla değişik bir çözüm önerisi sundunuz

iyi çalışmalar