maile eklenen yazıyı bold yapmak

[kneehot]

Arkadaşlar excelden direk mail gönderen bi makro kullanıyorum. Hücrelerden aldırdığım yazılar var. Bir hücredeki yazıyı bold yapmak istiyorum. Aşağıya kullanılan kodu ekledim. Bunu nasıl bold olarak ekletebilirim maile yardımcı olursanız çok sevinirim. Şimdiden yardımlara çok teşekkürler.


& vbNewLine & vbNewLine & [B76] & "" _

 

[Asri]

Maili format olarak html seçin.

hücrede veriyi bold yapın.
aşağıdaki şekilde kullanın

.HTMLBody = mesaj & _
"<br>" & "A'nın verileri;" & "<br>" & RangetoHTML(alana) & _
"<br>" & "B'nın verileri;" & "<br>" & RangetoHTML(alana) & _
"<br>" & "C'nın verileri;" & "<br>" & RangetoHTML(alana) & _
"<br>" & "D'nın verileri;" & "<br>" & RangetoHTML(alana) & _
.HTMLBody

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function