Listeden koşula göre sayma; yeni sayfaya listeleme

[snx111]

Sayfa1.de bir liste mevcut listede denetim sonucu ( I sütununda ) ; "X" alan çalışanın ; toplamda kaç x aldıgını adıyla beraber sayfa2 de listelenmesini istiyorum; LİSTE güncelleneceğinden son satıra yeni isim girilince ve o isimdeki şahıs ta x alırsa aynen sayfa2 ye geçmeli toplamx sayısıyla beraber ;

Çalışanın adı ikinci kez sayfa2 deki listede olmasın istiyorum

Sayfa1.de birleştirilmiş hücre olduğundan düşeyara hata verdi çözüm önermenizi istiyorum; açıklama ekte mevcut..
İlgilenecek arkadaşlara teşekkür ederim ..
Makroda olabilir eğer son çare ise..

 

[Ömer]

Merhaba,

Sayfa1 K3:

=EĞER(I3="x";ARA(2;1/($B$3:B3<>"");$B$3:B3);"")

yazarak alt satırlara dilediğiniz kadar kopyalayın.
----------------------------------------------------------------------------------

Sayfa2 D1:

=TOPLA.ÇARPIM((Sayfa1!K3:K100<>"")/EĞERSAY(Sayfa1!K3:K100;Sayfa1!K3:K100&""))

----------------------------------------------------------------------------------

Sayfa2 B3:

=EĞER(SATIRSAY($B$3:B3)>$D$1;"";İNDİS(Sayfa1!$K$3:$K$100;KÜÇÜK(EĞER(SIKLIK(EĞER(Sayfa1!$K$3:$K$100<>"";KAÇINCI("~"&Sayfa1!$K$3:$K$100;Sayfa1!$K$3:$K$100&"";0));SATIR(Sayfa1!$K$3:$K$100)-SATIR(Sayfa1!$K$3)+1);SATIR(Sayfa1!$K$3:$K$100)-SATIR(Sayfa1!$K$3)+1);SATIRSAY($B$3:B3))))

Yazarak dizi formülüne çevirdikten sonra alt satırlara kopyalayın.
----------------------------------------------------------------------------------

Sayfa2 C3:

=EĞER(B3="";"";EĞERSAY(Sayfa1!$K$3:$K$100;B3))

yazarak alt satırlara kopyalayın.

 

[snx111]

sayfa1deki isimler birleştirilmiş hücre teşkil ettiğinden dolayı çalışmıyor sanıyorum dediğiniz şekilde yaptım boş görünüyor ;

 

[Ömer]

Diğer mesajdaki sayfa1 k3 deki formülü değiştirdim. Deneme esnasında yazmıştım silmeyi unutmuşum.

Ayrıca Sayfa2 D1 deki formülü alt satırlara kopyalamayın. Benzersizlerin sayısını almak için kullandım, tek hücrede olması yeterli.

Dosya ektedir.

.

 

[snx111]

İyi görünüyor; Elinize sağlık hızınızdan dolayıda tebrik ederim ÖMER bey ..