kelimelere boşluk bırakma

[mesudiye_052]

Selamlar;

Hücre biçimlendirmesinde sayıları

0 0 0 0 0 0 biçimlendirmesinde sayıların arasına boşluk yapabiliyorum
mesela A1 hücresinde farzedelim 564875 sayısını hücre biçimlendirmesini 0 0 0 0 0 0
yaptığımızda A1 hücresi arada birer boşluk bırakarak 5 6 4 8 7 5 şeklinde oluyor

ama metinlerde yapamıyorum
kelimelerin aralarını boşluk bırakarak hücre biçimlendime olarak nasıl yapabilirim
k a r a gibi
yada olmuyorsa dizi formülle yapılabilirmiz

Saygılar

 

[Necdet]

Merhaba,

Kullanıcı Tanımlı Fonksiyon ister misiniz?

Kullanımı :

=HarfAc(A1)

Function HarfAc(Hücre As String) As String
Dim i As Integer
Dim Değer As String
If Len(Hücre) > 1 Then
    Değer = Left(Hücre, 1)
    For i = 2 To Len(Hücre)
        Değer = Değer & " " & Mid(Hücre, i, 1)
    Next i
Else
    Değer = Hücre
End If
HarfAc = Değer
End Function

 

[uzmanamele]

merhaba

alternatif olsun

Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False
If Intersect(Target, [a1]) Is Nothing Then Exit Sub
u = Len(Target.Text)
For i = 1 To u
harf = Mid(Target.Text, i, 1)
yazı = yazı & " " & harf
Next
Target = Trim(yazı)
Application.EnableEvents = True
End Sub

syn Necdet bey'in katkılarıyla

 

[Necdet]

Merhaba,

Kodları kısalttım, dosyayı yeniledim.

 

[mesudiye_052]

Selamlar;

Sayın Necdet Yeşertener;
Sayın uzmanamele;

İlginize teşekkür eder başarılarınızın devamını dilerim.

Saygılarımla;

 

[uzmanamele]

merhaba

Mustafa Kemal Atatürk gibi metinlerde arada 2 karakter boşluk olmasın istiyorsanız bu kodu deneyiniz.

Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False
If Intersect(Target, [a1]) Is Nothing Then Exit Sub
metin = Replace(Target.Text, " ", "")
u = Len(metin)
For i = 1 To u
harf = Mid(metin, i, 1)
yazı = yazı & " " & harf
Next
Target = Trim(yazı)
Application.EnableEvents = True
End Sub

 

[brawert2]

Merhabalar oncelıkle
sorum şu olucak ekte mevcut olan dosyanın ıcerısınde tek bır sütünda cok fazla adet ,tk,çift, mt, şeklinde sayılar olabılıyor . Bunları yıne aynı sutunda adet toplamları toplam adet , tk ları toplamtk , çift olanları toplam çift şeklinde yazmamızı saglıcak formul , fonksıyon , mevcutmudur acaba .. şimdiden teşekkur ederım ..

 

[brawert2]

help MEEEE

Bu ekte daha anlasılır olabılecegını dusunuyorum ..

 

[Korhan Ayhan]

Aşağıdaki fonksiyonu deneyin.

Kodu boş bir modüle ekleyin. Hücrede kullanırken =KTOPLA(I1) yazarak kullanın.

ADET-ÇİFT-TK-MT şeklinde olan verilerin toplamını verir. Başka kriterleriniz varsa fonksiyona eklemek gerekecektir.

Function KTOPLA(Veri As Range) As String
    Dim Data() As String, X As Integer
    Dim Toplam_Adet As Long
    Dim Toplam_Cift As Long
    Dim Toplam_Takim As Long
    Dim Toplam_Metre As Long
    Dim Sayi As Long
    
    Application.Volatile True
    
    Data = Split(Veri.Text, ",")
    
    For X = 0 To UBound(Data)
        If InStr(1, Data(X), "ADET") > 0 Then
            Sayi = Replace(Data(X), "ADET", "")
            Toplam_Adet = Toplam_Adet + Sayi
        End If
    
        If InStr(1, Data(X), "ÇİFT") > 0 Then
            Sayi = Replace(Data(X), "ÇİFT", "")
            Toplam_Cift = Toplam_Cift + Sayi
        End If
        
        If InStr(1, Data(X), "TK") > 0 Then
            Sayi = Replace(Data(X), "TK", "")
            Toplam_Takim = Toplam_Takim + Sayi
        End If
    
        If InStr(1, Data(X), "MT") > 0 Then
            Sayi = Replace(Data(X), "MT", "")
            Toplam_Metre = Toplam_Metre + Sayi
        End If
    Next
    
    KTOPLA = IIf(Toplam_Adet = 0, "", Toplam_Adet & " Adet") & _
             IIf(Toplam_Cift = 0, "", ", " & Toplam_Cift & " Çift") & _
             IIf(Toplam_Takim = 0, "", ", " & Toplam_Takim & " Takım") & _
             IIf(Toplam_Metre = 0, "", ", " & Toplam_Metre & " Metre")
End Function