Soru Kritere Göre Toplamını Almak

[Hsn55]

Merhabalar;
Aşağıdaki dosyamda H3 Hücresine Başlangıç, H4 hücresine ise bitiş tarihini girdiğimde ve H6 hücresine Bölme No,H7 hücresine Cinsi ve H8 hücresine ise Adı soyadı girdiğim zaman kritere göre Adet ve Toplamını H10 ile H11 hücresine formül yada makro ile yapabilir miyiz. No: H6,H7,H8 hücrelerinin bazıları boş olabilir.
Örneğin :H6 dolu,H7 boş,H8 dolu olduğu zaman iki kritere göre toplamını alacak. Yani hücerelerde seçilen veriye göre toplayacak. Yardımlarınızı bekliyorum. Saygılarımla

İndir Topla

Dosyayı indir Topla

dosya.co

 

[Korhan Ayhan]

Deneyiniz.

H10;

=ÇOKETOPLA($H$16:$H$25;$K$16:$K$25;">="&$H$3;$K$16:$K$25;"<="&$H$4;$D$16:$D$25;$H$6;$G$16:$G$25;$H$7;$J$16:$J$25;$H$8)

H11;

=ÇOKETOPLA($I$16:$I$25;$K$16:$K$25;">="&$H$3;$K$16:$K$25;"<="&$H$4;$D$16:$D$25;$H$6;$G$16:$G$25;$H$7;$J$16:$J$25;$H$8)

 

[Hsn55]

Korhan bey iyi akşamlar; Yapmış olduğunuz formülde H6,H7 ve H8 hücrelerinin hepsinin seçili olması gerekiyor. Benim istediğim
A) Tarihler seçili h6,h7,h8 boş ise tümünü toplayacak
B) Tarihler seçili sadece H6 seçili ise H6 ya göre toplayacak
C) Tarihler seçili H7 seçili ise H7 ye göre toplayacak.
D)Tarihler seçili H8 seçili ise H8 e göre toplayacak.
E) Tarihler seçili H6 ve H7 seçili ise bu iki kr,tere göre toplacak.
Aynı şekilde 3 veya hangileri seçili ise o kritere göre toplamlarını alacak.
Yine tarihler seçili değilse tümünü toplayacak.

 

[Hsn55]

Korhan bey 3. Nolu mesajımda belirtmiş olduğum talebim formül ile olabilir mi?

 

[Korhan Ayhan]

Deneyiniz.

H10;

=ÇOKETOPLA($H$16:$H$25;$K$16:$K$25;">="&EĞER($H$3="";TARİH(1900;1;1);$H$3);$K$16:$K$25;"<="&EĞER($H$4="";TARİH(9999;12;31);$H$4);$D$16:$D$25;EĞER($H$6="";">0";$H$6);$G$16:$G$25;EĞER($H$7="";"*";$H$7);$J$16:$J$25;EĞER($H$8="";"*";$H$8))

H11;

=ÇOKETOPLA($I$16:$I$25;$K$16:$K$25;">="&EĞER($H$3="";TARİH(1900;1;1);$H$3);$K$16:$K$25;"<="&EĞER($H$4="";TARİH(9999;12;31);$H$4);$D$16:$D$25;EĞER($H$6="";">0";$H$6);$G$16:$G$25;EĞER($H$7="";"*";$H$7);$J$16:$J$25;EĞER($H$8="";"*";$H$8))

Daha önce benzer tarz bir konu işlemiştik. Faydası olabilir. İnceleyiniz.

Çoketopla ile Birden Çok Koşula Göre İşlem Yapma

Merhabalar örnek dosyamda CARİ ve YILA göre toplama işlemi yapmaktayım buna ayrıca TÜMÜ seçenekleri eklemek istiyorum. YIL TÜMÜ olduğunda her bir CARİ seçtiğimde o cariye göre tüm yıllar CARİ TÜMÜ Olduğunda her bir YIL seçtiğimde o Yıla göre tüm cariler YIL ve CARİ ayrı seçtiğimde ise...

www.excel.web.tr

 

[Hsn55]

Korhan Bey ekli dosyamda Adet Toplamı:178 iken formülde 164 hesaplıyor. M3 Toplamı dosyamda 132,322 iken formülde 120,199 olarak hesaplıyor. Formül ile dosyadaki toplamlar tutmuyor gibi

 

[Korhan Ayhan]

K20 hücresini kontrol ediniz.

 

[Hsn55]

Çok teşekkür ederim. O hücreye dikkat etmemişim. Ellerinize sağlık. Hayırlı geceler

 

[Hsn55]

Korhan bey merhabalar;
Yapmış olduğunuz formülde revize edebilir misiniz. Ekli dosyada H6,H7 ve H8 hücrelerindeki verilere göre de toplamını aldırabilir miyiz
Adet Formülü:

=ÇOKETOPLA($H$19:$H$28;$K$19:$K$28;">="&EĞER($H$3="";TARİH(1900;1;1);$H$3);$K$19:$K$28;"<="&EĞER($H$4="";TARİH(9999;12;31);$H$4);$D$19:$D$28;EĞER($H$9="";">0";$H$9);$G$19:$G$28;EĞER($H$10="";"*";$H$10);$J$19:$J$28;EĞER($H$11="";"*";$H$11))

Toplam Formülü :

=ÇOKETOPLA($I$19:$I$28;$K$19:$K$28;">="&EĞER($H$3="";TARİH(1900;1;1);$H$3);$K$19:$K$28;"<="&EĞER($H$4="";TARİH(9999;12;31);$H$4);$D$19:$D$28;EĞER($H$9="";">0";$H$9);$G$19:$G$28;EĞER($H$10="";"*";$H$10);$J$19:$J$28;EĞER($H$11="";"*";$H$11))

Bilgi

Bilgi

dosyam.org

 

[Korhan Ayhan]

Bahsettiğiniz hücreler hangi alanlara başvuracak?

 

[Hsn55]

Kusura bakmayın aralıkları belirtmeyi unutmuşum. Dosyanı son hali ektedir.

Bilgi

Bilgi

dosyam.org

 

[Korhan Ayhan]

Bu yeni alanlarda sayısal veri içeren olacak mı? Yoksa hepsi metinsel ifadeler mi içerecek?

 

[Hsn55]

Son eklenen hücrelerde Metinsel ifadeler kullanılacak

 

[Hsn55]

Korhan bey hocam sizden ricam formülü revize edebilir msiniz?

 

[Korhan Ayhan]

Deneyiniz.

J13;

=ÇOKETOPLA($J$19:$J$28;$M$19:$M$28;">="&EĞER($J$3="";TARİH(1900;1;1);$J$3);$M$19:$M$28;"<="&EĞER($J$4="";TARİH(9999;12;31);$J$4);$C$19:$C$28;EĞER($J$6="";"*";$J$6);$D$19:$D$28;EĞER($J$7="";"*";$J$7);$E$19:$E$28;EĞER($J$8="";"*";$J$8);$F$19:$F$28;EĞER($J$9="";">0";$J$9);$I$19:$I$28;EĞER($J$10="";"*";$J$10);$L$19:$L$28;EĞER($J$11="";"*";$J$11))

J14;

=ÇOKETOPLA($K$19:$K$28;$M$19:$M$28;">="&EĞER($J$3="";TARİH(1900;1;1);$J$3);$M$19:$M$28;"<="&EĞER($J$4="";TARİH(9999;12;31);$J$4);$C$19:$C$28;EĞER($J$6="";"*";$J$6);$D$19:$D$28;EĞER($J$7="";"*";$J$7);$E$19:$E$28;EĞER($J$8="";"*";$J$8);$F$19:$F$28;EĞER($J$9="";">0";$J$9);$I$19:$I$28;EĞER($J$10="";"*";$J$10);$L$19:$L$28;EĞER($J$11="";"*";$J$11))

 

[Hsn55]

Korhan bey hocam çok teşekkür ederim. Sizden çok özür diliyorum.Bir veriyi unutmuşum. Eğer sizi uğraştırmayacaksa son olarak ekli dosyada J11 hücresine bir kriter ve sütun ekledim .Formülü son kez revize edebilir misiniz . Yine eklemiş olduğum sütun metinsel ifade

Bilgi

Bilgi

dosyam.org

 

[modoste]

korhan hocam
$C$19:$C$28;EĞER($J$6="";"*";$J$6) formülde C19:C28 aralığı eğer boşsa "*" olunca formül nasıl çalışıyo yani C19:C28 aralığında * ne anlama geliyor

 

[Korhan Ayhan]

@Hsn55,

Yeni alanın hangi veri türünü içereceğini belirtmemişsiniz. Ben metin olarak yorumladım. Bundan sonra eğer alan eklemeniz gerekirse artık kendiniz eklersiniz.

J14;

=ÇOKETOPLA($K$20:$K$29;$N$20:$N$29;">="&EĞER($J$3="";TARİH(1900;1;1);$J$3);$N$20:$N$29;"<="&EĞER($J$4="";TARİH(9999;12;31);$J$4);$C$20:$C$29;EĞER($J$6="";"*";$J$6);$D$20:$D$29;EĞER($J$7="";"*";$J$7);$E$20:$E$29;EĞER($J$8="";"*";$J$8);$F$20:$F$29;EĞER($J$9="";">0";$J$9);$I$20:$I$29;EĞER($J$10="";"*";$J$10);$J$20:$J$29;EĞER($J$11="";"*";$J$11);$M$20:$M$29;EĞER($J$12="";"*";$J$12))

J15;

=ÇOKETOPLA($L$20:$L$29;$N$20:$N$29;">="&EĞER($J$3="";TARİH(1900;1;1);$J$3);$N$20:$N$29;"<="&EĞER($J$4="";TARİH(9999;12;31);$J$4);$C$20:$C$29;EĞER($J$6="";"*";$J$6);$D$20:$D$29;EĞER($J$7="";"*";$J$7);$E$20:$E$29;EĞER($J$8="";"*";$J$8);$F$20:$F$29;EĞER($J$9="";">0";$J$9);$I$20:$I$29;EĞER($J$10="";"*";$J$10);$J$20:$J$29;EĞER($J$11="";"*";$J$11);$M$20:$M$29;EĞER($J$12="";"*";$J$12))

@modoste,

Bu yapıda başvuru aralıklarının dolu olması gerekiyor. Yoksa formül sonuç üretmez.

Burada ki amaç şudur;

Ölçüt hücrelerine ölçüt yazılırsa o ölçüt dikkate alınıyor. Eğer ölçüt hücresi boş bırakılırsa "tümünü dikkate al" mantığı ile çalışmaktadır.

 

[modoste]

anladım hocam teşekkür ederim
benim biraz önce sorduğum bir sorum vardı hocam yıllar öncede sormuştum cevabın son durumu ilgili olanı tekrar sordum ve bir yenileme gerekti
o soruma bakabilir misiniz

 

[Hsn55]

Korhan bey merhabalar; en son yapmış olduğunuz formülü uyguladım. Fakat hesaplama yapmıyor