Soru SAYFALAR ARASINDA MİNİMUM DEĞERİ BULMA

[yorgunsiyah]

Merhaba,

Aşağıda ekte bıraktığım excel dosyasında farklı tesislerde bulunan ilaçların ve sarf malzemelerin takibini yapmaktayım. Sayfalarda farklı farklı ilaçlar bulunmakta ve son sayfada hepsinin toplam adedi ve bugüne en yakın s.k.t yazmak için basit formüller yazdım. Takıldığım noktayı son sayfada açıkladım. Örneğin "Adrenalin ampul" her sayfada bulunmuyor, bu sebepten dolayı son sayfadaki formülün bir işlevi kalmıyor. Formülü nasıl revize edebilirim?

Yardımlarınızı bekliyorum,

 

[yorgunsiyah]

Çözümlerinizi bekliyorum

 

[Ömer]

Merhaba,

G7:

=TOPLA.ÇARPIM(ETOPLA(DOLAYLI("'"&{"PM";"PM ";"PS";"PX";"PL2";"PL";"PS2"}&"'!C:C");A7
;DOLAYLI("'"&{"PM";"PM ";"PS";"PX";"PL2";"PL";"PS2"}&"'!D:D")))

I7: (dizi formülüdür.)

=MİN(EĞER(M(KAYDIR(DOLAYLI("'"&{"PM";"PM ";"PS";"PX";"PL2";"PL";"PS2"}&"'!C9:C53");SATIR(DOLAYLI("9:53"))-9;0;1))=A7
;S(KAYDIR(DOLAYLI("'"&{"PM";"PM ";"PS";"PX";"PL2";"PL";"PS2"}&"'!G9:G53");SATIR(DOLAYLI("9:53"))-9;0;1))))

 

[yorgunsiyah]

[TR][TD]
Merhaba @Ömer bey,

Çok teşekkür ederim, ellerinize sağlık. Formül çalışıyor.

Ancak aşağıda ekte bıraktığım görseldeki gibi sadece bu kısımda formül çalışmıyor. Herhangi bir hata vermiyor, dizi formülü olarakta enterladım. Ancak tarihleri hesaplamadı :/



[/TD]
[TD]

[/TD]
[TD]

[/TD]
[TD]

[/TD][/TR]
[TR][TD]

[/TD]
[TD]

[/TD]
[TD]

[/TD]
[TD]

[/TD][/TR]

 

[Ömer]

İlave şart eklendi.
I7: (dizi formülüdür.)
Not: Detaylı deneme yapmadım.

=MİN(EĞER(M(KAYDIR(DOLAYLI("'"&{"PM";"PM ";"PS";"PX";"PL2";"PL";"PS2"}&"'!C9:C53");SATIR(DOLAYLI("9:53"))-9;0;1))=A7
;EĞER(S(KAYDIR(DOLAYLI("'"&{"PM";"PM ";"PS";"PX";"PL2";"PL";"PS2"}&"'!G9:G53");SATIR(DOLAYLI("9:53"))-9;0;1))>0
;S(KAYDIR(DOLAYLI("'"&{"PM";"PM ";"PS";"PX";"PL2";"PL";"PS2"}&"'!G9:G53");SATIR(DOLAYLI("9:53"))-9;0;1)))))

 

[yorgunsiyah]

Çok teşekkür ederim @Ömer bey, iyi çalışmalar dilerim

 

[Ömer]

Rica ederim, iyi çalışmalar.