Şartlı veri aktar

[Ahmet Sami]

Kıymetli abilerim VERİ sayfasıdaki veriler ile LİSTE sayfasında ki veriler karşılaştırılacak, VERİ sayfasında olupta LİSTE sayfasında olmayan veriler VERİ sayfısından ANATERM sayfasına aktarılacak yardımlarınız için şimdiden teşekkür ederim.

 

[Haluk]

Sub Test()
'   Haluk 28/08/2022
'   sa4truss@ gmail.com
'
    Dim strSQL As String
    Dim strQuery As String
    Dim adoCN As Object
    Dim RS As Object
    
    Sheets("ANATERM").Range("C19:D" & Rows.Count).ClearContents
    
    Set adoCN = CreateObject("ADODB.Connection")
    
    adoCN.Provider = "Microsoft.ACE.OLEDB.12.0"
    adoCN.Properties("Extended Properties") = "Excel 8.0; HDR= Yes;"
    adoCN.ConnectionString = ThisWorkbook.FullName
    
    adoCN.Open
    
    strSQL = "Select Table2.[ADI SOYADI], Table2.[ODA SAYISI] " & _
             "From [Veri$] as Table2 " & _
             "Left Join " & _
             "[Liste$] As Table1 " & _
             "On Table1.[ADI SOYADI] = Table2.[ADI SOYADI] Where Table1.[ADI SOYADI] Is Null " & _
             "And Table2.[ODA SAYISI] Is Not Null"
    
    Set RS = CreateObject("ADODB.Recordset")
    
    RS.ActiveConnection = adoCN
    RS.Source = strSQL
    
    RS.Open
    
    Sheets("ANATERM").Range("C19").CopyFromRecordset RS
    
    RS.Close
    adoCN.Close
    Set RS = Nothing
End Sub

.

 

[Ahmet Sami]

Haluk hocam benim Ofis versiyonundan mı bilmiyorum ama Kodun sonundaki RS.Open sarı oluyor ve hata veriyor.

 

[Haluk]

Örnek dosya ektedir...

.

 

[Ahmet Sami]

Haluk bey teşekkür ederim emeğine sağlık.