Sayfalar Arası Döngü Kurma Hk.

[OoParadiSeoO]

Arkadaşlar merhaba,

6 adet sayfa için bir dizi aynı işlemler yapılacak. Bu işlemler için yazılan komutları 6 kere ayrı ayrı yazmak yerine bir döngü kurarak aynı komutu 6 sayfa için nasıl uygulatabiliriz? (Not: Sayfa isimleri ardışık değildir isteğe göre düzenlenmiştir.)

 

[Muzaffer Ali]

Ctrl tuşuna basılı tutarak istediğin sayfaları seç.

Sonra açık olan sayfada istediğin değişiklikleri yap.

Seçmiş olduğun tüm sayfalarda aynı işlemlerin yapıldığını göreceksiniz.

 

[Korhan Ayhan]

Makro ile alternatif;

"Sayfalar" isimli bölüme sizin dosyanızdaki işlem yapmak istediğiniz sayfa isimlerini yazıp deneyiniz.

Sub Sayfa_Islemleri()
    Dim Sayfalar(), X As Integer, S1 As Worksheet, Onay As Byte
    
    Sayfalar = Array("Sayfa1", "Sayfa2", "Sayfa3")
    
    For X = 0 To UBound(Sayfalar)
        On Error Resume Next
        Set S1 = Nothing
        Set S1 = Sheets(CStr(Sayfalar(X)))
        On Error GoTo 0
        
        If S1 Is Nothing Then
            Onay = MsgBox(Sayfalar(X) & " isimli sayfa dosyanızda bulunamadı!" & Chr(10) & _
                   "Diğer sayfalar için işleme devam etmek ister misiniz?", vbCritical + vbYesNo)
            If Onay = vbYes Then
                GoTo 10
            Else
                MsgBox "İşleminiz iptal edilmiştir.", vbExclamation
                Exit Sub
            End If
        Else
            'Aşağıdaki bölüme sayfada yaptırmak istediğiniz işlemleri yazınız.
            'Örnek olması açısından iki satır kod yazdım. Siz kendinize göre revize edersiniz.
            S1.Range("A1") = Date
            S1.Range("A1").Font.Bold = True
        End If
10  Next
    
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[OoParadiSeoO]

Yardımlarınız için çok teşekkürler arkadaşlar...