ORTALAMA

[Deha_77]

Merhaba arkadaşlar kolaylıklar.

Ekli dosyada üst kısımda bulunan çizelgede PUAN başlığındaki dataları ortalamanın altında olanları BAŞARISIZ üstünde olanları ise BAŞARILI kısmına personel isim soy isimleri ile beraber yazdırmak istiyorum yardımcı olursanız sevinirim.

Teşekkürler.

 

[relaxim]

Merhaba,
Örneğinizi doldurup olması gerekeni gösterirseniz; daha çabuk çözüme ulaşabilirsiniz.

 

[Korhan Ayhan]

Deneyiniz.

DİZİ formüllerdir. Formülleri hücreye uyguladıktan sonra hücreyi CTRL+SHIFT+ENTER tuşlarına basarak terk ediniz. Bu işlemden sonra doğru sonuçları gösterecektir.

O4;

=IFERROR(INDEX($A$5:$A$15;SMALL(IF(($A$5:$A$15<>"")*($K$5:$K$15>AVERAGEIF($K$5:$K$15;"<>0"));ROW($K$5:$K$15)-4);ROW()-3));"")

P4;

=IFERROR(INDEX($A$5:$A$15;SMALL(IF(($A$5:$A$15<>"")*($K$5:$K$15<AVERAGEIF($K$5:$K$15;"<>0"));ROW($K$5:$K$15)-4);ROW()-3));"")

 

[Deha_77]

Deneyiniz.

DİZİ formüllerdir. Formülleri hücreye uyguladıktan sonra hücreyi CTRL+SHIFT+ENTER tuşlarına basarak terk ediniz. Bu işlemden sonra doğru sonuçları gösterecektir.

O4;

=IFERROR(INDEX($A$5:$A$15;SMALL(IF(($A$5:$A$15<>"")*($K$5:$K$15>AVERAGEIF($K$5:$K$15;"<>0"));ROW($K$5:$K$15)-4);ROW()-3));"")

P4;

=IFERROR(INDEX($A$5:$A$15;SMALL(IF(($A$5:$A$15<>"")*($K$5:$K$15<AVERAGEIF($K$5:$K$15;"<>0"));ROW($K$5:$K$15)-4);ROW()-3));"")

Merhaba Korhan Bey,
Vakit ayırdığınız için teşekkür ederim öncelikle, uyguladım formülleri ama herhangi bir atama olmadı. Ekledim datayı.

 

[Korhan Ayhan]

Siz Türkçe excel kullanıyorsanız formülleri Türkçe'ye çevirmelisiniz.

Ve DİZİ formül olarak uygulamalısınız.

IFERROR = EĞERHATA
INDEX = İNDİS
SMALL = KÜÇÜK
IF = EĞER
AVERAGEIF = EĞERORTALAMA
ROW = SATIR

 

[Deha_77]

Türkçeye çevirip denedim formül çalışıyor ama ekte ki datada da görüldüğü üzere daha başarılı personeller yada daha başarısız personeller olmasına rağmen hatalı isimleri atıyor başarılı başarısız sekmelerine.

 

[Korhan Ayhan]

Formülü sadece ilk satıra uygulamışsınız. Alt hücrelere sürüklemeniz gerekirdi.

Listede bulunan sıfırlar formülde sıkıntı yaratıyordu. Bir koşul daha ekledim.

İlgili hücrelere uyguladıktan sonra alta doğru sürükleyiniz. (DİZİ formüllerdir)

O4;

=EĞERHATA(İNDİS($A$5:$A$15;KÜÇÜK(EĞER(($A$5:$A$15<>"")*($K$5:$K$15<>0)*($K$5:$K$15>EĞERORTALAMA($K$5:$K$15;"<>0"));SATIR($K$5:$K$15)-4);SATIR()-3));"")

P4;

=EĞERHATA(İNDİS($A$5:$A$15;KÜÇÜK(EĞER(($A$5:$A$15<>"")*($K$5:$K$15<>0)*($K$5:$K$15<EĞERORTALAMA($K$5:$K$15;"<>0"));SATIR($K$5:$K$15)-4);SATIR()-3));"")

 

[Deha_77]

Çok teşekkürler sağ olun oldu bu kez.