kayıtı hızlandırmak

[igultekin2000]

http://dosya.co/3rhcwbn3ddan/KUMAS_SON.rar.html

iyi akşamlar;
kumaş imalatına ilişkin hazırladığım sayfa var. son duruma geldim ama tam neticelendiremedi m. Şöyleki. " İmalat " sekmesinde " alis- atelye - imalat " şeklinde üç seçenekli veri girişi yapıyorum.

1-) "alış" seçiliyken B-C-D-E hücresine 2-)" atelye" seçiliyken B-C-D-H hücresine 3-) "imalat" seçiliyken B-C-D-I-J hücresine veri girişi yapıyorum. "alış-atelye-imalat" seçtiğimde kursörün sadece bu hücrelere aktif olup veri girişinden sonra kayıt makrosunu çalıştırmasına uğraşıyorum. değişik alternatifler denedim lakin başarılı olamadım.

 

[vardar07]

http://dosya.co/3rhcwbn3ddan/KUMAS_SON.rar.html

iyi akşamlar;
kumaş imalatına ilişkin hazırladığım sayfa var. son duruma geldim ama tam neticelendiremedi m. Şöyleki. " İmalat " sekmesinde " alis- atelye - imalat " şeklinde üç seçenekli veri girişi yapıyorum.

1-) "alış" seçiliyken B-C-D-E hücresine 2-)" atelye" seçiliyken B-C-D-H hücresine 3-) "imalat" seçiliyken B-C-D-I-J hücresine veri girişi yapıyorum. "alış-atelye-imalat" seçtiğimde kursörün sadece bu hücrelere aktif olup veri girişinden sonra kayıt makrosunu çalıştırmasına uğraşıyorum. değişik alternatifler denedim lakin başarılı olamadım.

Sanki sorunuz eksik gibi. "alis" seçili iken hangi sayfanın B-C-D-E hücresine tabiki diğer iki seçenek sayfalarını belirtirseniz iyi olur.

 

[igultekin2000]

Sanki sorunuz eksik gibi. "alis" seçili iken hangi sayfanın B-C-D-E hücresine tabiki diğer iki seçenek sayfalarını belirtirseniz iyi olur.

Imalat sayfasındaki "A3" sekmesinde veri doğrulama seçeneğinde "alis-atelye-imalat" seçenekleri var. o sayfadaki kayıt için.

 

[vardar07]

Ne yapmak istediğinizi kavrayamadım. "alis" seçili iken imalat sayfasında hangi hücrelere veri girdiğinizi ve kayıt tuşuna basınca hangi sayfaya kayıt yapacağını,"atelye" hangi sayfaya kayıt yapacağını, "imalat" sayfaya kayıt yapacağını açıkça belirtilmiş bir örnek dosya (elle girdiğiniz yerleri sarıya aktarılacak yeride değişik bir renkle belirtilmiş şekilde) eklerseniz yardımcı olmaya çalışayım.

 

[igultekin2000]

örnek dosya

Ne yapmak istediğinizi kavrayamadım. "alis" seçili iken imalat sayfasında hangi hücrelere veri girdiğinizi ve kayıt tuşuna basınca hangi sayfaya kayıt yapacağını,"atelye" hangi sayfaya kayıt yapacağını, "imalat" sayfaya kayıt yapacağını açıkça belirtilmiş bir örnek dosya (elle girdiğiniz yerleri sarıya aktarılacak yeride değişik bir renkle belirtilmiş şekilde) eklerseniz yardımcı olmaya çalışayım.

http://s8.dosya.tc/server3/e1gtwl/ornek.rar.html

o sorunu örnek dosya bulup çözdüm, yeni yüklediğim dosya da yardımcı olabilirseniz, kayıtlar sonunda envanter şeklinde liste oluşuyor. tarih aralığı vererek envanter sayfasındaki verilerden rapor sayfasındaki gibi ilgili verileri almak makro ile listelemek istiyorum. Teşkkürler.

 

[Ziynettin]

Merhaba,
Kodu deneyiniz.

Option Explicit
Sub Aktar()
Dim S1 As Worksheet, S2 As Worksheet
Dim a(), b(), Tarih_1 As Date, Tarih_2 As Date
Dim i As Long, Say As Long

Set S1 = Sheets("Envanter")
Set S2 = Sheets("Rapor")
Tarih_1 = S2.[C2]: Tarih_2 = S2.[D2]

If Tarih_1 > Tarih_2 Then: MsgBox "Tarihleri kontrol ediniz.", vbCritical: Exit Sub

a = S1.Range("B3:L" & S1.Cells(Rows.Count, 2).End(3).Row).Value
ReDim b(1 To UBound(a), 1 To 5)
For i = 1 To UBound(a)
    If a(i, 8) <> "" And a(i, 8) <> 0 Then
        [COLOR="red"]If Tarih_2 >= a(i, 1) And Tarih_1 <= a(i, 1) Then[/COLOR]
            Say = Say + 1
            b(Say, 1) = a(i, 1)
            b(Say, 2) = a(i, 3)
            b(Say, 3) = a(i, 8)
            b(Say, 4) = a(i, 9)
            b(Say, 5) = a(i, 11)
        [COLOR="Red"]End If[/COLOR]
    End If
Next i
S2.Range("B4:F" & Rows.Count).ClearContents
If Say > 0 Then
    S2.[B4].Resize(Say, 5) = b
    S2.[B4].Resize(Say).NumberFormat = "dd.mm.yyyy"
    S2.[F4].Resize(Say).NumberFormat = "#,##0.00"
End If
MsgBox "İşlem Tamam....", vbInformation
End Sub

 

[igultekin2000]

Tarih sorunu

Teşekkürler, makro güzel çalışıyor , sadece tarih sınırlaması yapmıyor, listedeki tüm tarihleri raporluyor.

 

[Ziynettin]

Kodu yeniden deneyiniz.

 

[igultekin2000]

kod sorunsuz çalışıyor

Kodu yeniden deneyiniz.

teşekkürler düzenleme ile sorunsuz çalışıyor, teşekkürler. Zor olmayacaksa bir isteğim daha olacak;
zaman alacaksa olmayabilir de; Rapor sayfasına iki bağımsız açılır liste ilave edip seçtiğimiz kumaştan hangi ürünler imal edilmiş, ve hangi ürün hangi kumaşlardan imal edilmiş gibi bir bir sorgu da ilave edilebilir mi?

http://s3.dosya.tc/server10/rrix7e/ornek.rar.html

 

[Ziynettin]

İstediğiniz iki tarih arasında olacak ise;

Option Explicit
Sub Aktar()
Dim S1 As Worksheet, S2 As Worksheet
Dim a(), b(), Tarih_1 As Date, Tarih_2 As Date
Dim i As Long, Say As Long, Kumas As String, Mamul As String
Set S1 = Sheets("Envanter")
Set S2 = Sheets("Rapor")
Tarih_1 = S2.[C2]: Tarih_2 = S2.[D2]
Kumas = S2.[E2]: Mamul = S2.[F2]
If Tarih_1 > Tarih_2 Then: MsgBox "Tarihleri kontrol ediniz.", vbCritical: Exit Sub
a = S1.Range("B3:L" & S1.Cells(Rows.Count, 2).End(3).Row).Value
ReDim b(1 To UBound(a), 1 To 5)
For i = 1 To UBound(a)
    If a(i, 8) <> "" And a(i, 8) <> 0 Then
        If Tarih_2 >= a(i, 1) And Tarih_1 <= a(i, 1) Then
            If Kumas = a(i, 3) And Mamul = a(i, 8) Then
                Say = Say + 1
                b(Say, 1) = a(i, 1)
                b(Say, 2) = a(i, 3)
                b(Say, 3) = a(i, 8)
                b(Say, 4) = a(i, 9)
                b(Say, 5) = a(i, 11)
            End If
        End If
    End If
Next i
S2.Range("B4:F" & Rows.Count).ClearContents
If Say > 0 Then
    S2.[B4].Resize(Say, 5) = b
    S2.[B4].Resize(Say).NumberFormat = "dd.mm.yyyy"
    S2.[F4].Resize(Say).NumberFormat = "#,##0.00"
Else
    MsgBox "Aradığınız kriterlere ait veri bulunamadı.", vbExclamation
    Exit Sub
End If
MsgBox "İşlem Tamam....", vbInformation
End Sub

Kumaş ve mamul göre listeleme yapılacak ise kodu ona göre düzenleme yapılır.

 

[igultekin2000]

Kod sorunsuz çalışıyor

Teşekkür ederim, kod sorunsuz çalışıyor.