Koşullu biçimlenmiş hücreleri toplayamıyorum !

[gsray4ever]

Merhabalar,

ekteki dosyada "???" işaretli olarak yazdığım yerlere toplam almak istiyorum ama hücreler koşullu biçimlendiği için olmuyor.
Gerekiyorsa sadece formulle (-)değerli hücreleri sarı, (+)değerli hücreleri yeşil yapacak ve de tablonun altına da bunların toplamlarını ayrı ayrı alabilecek bi formül yazabilirmisiniz?
Bilgisayar şirket pcsi olduğu makro konusu biraz sorun yaratıyor..

Şimdiden teşekkürler..

 

[Korhan Ayhan]

Merhaba,

Forumumuza hoşgeldiniz.

D21 hücresine;

=ETOPLA(D2:D19;"<0";D2:D19)

D22 hücresine;

=ETOPLA(D2:D19;">0";D2:D19)

Formüllerini uygulayıp denermisiniz.

 

[gsray4ever]

Öncelikle bilgi için teşekkürler.
verdiğiniz formülü yazdım,

=SUMIF(D2:D19;"<0";D2:D19)

evet böylece seçili hücrelerdeki 0dan küçükleri topladı,
fakat herhangi bi şekilde filtre uyguladığım zaman toplam değişmiyor..
acaba sadece o anda ekranda bulunan aktif hücreleri nasıl toplatabiliriz?

 

[Korhan Ayhan]

Merhaba,

Filtrelenmiş alan için aşağıdaki formülleri kullanmanız gerekir.

D21;

=TOPLA.ÇARPIM(ALTTOPLAM(3;KAYDIR($D$2:$D$20;SATIR($D$2:$D$20)-MİN(SATIR($D$2:$D$20));;1));--($D$2:$D$20<0);--($D$2:$D$20))

D22;

=TOPLA.ÇARPIM(ALTTOPLAM(3;KAYDIR($D$2:$D$20;SATIR($D$2:$D$20)-MİN(SATIR($D$2:$D$20));;1));--($D$2:$D$20>0);--($D$2:$D$20))

 

[gsray4ever]

Teşekkürler..

=SUMPRODUCT(SUBTOTAL(3;OFFSET($F$2:$F$20;ROW($F$2:$F$20)-MIN(ROW($F$2:$F$20));;1));--($F$2:$F$20>0);--($F$2:$F$20))

=SUMPRODUCT(SUBTOTAL(3;OFFSET($F$2:$F$20;ROW($F$2:$F$20)-MIN(ROW($F$2:$F$20));;1));--($F$2:$F$20<0);--($F$2:$F$20))

şeklinde de ingilizceye cevirince canavar gibi çalıştı

 

[gsray4ever]

yine aynı tabloda aşağı doğru değilde sağa doğru toplatmak istediğimizde nasıl bi formül yazmamız gerekir?