Makro ile hücre aralığına formül atama

[kadir78]

İyi günler. H2 : H30000 aralığında bulunan hücrelere : =YUVARLA("E1*F1;0)*G1"

J2 : J30000 aralığına ise :
=G1-(K1+N1)

formüllerini hücrelerin içerisine makro ile nasıl yazdirabilirim. Biraz araştırdım fakat denediğim kodlar hata verdi çözemedim. Yardımcı olurmusunuz. Office 2019 kullanıyorum.

 

[kadir78]

Düzeltme ;

H2 : H30000 aralığı =YUVARLA("E2*F2;0)*G2

J2 : J30000 aralığı =G2-(K2+N2)

Örnek dinamik olarak J3 hücresinde =G3-(K3+N3) artarak gitmesini çözemedim.

 

[muygun]

Merhaba;
Sayfanın kod bölümüne;

Sub işlem()
For i = 2 To 30000
sayı = (Cells(i, "e") * Cells(i, "f"))
yuvsayı = Round(CDec(sayı), 0) * Cells(i, "g")
Cells(i, "h") = yuvsayı
Cells(i, "j") = Cells(i, "g") - (Cells(i, "k") + Cells(i, "n"))
Next i
End Sub

Ekleyerek deneyin.
İyi çalışmalar.

 

[kadir78]

Sağolun emeğinize sağlık

 

[Korhan Ayhan]

Merhaba,

Bu tarz işlemlerde özel bir durum yoksa döngü kullanmadan da daha hızlı bir şekilde sonuca gidebilirsiniz.

Option Explicit

Sub Add_Cell_Formula()
    Dim Zaman As Double
    
    Zaman = Timer
    
    With Range("H2:H30000")
        .Formula = "=ROUND(E2*F2,0)*G2"
        '.Value=.Value Rem bu satır formülü hücreye yazdıktan sonra sonucu değer olarak aynı aralığa yazar.
    End With
    
    With Range("J2:J30000")
        .Formula = "=G2-(K2+N2)"
        '.Value=.Value Rem bu satır formülü hücreye yazdıktan sonra sonucu değer olarak aynı aralığa yazar.
    End With
    
    MsgBox "İşlem süresi ; " & Format(Timer - Zaman, "0.00") & " Saniye"
End Sub

 

[kadir78]

Korhan hocam sağolun teşekkür ederim. 4 sene öncesine kadar makro ile ilgili zerre bilgim yoktu buradaki değerli hocalarımız ve değerli uzmanlar olmasa makro hakkında hiç bir şey öğrenemezdim. Bu forum sayfasından çok bilgiler öğrendim ve öğrenmeye devam ediyorum. Değerli hocalarımıza, uzmanlara ve bildiklerini paylaşan her forum üyesine teşekkür ederim, iyiki varsınız. Emeklerinize sağlık olsun.