Metin ayırma

[besen]

Merhaba dosya yapısı ekteki gibi.
A kolonunda muhasebe kodu ve hesap ismi birleşik yazılmış.
Her kodun altında tarihle başlayan hareket bilgileri var.
Kodların uzunluğu farklı farklı, isimlerin sonunda da belirsiz boşluklar var.
Benim istediğim ekteki örnekteki gibi, A kolonunda muhasebe kodu ve hesap ismi birleşik yazılmış olanları B ve C kolonlarına kod ve isim olarak yazdırmak.
Ben örnekteki formülle hallettim sanıyordum ama kod uzunlukları farklı olunca uymayanlar oldu.

Teşekkür ederim.

 

[volki_112]

Merhaba dosya yapısı ekteki gibi.
A kolonunda muhasebe kodu ve hesap ismi birleşik yazılmış.
Her kodun altında tarihle başlayan hareket bilgileri var.
Kodların uzunluğu farklı farklı, isimlerin sonunda da belirsiz boşluklar var.
Benim istediğim ekteki örnekteki gibi, A kolonunda muhasebe kodu ve hesap ismi birleşik yazılmış olanları B ve C kolonlarına kod ve isim olarak yazdırmak.
Ben örnekteki formülle hallettim sanıyordum ama kod uzunlukları farklı olunca uymayanlar oldu.

Teşekkür ederim.

B2 ye bunu yazın

=EĞER(H2+I2=0;SOLDAN(A2;MİN(EĞER(EHATALIYSA(MBUL({"A";"B";"C";"Ç";"D";"E";"F";"G";"Ğ";"H";"I";"İ";"J";"K";"L";"M";"N";"O";"Ö";"P";"R";"S";"Ş";"T";"U";"Ü";"V";"Y";"Z"};A2));UZUNLUK(A2)+1;MBUL({"A";"B";"C";"Ç";"D";"E";"F";"G";"Ğ";"H";"I";"İ";"J";"K";"L";"M";"N";"O";"Ö";"P";"R";"S";"Ş";"T";"U";"Ü";"V";"Y";"Z"};A2)))-2);B1)

C2 ye bunu yazın

=EĞER(H2+I2=0;PARÇAAL(A2;MİN(EĞER(EHATALIYSA(MBUL({"A";"B";"C";"Ç";"D";"E";"F";"G";"Ğ";"H";"I";"İ";"J";"K";"L";"M";"N";"O";"Ö";"P";"R";"S";"Ş";"T";"U";"Ü";"V";"Y";"Z"};A2));UZUNLUK(A2)+1;MBUL({"A";"B";"C";"Ç";"D";"E";"F";"G";"Ğ";"H";"I";"İ";"J";"K";"L";"M";"N";"O";"Ö";"P";"R";"S";"Ş";"T";"U";"Ü";"V";"Y";"Z"};A2)));UZUNLUK(A2));C1)

 

[besen]

Teşekkür ederim, ancak kod eksik geliyor.

 

[Ali]

B2 hücresine

=YERİNEKOY(A2;C2;"")

yazın.

C2 hücresine

=PARÇAAL(A2;KÜÇÜK(EĞERHATA(BUL({"A";"B";"C";"Ç";"D";"E";"F";"G";"Ğ";"H";"I";"İ";"J";"K";"L";"M";"N";"O";"Ö";"P";"R";"S";"Ş";"T";"U";"Ü";"V";"Y";"Z"};A2);9999);1);999)

yazın.

 

[besen]

=PARÇAAL(A2;KÜÇÜK(EĞERHATA(BUL({"A";"B";"C";"Ç";"D";"E";"F";"G";"Ğ";"H";"I";"İ";"J";"K";"L";"M";"N";"O";"Ö";"P";"R";"S";"Ş";"T";"U";"Ü";"V";"Y";"Z"};A2);9999);1);999)

Teşekkür ederim.

 

[Korhan Ayhan]

Alternatif...

B2;

=IF(NOT(ISTEXT(IFERROR(VALUE(SUBSTITUTE(A2;"/";"."));"")));B1;TRIM(LEFT(A2;MIN(FIND({"A";"B";"C";"Ç";"D";"E";"F";"G";"Ğ";"H";"I";"İ";"J";"K";"L";"M";"N";"O";"Ö";"P";"Q";"R";"S";"Ş";"T";"U";"Ü";"V";"W";"X";"Y";"Z"};A2&"ABCÇDEFGĞHIİJKLMNOÖPQRSŞTUÜVWXYZ")-1))))

C2;

=IF(NOT(ISTEXT(IFERROR(VALUE(SUBSTITUTE(A2;"/";"."));"")));C1;TRIM(MID(A2;LEN(B2)+1;1024)))

 

[besen]

Teşekkür ederim.

Merhaba ekteki örnekte 102 03 001 ABC BANK ŞB 100054 EURO bu hesabın içinde "BANK ŞB" arasında bir fazla boşluk olduğu için formül çalışmıyor.
Teşekkür ederim.

 

[volki_112]

Merhaba ekteki örnekte 102 03 001 ABC BANK ŞB 100054 EURO bu hesabın içinde "BANK ŞB" arasında bir fazla boşluk olduğu için formül çalışmıyor.
Teşekkür ederim.

B5 e bunu yazın aşağı çekin istediğiniz olur. İki boşluk yerine tek boşluk yapıyor formül. ondan sonra sizin işleme devam ediyor

=EĞER((I5+H5)=0;KIRP(YERİNEKOY(YERİNEKOY(A5;"  ";" ");C5;""));B4)

 

[Ali]

B4 hücresindeki formülü aşağıdaki ile değiştirip dener misin

=EĞERHATA(PARÇAAL(A4;1;BUL(" ";A4;BUL(" ";A4;BUL(" ";A4)+1)+1)-1);A4)

 

[Ali]

Diğer alternatif

=EĞERHATA(SOLDAN(A4;BUL("|";YERİNEKOY(A4;" ";"|";3))-1);A4)

 

[besen]

Alternatif...

B2;

=IF(NOT(ISTEXT(IFERROR(VALUE(SUBSTITUTE(A2;"/";"."));"")));B1;TRIM(LEFT(A2;MIN(FIND({"A";"B";"C";"Ç";"D";"E";"F";"G";"Ğ";"H";"I";"İ";"J";"K";"L";"M";"N";"O";"Ö";"P";"R";"S";"Ş";"T";"U";"Ü";"V";"Y";"Z"};A2&"ABCÇDEFGĞHIİJKLMNOÖPRSŞTUÜVYZ")-1))))

C2;

=IF(NOT(ISTEXT(IFERROR(VALUE(SUBSTITUTE(A2;"/";"."));"")));C1;TRIM(MID(A2;LEN(B2)+1;1024)))

Çok teşekkür ederim.

255 01 016 WT310-105 GMS İ5 BİLGİSAYAR bu kodda hatalı ayrım oldu. 255 01 016 W T310-105 GMS İ5 BİLGİSAYAR

 

[Korhan Ayhan]

İngiliz alfabesindeki harfleri formüle eklemek gerekecek..

Önerime bu eklemeyi yaparak revize ettim. Tekrar deneyebilirsiniz.

 

[besen]

İngiliz alfabesindeki harfleri formüle eklemek gerekecek..

Haklısınız, çok teşekkür ederim.

 

[Korhan Ayhan]

Revize formülü paylaşıyorum...