Şartların karşılıklarını yazma

[ahzola]

Merhabalar;

Aşağıdaki formülü müsait zamanlarında
ustalarımız yazarsa çok sevinirim.
anlaşılmayan bir şey varsa dosya
ekleyebilirim. Teşekkür ederim.

A1=5

B1+C1 18 den küçük
D1+E1 18 den küçük 1 yaz

B1+C1 18 e eşit yada büyük
D1+E1 18 e eşit yada büyük 2 yaz

B1+C1 18 den küçük
D1+E1 18 e eşit yada büyük 3 yaz

B1+C1 18 e eşit yada büyük
D1+E1 18 den küçük 4 yaz

A1=7

B1+C1 18 den küçük
D1+E1 18 den küçük 5 yaz

B1+C1 18 e eşit yada büyük
D1+E1 18 e eşit yada büyük 6 yaz

B1+C1 18 den küçük
D1+E1 18 e eşit yada büyük 7 yaz

B1+C1 18 e eşit yada büyük
D1+E1 18 den küçük 8 yaz

A boş ise boş kalsın.

 

[YUSUF44]

Şöyle mi?

=EĞER(A1="";"";EĞER(A1=5;EĞER(VE(B1+C1<18;D1+E1<18);1;EĞER(VE(B1+C1>=18;D1+E1>=18);2;EĞER(VE(B1+C1<18;D1+E1>=18);3;4)));EĞER(A1=7;EĞER(VE(B1+C1<18;D1+E1<18);5;EĞER(VE(B1+C1>=18;D1+E1>=18);6;EĞER(VE(B1+C1<18;D1+E1>=18);7;8)));"A1=5 ya da 7 değil")))

 

[ahzola]

Şöyle mi?

=EĞER(A1="";"";EĞER(A1=5;EĞER(VE(B1+C1<18;D1+E1<18);1;EĞER(VE(B1+C1>=18;D1+E1>=18);2;EĞER(VE(B1+C1<18;D1+E1>=18);3;4)));EĞER(A1=7;EĞER(VE(B1+C1<18;D1+E1<18);5;EĞER(VE(B1+C1>=18;D1+E1>=18);6;EĞER(VE(B1+C1<18;D1+E1>=18);7;8)));"A1=5 ya da 7 değil")))

Aynen Yusuf Bey
Hızır gibisiiniz maşallah.
Elinize sağlık.

Ben kendim yaparım diye yazmamıştım.
şuan uğraşıyorum lakin bir türlü üstesinden gelemiyorum.

A1=5 yada 7 olmak kaydı ile (a boş ise boş kalacak)
18 e eşit ve büyükleri bir renk
18 den küçük olanları başka bir renk yapmak
istiyorum koşullu biçimlendirme ile.
Sizin tarafınızdan mümkünmü acaba.

 

[Ömer]

Merhaba,

Alternatif olsun.

=EĞER(VE(A1<>5;A1<>7);"";ELEMAN((B1+C1<18)+(D1+E1<18)*2+1;1;2;3;0)+EĞER(A1=5;1;5))

Not: Koşullu biçimlendirme sorunuz net değil.

.

 

[ahzola]

Merhabalar;

Teşekkür ederim Sn Ömer bey.
Alakanız için.

aşağıdaki gibi olacak koşullu renk.

A1=5 yada 7 ise

B1+C1 yada D1+E1 den herhangi birisi
18 e eşit yada büyük ise bir renk
18 den küçük ise başka bir renk.
olsun.

A boş ise boş kalsın.

 

[Ömer]

1. Koşul: Küçükse; ( formülü ile istediğiniz renk )

=VE(YADA(A1=5;A1=7);((B1+C1<18)+(D1+E1<18))>0)

2. Koşul: Büyükse; ( formülü ile istediğiniz renk )

=VE(YADA(A1=5;A1=7);((B1+C1>=18)+(D1+E1>=18))>0)

.

 

[ahzola]

Çok teşekkür ederim.
iyiki varsınız.