Secilen satırı yeni sayfada gosterme ?

[romendo]

Merhaba ,

GENERAL REPORT sayfasında da kayıtlar var.
sheet1 deki combobox da general report daki course code ları yazıo. bunlardan birini secip report butonuna tıkladım zaman yeni bir sayfa acılıp ilgili satırı geitirmesini istiyorum . fakat çözemedim

ilginiz icin teşekkürler.

 

[Ömer]

Merhaba ,

GENERAL REPORT sayfasında da kayıtlar var.
sheet1 deki combobox da general report daki course code ları yazıo. bunlardan birini secip report butonuna tıkladım zaman yeni bir sayfa acılıp ilgili satırı geitirmesini istiyorum . fakat çözemedim

ilginiz icin teşekkürler.

Merhaba,

Bu şekilde deneyin.

Sub BulAcAktar()
 
    Dim Sg As Worksheet, S1 As Worksheet, syf As String
    Dim c As Range, sat As Long
 
    Set Sg = Sheets("GENERAL REPORT")
    Set S1 = Sheets("Sheet1")
 
    Application.ScreenUpdating = False
    
    syf = S1.Range("B3")
    If syf = "" Then Exit Sub
    
    If Not varmi(syf) Then
        Sheets.Add After:=Worksheets(Worksheets.Count)
        ActiveSheet.Name = syf
        Sg.Rows(1).Copy Sheets(syf).Range("A1")
    Else
        Sheets(syf).Select
        Cells.Clear
        Sg.Rows(1).Copy Sheets(syf).Range("A1")
    End If
    
    sat = 2
    Set c = Sg.[A:A].Find(syf, , xlValues, xlWhole)
    If Not c Is Nothing Then
        Adr = c.Address
        Do
            Sg.Rows(c.Row).Copy Sheets(syf).Range("A" & sat)
            sat = sat + 1
            Set c = Sg.[A:A].FindNext(c)
        Loop While Not c Is Nothing And c.Address <> Adr
    End If
 
    Application.ScreenUpdating = True
    
End Sub
 
Function varmi(adi As String) As Boolean
    On Error Resume Next
    varmi = CBool(Len(Worksheets(adi).Name) > 0)
End Function

.

 

[romendo]

Çok Teşekkürler

 

[romendo]

bir soru daha sorsam sakıncası yoksa
aynı coursename den 2 tane warsa
onları nası alt alta gore bılırım ?

 

[Ömer]

#2 numaralı mesajı bu doğrultuda düzenledim. Tekrar denermisiniz.

 

[romendo]

çok teşekkur ederim ilginiz icin