Makro ile sayfaya sığdırma

[teyadih]

Merhaba arkadaşlar. Ekli dosyada detaylı olarak açıkladığım şekilde dolu satırların satır yüksekliğini sayfaya sığdıracak, G7 ile AK23 arasındaki satırlara sadece 1 ve üstü rakamların girişine izin verilecek ve AL7 ile AL23 arasındaki her satır toplamının 50 saati geçmeyecek makroya ihtiyacım var. Yardım eder misiniz?

 

[AdemCan]

Merhaba konu üzerinden zaman geçmiş ancak 1 ve 2 numaralı istediğiniz için Mesai Cetveli sayfasının kod penceresine şu kodları ekleyiniz.
3 numaralı istediğiniz mevcut dosyanız üzerinde olmaktadır.

Public onceki

Private Sub Worksheet_Activate()
Unprotect Password:="7895123"
son = WorksheetFunction.Max([A:A]) + 6
If son > 6 Then
    Application.ScreenUpdating = False
    Rows("7:23").Hidden = False
    Rows(son + 1 & ":23").Hidden = True
    Application.ScreenUpdating = True
End If
Protect Password:="7895123"
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)

    If (Target.Column >= 7 And Target.Column <= 37) And _
        (Target.Row >= 7 And Target.Row <= 23) Then
        
        If Target.Value = 0 Or Not IsNumeric(Target.Value) Then
            Application.EnableEvents = False
                Target.ClearContents
            Application.EnableEvents = True
            Exit Sub
        End If
        
        toplam = WorksheetFunction.Sum(Range("G" & Target.Row & ":AK" & Target.Row))
        If toplam > 50 Then
            Target.Value = onceki
        End If
    End If

End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If (Target.Column >= 7 And Target.Column <= 37) And _
            (Target.Row >= 7 And Target.Row <= 23) Then
        onceki = Target.Value
    End If
End Sub

 

[teyadih]

Teşekkür ederim sayın AdemCan elinize sağlık

 

[AdemCan]

Rica ederim.