satırlar sırasında arama

[tiretwien]

arkadaşlar,

elimde C1:AA1 olarak her hücresi dolu bir veri var. formülü b1 e yazacagım.
istedigim şey; A1 de ne yazarsam onu C1:AA:1de arasın. buldugu hücrenin bir yanındaki hücreyi B1 e yazdırsın ( mesela ali yazdım K1de bulduysa L1 hücresinin icerigini B1 e yazsın

umarım anlatabilmişimdir. tüm bilgiler tek satırda.

şimdiden teşekkürler

 

[Ömer]

Merhaba,

Deneyiniz.

=İNDİS(C1:AA1;KAÇINCI(A1;C1:AA1;0)+1)

.

 

[tiretwien]

çok teşekkür ederim emeğinize sağlık

 

[tiretwien]

sevgili @Ömer Bey ve tüm forum ahalisi,

çözümler yeni ihtiyaçları doğuruyor. yukarıdaki formül 1.satır icin işime yaradı ancak aynı senaryoyu örnek 3:10 satırları arası nasıl aratabilirim.
yine formülü B1 e yazıyorum. aradığım kelimeyi A1 e yazıyorum. buldugu kelimenin bir yan hücresinin yazmasını istiyorum.

teşekkürler
hayırlı forumlar

 

[Korhan Ayhan]

DİZİ formüldür.

=EĞERHATA(DOLAYLI(METNEÇEVİR(KÜÇÜK(EĞER($C$3:$AA$10=$A$1;SATIR($C$3:$AA$10)*10^7+SÜTUN($C$3:$AA$10)+1);SATIR(A1));"R0C0000000");0);"")

 

[52779]

sevgili @Ömer Bey ve tüm forum ahalisi,

çözümler yeni ihtiyaçları doğuruyor. yukarıdaki formül 1.satır icin işime yaradı ancak aynı senaryoyu örnek 3:10 satırları arası nasıl aratabilirim.
yine formülü B1 e yazıyorum. aradığım kelimeyi A1 e yazıyorum. buldugu kelimenin bir yan hücresinin yazmasını istiyorum.

teşekkürler
hayırlı forumlar

Selamlar,
Sorunuza benim cevabım,

C3 : AA10 verileriniz var
A1 : Verileriniz içerisinde Aranılacak Değer
B1 : Verileriniz içerisinde A1 deki değerin bulunduğu hücrenin AYNI satırdaki ve 1 Kolon sağındaki Hücredeki Değeri yazacak Formül.

UYARI :
Aranan Değer, AA kolonunda ise, AB kolonundaki değeri yazacaktır. Bu durumda ne olacağı BELİRSİZ olduğundan, formüller AB kolonundaki değeri yazacak şekilde bırakıldı....

Durum1
C3 : AA10 aralığındaki verileriniz TEKRARSIZ ise ve Aranılan Değer C3 : AA10 aralığında Mevcut ise (Mevcut değilse HATA verecektir)

DİZİ Formül olarak, (DİZİ Formülün Hücreye girişi CTRL + SHIFT + ENTER ile yapılır)

=DOLAYLI(ADRES(MAK(EĞER(C3:AA10=A1;SATIR(C3:AA10)));MAK(EĞER(C3:AA10=A1;SÜTUN(C3:AA10))+1)))

ya da yine DİZİ Formül olarak

=DOLAYLI(METNEÇEVİR(MAK(EĞER(C3:AA10=A1;100*SATIR(C3:AA10)+SÜTUN(C3:AA10)+1));"R0C00");0)

Durum 2
C3 : AA10 aralığındaki verileriniz TEKRARLI ise ve Aranılan Değer C3 : AA10 aralığında Mevcut ise (Mevcut değilse "" yazılacaktır (BOŞ görünecek))
B1 den itibaren B kolonunda Listelemek için

=EĞERHATA(DOLAYLI(METNEÇEVİR(KÜÇÜK(EĞER($C$3:$AA$10=$A$1;100*SATIR($C$3:$AA$10)+SÜTUN($C$3:$AA$10)+1);SATIRSAY($A$1:$A1));"R0C00");0);"")

DİZİ Formülünü B1 giriniz...
Formülü B2 den itibaren B kolonuna kopyalayınız...

 

[tiretwien]

@Korhan Ayhan ve @52779 cevaplarınız için çok teşekkür ederim. işime çok yaradı. emeğinize sağlık