Satırları tek sütun haline getirme...

[scartex]

Merhaba,

Çok miktarda satırı tek bir sütunda alt alta birleştirmek istiyorum.

Örnek dosyayı ekte gönderdim.

Teşekkür ederim. İyi çalışmalar.

 

[Necdet]

Merhaba,

Aşağıdaki kodları bir modüle kopyalayıp deneyiniz.

Sub Duzenle()
    
    Dim i   As Long, _
        j   As Long, _
        Kol As Integer, _
        ShL As Worksheet, _
        ShD As Worksheet
    
    Application.ScreenUpdating = False
    
    Set ShL = Sheets("LİSTE")
    Set ShD = Sheets("DATA")
    
    ShL.Range("A:A").Clear
    Kol = ShD.Cells.Find("*", SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
    
    For i = 1 To ShD.Cells(Rows.Count, "A").End(3).Row Step 2
        ShD.Range(ShD.Cells(i, "A"), ShD.Cells(i + 1, Kol)).Copy
        j = ShL.Cells(Rows.Count, "a").End(3).Row + 1
        ShL.Range("A" & j).PasteSpecial Paste:=xlPasteAll, Operation:=xlNone, SkipBlanks:= _
        False, Transpose:=True
    Next i
        
    ShL.Cells.EntireColumn.AutoFit
    
    With Application
        .ScreenUpdating = True
        .CutCopyMode = False
    End With
End Sub

 

[scartex]

Necdet Bey elinize sağlık çok işime yaradı.

 

[scartex]

Formüllü hücrede makro çalışmıyor.

Merhaba,

Gönderdiğiniz kod formülsüz hücrelerde çalışıyor, ancak C1 hücresine =DATALAR!C1 şeklinde bir bağ oluşturduğumda 0 (sıfır) olarak sütun oluşturuyor.

Makro; formül, köprü, link veya bağ yapıştırılmış hücrelerde çalışmıyor.

Bunu sağlamanın bir yolu varmı? Teşekkür ederim.

 

[Necdet]

Merhaba,

Paste:=xlPasteAll

u

Paste:=xlPasteValues

Şeklinde dener misiniz?

 

[scartex]

Şimdi oldu. Çok teşekkür ederim.

 

[Necdet]

Güle güle kullanınız.