Soru listview ve textbox kayıt

[sirkülasyon]

Commandbutton ile Akaryakıt sayfasına her kayıt esnasında
Textbox1' e girilen veriyi B4' ten itibaren B12' ye kadar alt alta kaydetmesi
Textbox2' e girilen veriyi C4' ten itibaren C12' ye kadar alt alta kaydetmesi
Aynı zamanda da listview1' de
1. sütuna B4:B12 aralığını
2. sütuna C4:C12 aralığını sayfadan aldırmak için yardımcı olabilir misiniz?

 

[Muzaffer Ali]

Merhaba.

Formun kod kısmına kopyalayın.

Private Sub CommandButton1_Click()
    Dim Bak As Range
    If Range("B12") <> "" Then
        MsgBox "'B4:B12' arası dolu, kayıt yapılamoıyor"
        Exit Sub
    End If
    For Each Bak In Range("B4:B12")
        If Bak = "" Then
            Bak = TextBox1.Text
            Bak.Offset(0, 1) = TextBox2.Text
            ListView1.ListItems.Clear
            Listele
            Exit Sub
        End If
    Next
End Sub

Private Sub UserForm_Initialize()
    With ListView1
        .FullRowSelect = True
        .View = lvwReport
        .Gridlines = True
        .ColumnHeaders.Add , , "Kolon Adı 1", 150
        .ColumnHeaders.Add , , "Kolon Adı 2", 100
    End With
    Listele
End Sub

Sub Listele()
    Dim Bak As Byte
    For Bak = 4 To 12
        ListView1.ListItems.Add , , Cells(Bak, "B")
        ListView1.ListItems(Bak - 3).ListSubItems.Add , , Cells(Bak, "C")
    Next
End Sub

 

[sirkülasyon]

eline emeğine sağlık. Sağ olasın

 

[Muzaffer Ali]

Rica ederim. Kolay gelsin.