Search (arama) kodu küçük büyük harf duyarlılığı kaldırma

[sinnernekolens]

İyi günler arkadaşlar, aşağıdaki kodda küçük ve büyük harf duyarlılığını nasıl yok edebilirim? Yani küçük harfle de yazsam bulacak büyük harfle de yazsam bulacak. yardımlarınızı rica ederim.

Private Sub TextBox1_Change()
Dim X As Long, Y As Byte, Z As Byte, Uzunluk As Integer
If Me.TextBox1 = "" Then
ListBox1.RowSource = "veri!A2:K" & Sheets("veri").Cells(Rows.Count, 1).End(3).Row
Else
Me.ListBox1.RowSource = ""
End If
On Error Resume Next
TextBox1.Text = Evaluate("=UPPER(""" & Me.TextBox1.Text & """)")
ListBox1.Clear

For X = 2 To Application.WorksheetFunction.CountA(Sheets("veri").Range("A:K"))
For Y = 1 To 12
Uzunluk = Len(TextBox1.Text)
If Left(Sheets("veri").Cells(X, Y).Value, Uzunluk) = TextBox1.Text And TextBox1.Text <> "" Then
ListBox1.AddItem Sheets("veri").Cells(X, 1).Value
For Z = 1 To 12
ListBox1.List(ListBox1.ListCount - 1, Z) = Sheets("veri").Cells(X, Z + 1).Value
Next
End If
Next
Next
End Sub

 

[Ömer]

Merhaba,

Bu şekilde deneyin.

Private Sub TextBox1_Change()
Dim X As Long, Y As Byte, Z As Byte, Uzunluk As Integer
Dim deg1 As String, deg2 As String
If Me.TextBox1 = "" Then
ListBox1.RowSource = "veri!A2:K" & Sheets("veri").Cells(Rows.Count, 1).End(3).Row
Else
Me.ListBox1.RowSource = ""
End If
On Error Resume Next
'TextBox1.Text = Evaluate("=UPPER(""" & Me.TextBox1.Text & """)")
ListBox1.Clear

For X = 2 To Application.WorksheetFunction.CountA(Sheets("veri").Range("A:K"))
For Y = 1 To 12
Uzunluk = Len(TextBox1.Text)
deg1 = UCase(Replace(Replace(Left(Sheets("veri").Cells(X, Y).Value, Uzunluk), "ı", "I"), "i", "İ"))
deg2 = UCase(Replace(Replace(TextBox1.Text, "ı", "I"), "i", "İ"))
If deg1 = deg2 And TextBox1.Text <> "" Then
ListBox1.AddItem Sheets("veri").Cells(X, 1).Value
For Z = 1 To 12
ListBox1.List(ListBox1.ListCount - 1, Z) = Sheets("veri").Cells(X, Z + 1).Value
Next
End If
Next
Next
End Sub

.

 

[sinnernekolens]

Ömer bey, çok teşekkür ederim sorunsuz çalışıyor. Allah razı olsun.